package RPS::Import::DoubleSix::v1;

use strict;
use warnings;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;
use Common::Date;

use parent 'RPS::Import::ImporterMixed';

sub physical { 2 }

sub _fieldMapExtended {
    {
        mixed => {
            option1 => {
                labelName   => 'A',
                countryCode => 'B',
                dateBegin   => 'D',
                artistName  => 'H',
                isrc        => 'J',
                trackName   => 'I',
                price       => 'K',
            },
         },
    };
}

sub _unverifiedFieldMapExtended { {} }

sub _headerIdentifierExtended {
    {
        mixed => {
            option1 => {
                isrc => 'ISRC',
            },
        },
    };
}

sub serviceName  { Client::Service::DSP_DOUBLE_SIX }
sub productType  { RPS::File::Sale::TYPE_TRACK }
sub formatType   { RPS::File::Sale::FORMAT_PERFORMANCE }
sub mediaType    { RPS::DB::Item::MediaType::kMediaTypeAudio }
sub currenctCode { 'USD' }

sub countryCode {
    my $self = shift;

    my $name = $self->_getByFieldName('countryCode') || '';

    my $oCountry = Common::Country->Get($name);
    if ( my $country = $oCountry->alpha2 ) {
        return $country;
    }

    $self->fail( "Unable to determine country from: '$name'." );
}

sub saleDates {
    my $self = shift;

    # MM/DD/YYYY
    my $dateBegin = $self->_getByFieldName('dateBegin') || '';

    if ( $dateBegin =~ /(\d{2})[\-\/](\d{2})[\-\/](\d{4})/ ) {
        $dateBegin = sprintf "%04d-%02d-%02d", $3, $1, $2;
    } elsif ( $dateBegin =~ /^\d+$/) {
        $dateBegin = Common::Date->new( date => $dateBegin, type => 'excel' );
    } else {
        $self->fail( "Unable to determine date from: '$dateBegin'." );
    }

    return $self->_getDates( date_begin => $dateBegin );
}

sub price     { abs( shift->_getByFieldName('price') || 0 ) }
sub unitPrice { abs shift->SUPER::unitPrice }
sub units {
    my $self = shift;

    my $price = $self->_getByFieldName('price') || 0;
    return $price <=> 0;
}


1;