package RPS::Import::Inertia::v2;

use strict;
use warnings;

use lib '/app/tools/rps/lib';
use RPS::File::Sale;
use RPS::Import::ServiceMap;
use RPS::DB::Item::MediaType;
use lib '/app/tools/data_classes/lib';

use parent 'RPS::Import::ImporterMixed';

sub physical { 2 }

sub _fieldMapExtended {
    {
        mixed => {
            option1 => {
               countryCode     => 'E',
                dateBegin      => 'F',
                dateEnd        => 'F',
                productType    => 'I',
                formatType     => 'V',
                upc            => 'A',
                albumName      => 'C',
                artistName     => 'D',
                isrc           => 'A',
                trackName      => 'C',
                units          => 'Q',
                currencyCode   => 'S',
                price          => 'R',
                totalRevenue   => 'R',
                priceLevel     => 'H',
                mediaType      => 'I',
                wholesalePrice => 'K',
                retailPrice    => 'L'
            },
         },
    };
}

sub _unverifiedFieldMapExtended {
    {
        mixed => {
            option1 => {
                _distChan => 'G',
                netUnits  => "Q"
            },
        }
    };
}

sub _headerIdentifierExtended {
    {
        mixed => {
            option1 => {
                upc => 'Product Code',
            },
        },
    };
}
my %services = (
	"3RD" => 'error',
	AMUS => Client::Service::DSP_AMAZON,
	DEEZ => Client::Service::DSP_DEEZER,
	GLCK => Client::Service::DSP_GOOGLE,
	GSUB => Client::Service::DSP_GOOGLE,
	GTRN => Client::Service::DSP_GOOGLE,
	ITCL => Client::Service::DSP_ITUNES_CLOUD,
	ITUN => Client::Service::DSP_ITUNES,
	PHY  => Client::Service::DSP_INERTIA,
	PPCA => Client::Service::DSP_PPCA,
	SPOT => Client::Service::DSP_SPOTIFY,
	YOUT => Client::Service::DSP_YOUTUBE
);
sub channel {RPS::File::Sale::CHANNEL_RETAIL}

sub serviceID {
    my $self = shift;

    return Client::Service::DSP_INERTIA unless $self->isDigitalProduct($self->productType);

    my $service = $self->_getByFieldName('_distChan');

    my $service_id = $services{$service};
    return $service_id if ($service_id && $service_id ne 'error');

    return $self->fail("Cannot determine service id from: $service");
}

sub countryCode {
    my $self = shift;

    my $name = $self->_getByFieldName('countryCode') || '';
    my $country = Common::Country->Get($name);
    return $country ? $country->alpha2 : undef ;
}

sub priceLevel {
    my $self = shift;

    my $price_level = $self->_getByFieldName('priceLevel') || '';
    return RPS::File::Sale::PLEVEL_FULL if ($price_level =~ /^fp$/i);
}

sub saleDates {
    my $self = shift;

    my $dt = $self->_getDateBegin() || '';
    $dt = 0 . $dt if (length($dt) < 8);

    return $self->_getDates( date_begin => $dt, type => 'eur' );
}

sub productType {
    my $self = shift;

    my $type = $self->_getByFieldName('productType') || '';
    my $product_code = $self->_getByFieldName('upc') || '';

    if ($type =~ /^lp$/i) {
        return RPS::File::Sale::TYPE_LP;
    }
    elsif ( $type =~ /^ad$/i ) {
        return RPS::File::Sale::TYPE_ALBUM;
    } elsif ( $type =~ /^td$/i ) {
        if ( $product_code =~ /^[a-z]/i) {
            return RPS::File::Sale::TYPE_TRACK;
        }
        elsif ( $product_code =~ /^\d/) {
            return RPS::File::Sale::TYPE_ALBUM;
        }
    }

    $self->fail( "Unable to determine product_type from: '$type' and product_code '$product_code'." );
}

sub formatType {
    my $self = shift;

    my $type = $self->_getByFieldName('formatType') || '';
    my $dist_chan = $self->_getByFieldName('_distChan') || '';

    return RPS::File::Sale::FORMAT_PERFORMANCE if ($dist_chan =~ /^PPCA$/i);
    return RPS::File::Sale::FORMAT_STREAM if $type < 0.20;
    return RPS::File::Sale::FORMAT_DOWNLOAD if $type >= 0.20;

    $self->fail( "Unable to determine format_type from: '$type'. DistChan: '$dist_chan'." );
}

sub upc {
    my $self = shift;

    if (!$self->isDigitalProduct($self->productType) ||
        $self->productType() eq RPS::File::Sale::TYPE_ALBUM) {
        return $self->_getByFieldName('upc');
    }
}

sub isrc {
    my $self = shift;

    return $self->_getByFieldName('isrc') if ($self->productType() eq RPS::File::Sale::TYPE_TRACK);
}
sub albumName {
    my $self = shift;

    if (!$self->isDigitalProduct($self->productType) ||
        $self->productType() eq RPS::File::Sale::TYPE_ALBUM) {
        return $self->_getByFieldName('albumName');
    }
}

sub trackName {
    my $self = shift;

    if ($self->productType() eq RPS::File::Sale::TYPE_TRACK) {
        return $self->_getByFieldName('trackName');
    }
}
sub mediaType {
    my $self = shift;

    my $type = $self->_getByFieldName('mediaType') || '';
    if ($type =~ /^ad|lp|td$/i) {
        return RPS::DB::Item::MediaType::kMediaTypeAudio;
    }

    $self->fail( "Unable to determine media type from: '$type'." );
}

sub price     { abs( shift->_getByFieldName('price') || 0 ) }
sub units {
    my $self = shift;

    my $units = $self->netUnits;
    my $price = $self->_getByFieldName('price') || 0;

    return $price < 0 ? abs($units) * -1 : $units;
}
sub unitPrice { abs shift->SUPER::unitPrice }

sub netUnits       { sprintf "%.0f", ( shift->_getByFieldName('netUnits') || 0 ) }
sub totalRevenue   { $_[0]->_getByFieldName('totalRevenue')               || 0 }
sub sales          { $_[0]->netUnits     > 0 ? $_[0]->netUnits         : 0 }
sub salesRevenue   { $_[0]->totalRevenue > 0 ? $_[0]->totalRevenue     : 0 }
sub returns        { $_[0]->netUnits     < 0 ? abs $_[0]->netUnits     : 0 }
sub returnsRevenue { $_[0]->totalRevenue < 0 ? abs $_[0]->totalRevenue : 0 }

1;