#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2013 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------
package RPS::Import::E1Distribution::v2;
use strict;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;

use base 'RPS::Import::MapFaceBase';
use base 'RPS::Import::Importer';

sub _fieldMap {
    my $self      = shift;
    my %field_map = (
        2 => {
            labelName    => 'C',
            dateBegin    => 'A',
            dateEnd      => 'A',
            serviceID    => 'D',
            countryCode  => 'F',
            currencyCode => 'W1',
            upc          => 'G',
            albumName    => 'I',
            artistName   => 'J',
            trackName    => 'N',
            trackNum     => 'M',
            isrc         => 'K',
            units        => 'Q',
            price        => 'AA',
            productType  => 'P',
            formatType   => 'E',
        },
        3 => {
            labelName    => 'D',
            dateBegin    => 'A',
            dateEnd      => 'A',
            serviceID    => 'E',
            countryCode  => 'G',
            currencyCode => 'S1',
            upc          => 'H',
            albumName    => 'J',
            artistName   => 'K',
            trackName    => 'O',
            trackNum     => 'N',
            isrc         => 'L',
            units        => 'R',
            price        => 'S',
            productType  => 'Q',
            formatType   => 'F',
        }
    );

    return $field_map{ $self->_version };
}

sub _headerIdentifier { ( upc => 'UPC' ) }

sub mediaType { RPS::DB::Item::MediaType::kMediaTypeAudio; }

sub serviceID {
    my $self    = shift;
    my $service = $self->_getByFieldName('serviceID');

    my $serviceID = $self->getServiceID( lc($service) ) || $RPS::Import::ServiceMap::SERVICE_ALIASES{ lc $service };

    return $serviceID if ($serviceID);

    return $self->handleError( "Unknown service: $service", RPS::DB::Item::SaleImportError::kErrorService );
}

sub currencyCode {
    my $self = shift;
    return $self->{_currencyCode} if ( $self->{_currencyCode} );

    my $ccode = $self->_getByFieldName('currencyCode');
    if ( $ccode =~ /Sales \((\w{3})\)/i ) {
        $self->{_currencyCode} = $1;
    } else {
        return $ccode;
    }
}

sub saleDates {
    my $self = shift;
    my $dt   = $self->_getByFieldName('dateBegin');
    if ( $dt =~ /^(\d{4})-(\d{1,2})$/ )    # YYYY-MM
    {
        $dt = sprintf( "%04d-%02d-%02d", $1, $2, 1 );
    }
    return $self->_getDates( date_begin => $dt );
}

sub productType {
    my $self = shift;
    my $type = $self->_getByFieldName('productType');
    if ( $type =~ /^t$/i ) {
        return RPS::File::Sale::TYPE_TRACK;
    } elsif ( $type =~ /^a$/i ) {
        return RPS::File::Sale::TYPE_ALBUM;
    }
    return $type;
}

sub formatType {
    my $self = shift;
    my $type = $self->_getByFieldName('formatType');
    if ( $type =~ /^d$/i ) {
        return RPS::File::Sale::FORMAT_DOWNLOAD;
    } elsif ( $type =~ /^s$/i ) {
        return RPS::File::Sale::FORMAT_STREAM;
    }
    return $type;
}

# MapFace settings
sub _mapFaceCompatibleVersions {
    return ( 2, 3 );
}

sub _mapFaceServiceID {
    return ('serviceID');
}

sub _mapFaceCountryCode {
    return ('countryCode');
}

sub _mapFaceProductType {
    return ('productType');
}

sub _mapFaceFormatType {
    return ('formatType');
}

# Not mapped for this file format.
sub _mapFaceMediaType { }

###
1;    # Play nicely.
###