package RPS::Import::Kontor::v6;

use strict;
use warnings;

use lib '/app/tools/common/lib';
use Date::Calc qw(Days_in_Month);

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;

use parent qw/RPS::Import::MapFaceBase RPS::Import::ImporterMixed/;

sub physical { 2 }

sub _fieldMapExtended {
    {
        digital => {
            option1 => {
                labelName   => 'F',
                serviceID   => 'B',
                countryCode => 'E',
                dateBegin   => 'A',
                dateEnd     => 'A',
                productType => 'G',
                formatType  => 'C',
                artistName  => 'I',
                upc         => 'J',
                albumName   => 'H',
                isrc        => 'L',
                trackName   => 'H',
                units       => 'P',
                price       => 'O',
            },
         },
    };
}

sub _unverifiedFieldMapExtended { {} }

sub _headerIdentifierExtended {
    {
        digital => {
            option1 => {
                upc => 'EAN',
            },
        },
    };
}

sub currencyCode { 'EUR' }
sub mediaType     { RPS::DB::Item::MediaType::kMediaTypeAudio }

sub serviceID {
    my $self = shift;

    my $service = lc( $self->_getByFieldName('serviceID') || '' );

    my $serviceID = $self->getServiceID($service) || $RPS::Import::ServiceMap::SERVICE_ALIASES{$service};
    return $serviceID if $serviceID;

    $self->handleError( "Unknown service: '$service'", RPS::DB::Item::SaleImportError::kErrorService );
}

sub countryCode {
    my $self = shift;

    my $name = $self->_getByFieldName('countryCode') || '';
    my $oCountry = Common::Country->Get($name);
    return $oCountry ? $oCountry->alpha2 : undef ;
}

sub saleDates {
    my $self = shift;

    my $date = $self->_getByFieldName('dateBegin') || '';
    if ( my ($year, $month) = $date =~ /^(\d{4})(\d{2})$/i ) {
        return
            sprintf("%04d-%02d-%02d", $year, $month, 1),
            sprintf("%04d-%02d-%02d", $year, $month, Days_in_Month( $year, $month ) ),
    }

     $self->fail( "Unable to determine dates from: '$date'.");
}

sub productType {
    my $self = shift;

    my $type = $self->_getByFieldName('productType') || '';
    return RPS::File::Sale::TYPE_ALBUM if $type =~ /^album$/i;
    return RPS::File::Sale::TYPE_TRACK if $type =~ /^track$/i;

    $self->fail( "Unable to determine product_type from: '$type'." );
}

sub formatType {
    my $self = shift;

    my $type = $self->_getByFieldName('formatType') || '';
    return RPS::File::Sale::FORMAT_STREAM   if $type =~ /^streaming|social.+$/i;
    return RPS::File::Sale::FORMAT_DOWNLOAD if $type =~ /^download$/i;

    $self->fail( "Unable to determine format_type from: '$type'." );
}

sub albumName {
    my $self = shift;

    return $self->productType eq RPS::File::Sale::TYPE_ALBUM
        ? $self->_getByFieldName('albumName')
        : undef;
}

sub trackName {
    my $self = shift;

    return $self->productType eq RPS::File::Sale::TYPE_TRACK
        ? $self->_getByFieldName('trackName')
        : undef;
}

sub units {
    my $self = shift;

    my $units = $self->_getByFieldName('units') || 0;
    my $price = $self->_getByFieldName('price') || 0;

    $units =~ s/,//g;

    if ( $price > 0 ) {
        $units = $units ? abs($units) : 1;
    } elsif ( $price < 0 ) {
        $units = $units ? -1 * abs($units) : -1;
    }

    return $units;
}

sub _isValidSaleRecord {
    my $self = shift;

    return ( $self->_getByFieldName('price') || $self->units ) && ( $self->trackName || $self->albumName );
}

sub _mapFaceServiceID   { 'serviceID' }
sub _mapFaceProductType { 'productType'}
sub _mapFaceCountryCode { 'countryCode' }
sub _mapFaceFormatType  { 'formatType' }
sub _mapFaceMediaType   { 'mediaType' }

1;