package RPS::Import::Dorado::v2;

use strict;
use warnings;

use lib '/app/tools/rps/lib';

use RPS::Import::ServiceMap;
use Date::Calc qw(Days_in_Month);

use parent qw/RPS::Import::MapFaceBase RPS::Import::ImporterMixed/;

sub physical { 0 }

sub _fieldMapExtended {
    {
        digital => {
            option1 => {
                labelName        => 'E',
                serviceID        => 'G',
                countryCode      => 'K',
                productType      => 'M',
                formatType       => 'M',
                serviceProductID => 'H',
                artistName       => 'I',
                trackName        => 'I',
                units            => 'L',
                price            => 'Q',
                mediaType        => 'M',
            }
        }
    }
}

sub _unverifiedFieldMapExtended {
    {
        digital => {
            option1 => {
                _year  => 'A',
                _month => 'B',
            }
        }
    }
}

sub _headerIdentifierExtended {
    {
        digital => {
            option1 => { artistName => 'VIDEOTITLE' }
        }
    }
}

sub currencyCode { 'EUR' }

sub serviceID {
    my $self = shift;

    my $service = lc( $self->_getByFieldName('serviceID') || '' );
    my $serviceID = $self->getServiceID($service) || $RPS::Import::ServiceMap::SERVICE_ALIASES{$service};
    return $serviceID if $serviceID;

    return $self->handleError( "Unknown service: $service", RPS::DB::Item::SaleImportError::kErrorService );
}

sub countryCode {
    my $self = shift;

    my $name = $self->_getByFieldName('countryCode') || '';

    return 'DE' if $name eq 'WW';

    my $country = Common::Country->Get($name);
    return $country->alpha2() if $country;

    $self->handleError( "Unknown country: $name", RPS::DB::Item::SaleImportError::kErrorCountry );
    return $name;
}

sub saleDates {
    my $self = shift;

    my $year  = $self->_getByFieldName('_year') || '';
    my $month = $self->_getByFieldName('_month') || '';

    if ( $year =~ /^\d{4}$/ && $month =~ /^\d{1,2}$/ ) {
        return $self->_getDates(
            date_begin => sprintf( "%04d-%02d-%02d", $year, $month, 1 ),
            date_end   => sprintf( "%04d-%02d-%02d", $year, $month, Days_in_Month($year, $month)))
    }

    $self->fail( "Unable to determine date from '$year' and '$month'." );
}

sub formatType {
    my $self = shift;

    my $type = $self->_getByFieldName('formatType') || '';

    return RPS::File::Sale::FORMAT_STREAM if $type =~ /^AVOD$/i;

    $self->handleError( "Unknown format type: $type", RPS::DB::Item::SaleImportError::kErrorFormatType );
}

sub productType {
    my $self = shift;

    my $type = $self->_getByFieldName('productType') || '';

    return RPS::File::Sale::TYPE_TRACK if $type =~ /^AVOD$/i;
}

sub mediaType {
    my $self = shift;

    my $type = $self->_getByFieldName('mediaType') || '';

    return RPS::DB::Item::MediaType::kMediaTypeVideo if $type =~ /^AVOD$/i;
}

sub artistName {
    my $self = shift;

    my $name = $self->_getByFieldName('artistName') || '';
    $name =~ s/\s*-.*$//g;

    return $name
}

sub trackName {
    my $self = shift;

    my $name = $self->_getByFieldName('trackName') || '';
    $name =~ s/(^.*?-\s*|\|.*$)//g;

    return $name
}

sub price     { abs( shift->_getByFieldName('price') || 0 ) }
sub unitPrice { abs shift->SUPER::unitPrice }

sub units {
    my $self = shift;

    my $units = $self->_getByFieldName('units') || 0;
    my $price = $self->_getByFieldName('price') || 0;

    if ( $price > 0 ) {
        $units = $units ? abs($units) : 1;
    } elsif ( $price < 0 ) {
       $units = $units ? -1 * abs($units) : -1;
    }

    return $units * 1;
}

sub _isValidSaleRecord {
    my $self = shift;

    my $countryCode = $self->countryCode;
    my $units       = $self->units;
    my $price       = $self->price;

    return ($countryCode && $units && $price) ? 1 : 0;
}

sub _mapFaceServiceID   { 'serviceID' }
sub _mapFaceCountryCode { 'countryCode' }
sub _mapFaceFormatType  { 'formatType' }
sub _mapFaceProductType { }
sub _mapFaceMediaType   { }

1;