#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2010 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------

package RPS::Import::FontanaPhysical::v7;

use strict;

use lib '/app/tools/common/lib';
use Common::Assert;

use lib '/app/tools/rps/lib';
use base 'RPS::Import::Importer';

sub _fieldMap {
    {
        labelName        => 'A',
        dateBegin        => 'C',
        productType      => 'K',
        artistName       => 'I',
        serviceProductID => 'F',
        albumName        => 'G',
        sales            => 'R',
        salesRevenue     => 'O',
        returns          => 'S',
        returnsRevenue   => 'P',
        units            => 'T',
        totalRevenue     => 'Q',
    };
}

sub _unverifiedFieldMap {
    { salesType => 'N', };
}

sub _headerIdentifier { ( labelName => 'Operating Unit' ) }

sub channel {
    my $self      = shift;
    my $salesType = $self->_getByFieldName('salesType');
    my $channel;
    if ( $salesType eq '11' || $salesType eq '29' || $salesType eq '41' || $salesType eq '51' || $salesType eq '53' ) {
        $channel = RPS::File::Sale::CHANNEL_RETAIL;
    } elsif ( $salesType eq '21' ) {
        $channel = RPS::File::Sale::CHANNEL_MILITARY;
    } elsif ( $salesType eq '57' ) {
        $channel = RPS::File::Sale::CHANNEL_CLUB;
    }
    print STDERR "Unable to determine channel from sales type '$salesType'\n" if ( !$channel );
    return $channel;
}

sub priceLevel {
    my $self      = shift;
    my $salesType = $self->_getByFieldName('salesType');
    my $plevel    = RPS::File::Sale::PLEVEL_UNKNOWN;
    if ( $salesType eq '53' ) {
        $plevel = RPS::File::Sale::PLEVEL_PROMO;
    }
    return $plevel;
}

sub countryCode  { 'US' }
sub currencyCode { 'USD' }

sub productType {
    my $self   = shift;
    my $config = $self->_getByFieldName('productType');
    my $prodtype;
    if ( $config eq 'CD' || $config eq 'COMPACT DISC' || $config =~ /^UNKNOWN-CF$/i ) {
        $prodtype = RPS::File::Sale::TYPE_CD;
    } elsif ( $config eq 'DV' || $config =~ /DVD VIDEO/i ) {
        $prodtype = RPS::File::Sale::TYPE_DVD;
    } elsif ( $config =~ /CD\/TEMP DVD/i || $config =~ /MIXED CD\/DVD/i ) {
        $prodtype = RPS::File::Sale::TYPE_DVD_CD_SET;
    } elsif ( $config =~ /SINGLE 12 INCH/i ) {
        $prodtype = RPS::File::Sale::TYPE_LP;
    } elsif ( $config eq 'VH' ) {
        $prodtype = RPS::File::Sale::TYPE_VHS;
    } elsif ( $config eq 'CF' ) {
        $prodtype = RPS::File::Sale::TYPE_CD;
    } elsif ( $config eq 'S5' ) {
        $prodtype = RPS::File::Sale::TYPE_CD_SIN;
    } elsif ( $config eq 'ST' || $config eq 'ALBUM' || $config eq 'LP' ) {
        $prodtype = RPS::File::Sale::TYPE_LP;
    } elsif ( $config eq 'DX' ) {
        $prodtype = RPS::File::Sale::TYPE_CD;
    }
    $self->fail("Unable to determine product type from '$config'") if ( !$prodtype );
    return $prodtype;
}

sub sales {
    my $self  = shift;
    my $sales = $self->_getByFieldName('sales');
    if ( $sales < 0 ) {
        $sales = 0;
    }
    return $sales;
}

sub salesRevenue {
    my $self         = shift;
    my $salesRevenue = $self->_getByFieldName('salesRevenue');
    if ( $salesRevenue < 0 ) {
        $salesRevenue = 0;
    }
    return $salesRevenue;
}

sub returns {
    my $self    = shift;
    my $sales   = $self->_getByFieldName('sales');
    my $returns = $self->_getByFieldName('returns');
    if ( $sales < 0 ) {
        $returns += $sales;
    }
    if ( $returns < 0 ) {
        $returns *= -1;
    }
    return $returns;
}

sub returnsRevenue {
    my $self           = shift;
    my $salesRevenue   = $self->_getByFieldName('salesRevenue');
    my $returnsRevenue = $self->_getByFieldName('returnsRevenue');
    if ( $salesRevenue < 0 ) {
        $returnsRevenue += $salesRevenue;
    }
    if ( $returnsRevenue < 0 ) {
        $returnsRevenue *= -1;
    }
    return $returnsRevenue;
}

sub _isValidSaleRecord {
    my $self = shift;

    return unless ( $self->SUPER::_isValidSaleRecord );

    # Generate an error if line has revenue without units
    #
    if (   ( $self->salesRevenue || $self->returnsRevenue )
        && !$self->sales
        && !$self->returns ) {
        $self->fail( "Line " . $self->linenum . ": revenue with no units" );
    }

    # We have some lines with no units or revenue of any kind.
    # We need to ignore these.
    return $self->sales || $self->returns ? 1 : undef;
}

sub _getDateBegin {

    my $self = shift;
    my $value = $self->_getByFieldName('dateBegin') || return;
    my $dateBegin;

    if ( $value =~ /\((\w{3,4}\s*\d{2})\)$/ ) {
        $dateBegin = $1;
    }

    return $dateBegin;
}

sub _dateFormat { 'text' }

###
1;    # Play nicely.
###