package RPS::Import::Fuga::v4;

use strict;
use warnings;

use lib '/app/tools/common/lib';
use Common::Country;


use lib '/app/tools/rps/lib';
use Date::Calc qw(Add_Delta_Days Days_in_Month);
use RPS::Import::ServiceMap;

use parent qw/RPS::Import::MapFaceBase RPS::Import::ImporterMixed/;

sub physical { 0 }

sub _fieldMapExtended {
    {
        digital => {
            option1 => {
                labelName    => 'K',
                serviceID    => 'C',
                countryCode  => 'G',
                dateBegin    => 'A',
                dateEnd      => 'B',
                productType  => 'T',
                formatType   => 'E',
                upc          => 'H',
                albumName    => 'M',
                isrc         => 'R',
                trackName    => 'O',
                currencyCode => 'AC',
                price        => 'AB',
                mediaType    => 'E',
            },
         },
    };
}

sub _unverifiedFieldMapExtended {
    {
        digital => {
            option1 => {
                _asset_quantity   => 'V',
                _product_quantity => 'U',
                _asset_artist     => 'N',
                _product_artist   => 'L',
            },
        },
    };
}

sub _headerIdentifierExtended {
    {
        digital => {
            option1 => {
                productType => 'Asset/Product',
            },
        },
    };
}

sub mediaType {
    my $self = shift;

    my $type = $self->_getByFieldName('mediaType') || '';
    $self->fail("Media type is empty") unless $type;

    if ( $type =~ /^(?:Download|Streaming|Breakage)$/i ) {
        return RPS::DB::Item::MediaType::kMediaTypeAudio;
    } elsif ( $type =~ /^(?:Video Stream \(Audio \+ Video\))$/i ) {
        return RPS::DB::Item::MediaType::kMediaTypeVideo;
    }

    my $serviceID = $self->_getByFieldName('serviceID') || '';
    if ( $serviceID =~ /^(?:SNAP|TikTok)$/i && $type =~ /^Synch$/i ) {
        return RPS::DB::Item::MediaType::kMediaTypeAudio;
    } elsif ( $serviceID =~ /^(?:Pandora)$/i && $type =~ /^Non-Interactive Stream$/i ) {
        return RPS::DB::Item::MediaType::kMediaTypeAudio;
    }

    return $self->handleError( "Unknown media_type: '$type'", RPS::DB::Item::SaleImportError::kErrorMediaType );
}

sub serviceID {
    my $self = shift;

    my $service = lc( $self->_getByFieldName('serviceID') || '' );
    my $serviceID = $self->getServiceID($service) || $RPS::Import::ServiceMap::SERVICE_ALIASES{$service};
    return $serviceID if $serviceID;

    return $self->handleError( "Unknown service: '$service'", RPS::DB::Item::SaleImportError::kErrorService );
}

sub productType {
    my $self = shift;

    my $type = $self->_getByFieldName('productType') || '';

    return RPS::File::Sale::TYPE_TRACK if ( $type =~ /^asset$/i );
    return RPS::File::Sale::TYPE_ALBUM if ( $type =~ /^product$/i );

    $self->fail("Unknown product_type: '$type'");
}

sub formatType {
    my $self = shift;

    my $type = $self->_getByFieldName('formatType') || '';

    $self->fail("Format type is empty") unless $type;

    return RPS::File::Sale::FORMAT_DOWNLOAD if ( $type =~ /^download$/i );
    return RPS::File::Sale::FORMAT_STREAM if ( $type =~ /^(?:streaming|Video Stream \(Audio \+ Video\)|Breakage)$/i );

    my $serviceID = $self->_getByFieldName('serviceID') || '';
    if ( $serviceID =~ /^(?:SNAP|TikTok)$/i && $type =~ /^Synch$/i ) {
        return RPS::File::Sale::FORMAT_STREAM;
    } elsif ( $serviceID =~ /^(?:Pandora)$/i && $type =~ /^Non-Interactive Stream$/i ) {
        return RPS::File::Sale::FORMAT_PERFORMANCE;
    }

    return $self->handleError( "Unknown format_type: '$type'", RPS::DB::Item::SaleImportError::kErrorFormatType );
}

sub saleDates {
    my $self = shift;

    my $startDate = $self->_getByFieldName('dateBegin') || '';
    my $endDate   = $self->_getByFieldName('dateEnd')   || '';

    unless ( $startDate && $endDate ) {
        $self->fail("Unable to determine sale dates from: '$startDate' and '$endDate'");
    }

    my $flipMonthDay = 0;
    # MM/DD/YY[YY] - 7/1/23, 7/31/23 OR DD/MM/YY[YY]
    if ( my ($m, $d, $y) = $endDate =~ /^(\d{1,2})\/(\d{1,2})\/(\d{2,4})$/ ) {
        if ( $m > 12 ) {
            ($m, $d) = ($d, $m);
            $flipMonthDay++;
        }
        $endDate = sprintf "20%02d-%02d-%02d", substr($y, -2), $m, $d;
    }
    # MM/DD/YY[YY] - 7/1/23, 7/31/23 OR DD/MM/YY[YY]
    if ( my ($m, $d, $y) = $startDate =~ /^(\d{1,2})\/(\d{1,2})\/(\d{2,4})$/ ) {
        if ( $flipMonthDay || $m > 12 ) {
            ($m, $d) = ($d, $m);
            $flipMonthDay++;
        }

        $startDate = sprintf "20%02d-%02d-%02d", substr($y, -2), $m, $d;
    }

    return $self->_getDates( date_begin => $startDate, date_end => $endDate );
}

sub artistName {
    my $self = shift;

    my $asset_artist = $self->_getByFieldName('_asset_artist');
    my $product_artist = $self->_getByFieldName('_product_artist');

    return ( ( $self->productType eq RPS::File::Sale::TYPE_TRACK ) ? $asset_artist : $product_artist );
}

sub countryCode {
    my $self = shift;

    my $country = $self->_getByFieldName('countryCode') || 'blank';
    my $oCountry = Common::Country->Get($country);
    return $oCountry->alpha2 if $oCountry;

    $self->handleError( "Unknown country code '$country'", RPS::DB::Item::SaleImportError::kErrorCountry );
    return $country;
}

# digital
sub price     { abs( shift->_getByFieldName('price') || 0 ) }
sub unitPrice { abs shift->SUPER::unitPrice }
sub units {
    my $self = shift;

    my $asset_q = $self->_getByFieldName('_asset_quantity');
    my $product_q = $self->_getByFieldName('_product_quantity');
    my $units = ( $self->productType eq RPS::File::Sale::TYPE_TRACK ? $asset_q : $product_q ) || 0;
    my $price = $self->_getByFieldName('price') || 0;

    if ( $price > 0 ) {
        $units = $units ? abs($units) : 1;
    } elsif ( $price < 0 ) {
       $units = $units ? -1 * abs($units) : -1;
    }

    return $units;
}

sub _isValidSaleRecord {
    my $self = shift;

    my $formatType = $self->_getByFieldName('formatType') || '';
    if ($formatType =~ /^Other(?:s)?$/i) {
        $self->fail("Unknown product format: 'Other'.");
    }

    return 1;
}

# mapFace
sub _mapFaceProductType { }
sub _mapFaceServiceID   { 'serviceID' }
sub _mapFaceCountryCode { 'countryCode' }
sub _mapFaceFormatType  { 'formatType' }
sub _mapFaceMediaType   { 'mediaType' }


1;