package RPS::Import::LooseMusic::v1;

use strict;
use warnings;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;

use parent 'RPS::Import::ImporterMixed';

sub physical { 2 }

sub _fieldMapExtended {
    {
        mixed => {
            option1 => {
                serviceID       => 'U',
                countryCode     => 'E',
                dateBegin       => 'F',
                dateEnd         => 'F',
                formatType      => 'I',
                clientProductID => 'A',
                artistName      => 'D',
                upc             => 'B',
                albumName       => 'C',
                isrc            => 'A',
                trackName       => 'C',
                units           => 'Q',
                priceLevel      => 'H',
                currencyCode    => 'S',
                totalRevenue    => 'T',
                price           => 'T',
                mediaType       => 'I',
            },
        },
    };
}

sub _unverifiedFieldMapExtended {
    {
        mixed => {
            option1 => {
                _productTypePhys => 'I',
                _productTypeDig  => 'B',
                _netUnits        => 'Q',
            },
        },
    };
}

sub _headerIdentifierExtended {
    {
        mixed => {
            option1 => {
                upc => 'Barcode',
            },
        },
    };
}

sub serviceID {
    my $self = shift;

    my $service = lc( $self->_getByFieldName('serviceID') || '' );
    my $serviceID = $self->getServiceID($service) || $RPS::Import::ServiceMap::SERVICE_ALIASES{$service};
    return $serviceID if $serviceID;

    $self->fail("Unknown service: $service");
}

sub countryCode {
    my $self = shift;

    my $name = $self->_getByFieldName('countryCode') || '';
    my $oCountry = Common::Country->Get($name);
    return $oCountry->alpha2() if $oCountry;
}

sub saleDates {
    my $self = shift;

    # DDMMYYYY
    my $dateBegin = $self->_getByFieldName('dateBegin') || '';
    $dateBegin = sprintf "%08d", $dateBegin if $dateBegin;

    unless ( $dateBegin =~ /(\d{2})(\d{2})(\d{4})/ ) {
        $self->fail( "Unable to determine date from: '$dateBegin'." );
    }

    $dateBegin = sprintf "%04d-%02d-%02d", $3, $2, $1;
    return $self->_getDates( date_begin => $dateBegin );
}

sub productType {
    my $self = shift;

    my $typePhys = $self->_getByFieldName('_productTypePhys') || '';
    $typePhys =~ s/['\s]//g;

    # physical
    return RPS::File::Sale::TYPE_CD if $typePhys =~ /^CD$/i;
    return RPS::File::Sale::TYPE_LP if $typePhys =~ /^LP2?$/i;

    # digital
    my $typeDig = $self->_getByFieldName('_productTypeDig')  || '';
    return $typeDig ? RPS::File::Sale::TYPE_ALBUM : RPS::File::Sale::TYPE_TRACK;
}

sub formatType {
    my $self = shift;

    my $type = $self->_getByFieldName('formatType') || '';
    return RPS::File::Sale::FORMAT_DOWNLOAD if $type =~ /^DA|DD$/i;
    return RPS::File::Sale::FORMAT_STREAM   if $type =~ /^AV|STR$/i;

    $self->fail( "Unable to determine format_type from: '$type'." );
}

sub clientProductID {
    return $_[0]->productType eq RPS::File::Sale::TYPE_ALBUM
        ? $_[0]->_getByFieldName('clientProductID')
        : undef;
}

sub albumName {
    return $_[0]->productType eq RPS::File::Sale::TYPE_ALBUM
        ? $_[0]->_getByFieldName('albumName')
        : undef;
}

sub isrc {
    return $_[0]->productType eq RPS::File::Sale::TYPE_TRACK
        ? $_[0]->_getByFieldName('isrc')
        : undef;
}

sub trackName {
    return $_[0]->productType eq RPS::File::Sale::TYPE_TRACK
        ? $_[0]->_getByFieldName('trackName')
        : undef;
}

sub priceLevel {
    return ( $_[0]->_getByFieldName('priceLevel') || '' ) =~ /^FP$/i
        ? RPS::File::Sale::PLEVEL_FULL
        : undef;
}

sub mediaType {
    my $self = shift;

    my $type = $self->_getByFieldName('mediaType') || '';
    if ( $type =~ /^AV$/i ) {
        return RPS::DB::Item::MediaType::kMediaTypeVideo;
    }
    elsif ( $type =~ /^CD|DA|DD|LP|LP2|STR$/i ) {
        return RPS::DB::Item::MediaType::kMediaTypeAudio;
    }

    $self->fail( "Unable to determine media_type from: '$type'." );
}

# digital
sub price     { abs( shift->_getByFieldName('price') || 0 ) }
sub unitPrice { abs shift->SUPER::unitPrice }
sub units {
    my $units = $_[0]->_getByFieldName('units') || 0;
    my $price = $_[0]->_getByFieldName('price') || 0;
    return $price < 0 ? abs($units) * -1 : $units;
}

# physical
sub channel            { RPS::File::Sale::CHANNEL_RETAIL }
sub netUnits           { $_[0]->_getByFieldName('_netUnits')    || 0 }
sub totalRevenue       { $_[0]->_getByFieldName('totalRevenue') || 0 }
sub sales              { $_[0]->netUnits     > 0 ? $_[0]->netUnits         : 0 }
sub salesRevenue       { $_[0]->totalRevenue > 0 ? $_[0]->totalRevenue     : 0 }
sub returns            { $_[0]->netUnits     < 0 ? abs $_[0]->netUnits     : 0 }
sub returnsRevenue     { $_[0]->totalRevenue < 0 ? abs $_[0]->totalRevenue : 0 }
sub _isValidSaleRecord {
    return ( $_[0]->_getByFieldName('trackName') || $_[0]->_getByFieldName('albumName') )
    && defined $_[0]->netUnits
}


1;