package RPS::Import::FunMobility;

use strict;

use Date::Calc qw(Days_in_Month Add_Delta_Days Decode_Month);

use lib '/app/tools/common/lib';
use Common::Consts qw(%COUNTRY_CODE);

use lib '/app/tools/data_classes/lib';

use lib '/app/tools/rps/lib';
use RPS::File::Sale;
use RPS::Import::Importer;
use base 'RPS::Import::Importer';

my %fieldMap = (
    1 => {
        date_row => 2,     # C
        date_col => 1,     # B
        service  => 0,     # A
        title    => 1,     # B
        artist   => 2,     # C
        units    => 3,     # D
        catalog  => 7,     # H
        price    => 11,    # L
        upc      => 12,    # M
        isrc     => 15,    # P
    },
    2 => {
        date_row     => 12,    # M
        date_col     => 7,     # H
        upc_isrc     => 4,     # E
        title_artist => 10,    # K
        units        => 15,    # P
        price        => 17,    # R
    },
    3 => {
        date_row => 6,         # G
        date_col => 6,         # G
        upc      => 11,        # L
        isrc     => 12,        # M
        title    => 1,         # B
        artist   => 2,         # C
        service  => 0,         # A
        units    => 3,         # D
        catalog  => 6,         # G
        price    => 10,        # K

    },
    4 => {
        date_row => 11,        # 12
        date_col => 0,         # A
        service  => 0,         # A
        title    => 1,         # B
        artist   => 2,         # C
        upc      => 11,        # L
        isrc     => 12,        # M
        units    => 6,         # G
        price    => 10,        # K

    },
);

#public methods

sub _importLines {
    my $self        = shift;
    my %args        = @_;
    my $fileObj     = $args{file};
    my $version     = $args{file}->VersionNum();
    my $fileName    = $args{file}->OrigFileName();
    my $serviceID   = $args{file}->ServiceID;
    my $sheet_count = 0;

    return undef unless ( defined $args{sheets} && defined $version );

    my $offsets      = $fieldMap{$version};
    my $sheet_names  = $args{sheet_names};
    my $header_found = 0;
    my $linenum      = 1;

    foreach my $sheet ( @{ $args{sheets} } ) {
        $linenum = 1;
        if ( $sheet_names->[$sheet_count] !~ /summary/i ) {
            my ( $dateBegin, $dateEnd ) = _getDates( $sheet->[ $offsets->{date_row} ]->[ $offsets->{date_col} ] );

            foreach my $line (@$sheet) {
                my $country  = "US";
                my $currency = "USD";
                my $product  = RPS::File::Sale::TYPE_TRACK;
                my $format   = RPS::File::Sale::FORMAT_RINGTONE;
                my ( $artist, $title, $upc, $isrc, $service, $catalog );

                if ( $version != 2 ) {
                    $service = $line->[ $offsets->{service} ];
                    $catalog = $line->[ $offsets->{catalog} ];
                    $artist  = $line->[ $offsets->{artist} ];
                    $title   = $line->[ $offsets->{title} ];
                    $upc     = $line->[ $offsets->{upc} ];
                    $isrc    = $line->[ $offsets->{isrc} ];
                    $upc =~ s/\-//g;
                    $isrc =~ s/\-//g;
                } elsif ( $version == 2 ) {
                    $line->[ $offsets->{upc_isrc} ] =~ s/\-//g;
                    ( $title, $artist ) = split( " - ", $line->[ $offsets->{title_artist} ] );
                    ( $upc,   $isrc )   = split( /\|/,  $line->[ $offsets->{upc_isrc} ] );
                }
                my $units = $line->[ $offsets->{units} ];
                my $price = $line->[ $offsets->{price} ];
                $price =~ s/\$//;
                $price /= $units if ( $units != 0 );

                if (   $units
                    && $country
                    && $price
                    && $title
                    && $title ne "Title"
                    && $title ne "Name"
                    && $title ne "Total:"
                    && $units ne "Sales" ) {

                    my $service_id = $self->getServiceID( lc($service) ) if ( defined $offsets->{service} );

                    unless ( defined $dateBegin && defined $dateEnd ) {
                        print STDERR "Couldn't get dates from: " . $sheet->[ $offsets->{date_row} ]->[ $offsets->{date_col} ] . "\n";
                        $self->errstr( "couldn't get dates from: " . $sheet->[ $offsets->{date_row} ]->[ $offsets->{date_col} ] );
                        return undef;
                    }

                    my $sale = RPS::Import::SaleRec->new();

                    $sale->mediaType(2) if ( $format =~ /video/i );
                    $sale->productType($product);
                    $sale->dateBegin($dateBegin);
                    $sale->dateEnd($dateEnd);
                    $sale->isrc($isrc);
                    $sale->upc($upc);
                    $sale->artistName($artist);
                    $sale->trackName($title);
                    $sale->formatType($format);
                    $sale->serviceID($service_id)     if ( defined $offsets->{service} );
                    $sale->serviceProductID($catalog) if ( defined $offsets->{catalog} );
                    $sale->units($units);
                    $sale->price($price);
                    $sale->countryCode($country);
                    $sale->currencyCode($currency);
                    $sale->lineNum($linenum);

                    $self->_insertSale( sale => $sale );
                } elsif ( $version == 2 && $line->[2] =~ /(Jan|Feb|Mar|Apr|May|Jun|Jul|Aug|Sep|Oct|Nov|Dec)/ ) {
                    my $year = $dateBegin;
                    $year =~ s/\-.*$//;
                    $dateBegin = $year . "-" . sprintf( "%02d", Decode_Month( $line->[2] ) ) . "-01";
                    $dateEnd =
                        $year . "-"
                      . sprintf( "%02d", Decode_Month( $line->[2] ) ) . "-"
                      . Days_in_Month( $year, Decode_Month( $line->[2] ) );
                }

                #else { print STDERR "skip l:" . $linenum . " - c:".$country." u:".$units." p:".$price." t:".$title."\n"; }
                $linenum++;
            }
        }
        $sheet_count++;
    }
    return $linenum;
}

