#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2013 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------

package RPS::Import::Fuga::v2;

use strict;

use lib '/app/tools/common/lib';
use Common::Assert;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;

use base 'RPS::Import::Importer';

sub _fieldMap {
    my $self      = shift;
    my %field_map = (
        2 => {
            labelName   => 'I',
            serviceID   => 'G',
            countryCode => 'N',
            dateBegin   => 'A',
            dateEnd     => 'B',
            productType => 'M',
            formatType  => 'O',
            artistName  => 'J',
            upc         => 'L',
            albumName   => 'K',
            isrc        => 'M',
            trackName   => 'K',
            units       => 'Q',
            price       => 'AD',
        },
        3 => {
            labelName   => 'I',
            serviceID   => 'G',
            countryCode => 'N',
            dateBegin   => 'A',
            dateEnd     => 'B',
            productType => 'M',
            formatType  => 'O',
            artistName  => 'J',
            upc         => 'L',
            albumName   => 'K',
            isrc        => 'M',
            trackName   => 'K',
            units       => 'Q',
            price       => 'Y',
            mediaType   => 'O',
        },
    );
    return $field_map{ $self->_version };
}

sub _headerIdentifier { ( upc => 'UPCCode' ) }

sub currencyCode { 'EUR' }

sub productType {
    my $self        = shift;
    my $productType = $self->_getByFieldName('productType');

    if ( !$productType || $productType eq '' ) {
        return RPS::File::Sale::TYPE_ALBUM;
    } else {
        return RPS::File::Sale::TYPE_TRACK;
    }
}

sub formatType {
    my $self = shift;

    my $fmt  = $self->_getByFieldName('formatType');

    if ( $self->_version == 3 ) {
        return RPS::File::Sale::FORMAT_STREAM if $fmt =~ /^(?:Video|Ad\-Supported) Streams?$/i;
    }

    if ( $fmt =~ /^(?:album|track)?\s?download$/i ) {
        return RPS::File::Sale::FORMAT_DOWNLOAD;
    } elsif ( $fmt =~ /^streaming$/i ||
              $fmt =~ /^subscription audio stream$/i ||
              $fmt =~ /^ad-supported audio stream$/i ||
              $fmt =~ /^cloud match unit$/i ) {
        return RPS::File::Sale::FORMAT_STREAM;
    } elsif ( $fmt =~ /^non-interactive radio stream$/i ) {
        return RPS::File::Sale::FORMAT_PERFORMANCE;
    }

    $self->fail("Unrecognized format '$fmt'");
}

sub albumName {
    my $self = shift;
    my $name = $self->_getByFieldName('albumName');

    return $name if ( $self->productType eq RPS::File::Sale::TYPE_ALBUM );
}

sub trackName {
    my $self = shift;
    my $name = $self->_getByFieldName('trackName');
    return $name if ( $self->productType eq RPS::File::Sale::TYPE_TRACK );
}

sub saleDates {
    my $self = shift;

    my $dateBegin;
    my $dateEnd;

    my $startDate = $self->_getDateBegin();
    my $endDate   = $self->_getDateEnd();

    if ( $startDate && $endDate ) {
        ( $dateBegin, $dateEnd ) = $self->_getDates( date_begin => $startDate, date_end => $endDate );
    }

    return ( $dateBegin, $dateEnd );
}

sub serviceID {
    my $self    = shift;
    my $service = $self->_getByFieldName('serviceID');

    my $serviceID = $self->getServiceID( lc($service) ) || $RPS::Import::ServiceMap::SERVICE_ALIASES{ lc $service };

    return $serviceID if ($serviceID);

    $self->fail("Unknown service '$service'");
}

sub _processSheet {
    my $self     = shift;
    my $sheet    = shift;
    my $sheetnum = shift;

    # Process only if this is not an Excel file (e.g. text) or if there's a sheet named 'details' ...
    #
    if ( $self->filename !~ /\.xls$/ || $self->{sheetname} =~ /^details$/i ) {
        return $self->SUPER::_processSheet( $sheet, $sheetnum );
    }
}


sub price     { sprintf( "%.8f", abs( shift->_getByFieldName('price') || 0 )) }
sub unitPrice { abs shift->SUPER::unitPrice }
sub units {
    my $self = shift;

    my $units = $self->_getByFieldName('units') || 0;
    my $price = $self->_getByFieldName('price') || 0;

    if ( $price > 0 ) {
        $units = $units ? abs($units) : 1;
    } elsif ( $price < 0 ) {
       $units = $units ? -1 * abs($units) : -1;
    }

    return $units;
}

sub mediaType {
    my $self = shift;

    my $type = $self->_getByFieldName('mediaType') || '';
    if ( $type =~ /^Video Stream$/i ) {
        return RPS::DB::Item::MediaType::kMediaTypeVideo;
    }

    return RPS::DB::Item::MediaType::kMediaTypeAudio;
}


1;