#
# Private methods
#

sub _getDates {
    my ( $year, $qtr, $passed_date, $dateBegin, $dateEnd );
    $passed_date = shift;

    #print STDERR "|>".$passed_date."<|\n";
    if ( $passed_date =~ m/(\d+)\D(\d+)\D(\d{4}) \- (\d+)\D(\d+)\D(\d{4})/ ) {
        return ( $3 . "-" . sprintf( "%02d", $1 ) . "-" . sprintf( "%02d", $2 ),
            $6 . "-" . sprintf( "%02d", $4 ) . "-" . sprintf( "%02d", $5 ) );
    } elsif ( $passed_date =~ m/Q(\d) (\d{4})/ ) {
        $year = $2;
        $qtr  = $1;
    }
    if ( $year && $qtr ) {
        if ( $qtr == 1 ) {
            $dateBegin = $year . "-01-01";
            $dateEnd = $year . "-03-" . Days_in_Month( $year, 3 );
        } elsif ( $qtr == 2 ) {
            $dateBegin = $year . "-04-01";
            $dateEnd = $year . "-06-" . Days_in_Month( $year, 6 );
        } elsif ( $qtr == 3 ) {
            $dateBegin = $year . "-07-01";
            $dateEnd = $year . "-09-" . Days_in_Month( $year, 9 );
        } elsif ( $qtr == 4 ) {
            $dateBegin = $year . "-10-01";
            $dateEnd = $year . "-12-" . Days_in_Month( $year, 12 );
        } else {
            return undef;
        }
        return ( $dateBegin, $dateEnd );
    }

    return undef;
}

###
1;    # Play nicely.
###