package RPS::Import::MacBlk::v1;

use strict;
use warnings;
use POSIX qw(floor);

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;

use parent 'RPS::Import::ImporterMixed';

use Date::Calc qw(Add_Delta_Days Days_in_Month);

sub physical { 0 }

sub _fieldMapExtended {
    {
        digital => {
            option1 => {
                labelName    => 'F',
                serviceID    => 'D',
                countryCode  => 'E',
                dateBegin    => 'C',
                formatType   => 'D',
                artistName   => 'G',
                upc          => 'L',
                isrc         => 'K',
                trackName    => 'H',
                units        => 'N',
                currencyCode => 'P',
                price        => 'O',
            },
         },
    };
}
sub _unverifiedFieldMapExtended {
    {
        digital => {
            option1 => {
                _release_title => 'I',
            },
        },
    };
}

sub _headerIdentifierExtended {
    {
        digital => {
            option1 => {
                upc => 'upc',
            },
        },
    };
}

sub mediaType { RPS::DB::Item::MediaType::kMediaTypeAudio }

sub saleDates {
    my $self = shift;

    my $dt = $self->_getByFieldName('dateBegin') || '';

    # MMYY or MYY
    if ( $dt =~ /^(\d{1,2})(\d{2})$/ ) {
        return (
            sprintf( "%04d-%02d-%02d", "20$2", $1, 1 ),
            sprintf( "%04d-%02d-%02d", "20$2", $1, Days_in_Month( "20$2", $1 ) )
        );
    }
    # YYYYMM
    elsif ( $dt =~ /^(\d{4})(\d{2})$/ ) {
        return (
            sprintf( "%04d-%02d-%02d", $1, $2, 1 ),
            sprintf( "%04d-%02d-%02d", $1, $2, Days_in_Month( $1, $2 ) )
        );
    }

    $self->fail("Unable to determine date begin from '$dt'.");
}

sub serviceID {
    my $self = shift;

    my $service = lc( $self->_getByFieldName('serviceID') || '' );
    my $serviceID = $self->getServiceID($service) || $RPS::Import::ServiceMap::SERVICE_ALIASES{$service};
    return $serviceID if $serviceID;

    $self->fail("Unable to determine service from: '$service'");
}

sub countryCode {
    my $self = shift;

    my $country = $self->_getByFieldName('countryCode') || '';
    return 'TL' if $country =~ /^TP$/i;

    $country = 'US' if !$country || $country =~ /^(?:nan?|None|-)$/i;
    my $oCountry = Common::Country->Get($country) if $country;
    return $oCountry->alpha2 if $oCountry;

    $self->fail( "Unable to determine country code from: '$country'." );
}

sub productType {
    my $self = shift;

    if ( $self->formatType eq RPS::File::Sale::FORMAT_STREAM ) {
        return RPS::File::Sale::TYPE_TRACK;
    }

    if ( $self->formatType eq RPS::File::Sale::FORMAT_PERFORMANCE ) {
        return RPS::File::Sale::TYPE_TRACK;
    }

    if ( $self->formatType eq RPS::File::Sale::FORMAT_DOWNLOAD ) {
        return RPS::File::Sale::TYPE_ALBUM if $self->upc && !$self->isrc;
        return RPS::File::Sale::TYPE_TRACK if $self->isrc;
    }

    $self->fail("Unable to determine product type in line: " . $self->linenum . ".");
}

sub formatType {
    my $self = shift;

    my $type = $self->_getByFieldName('formatType') || '';

    return RPS::File::Sale::FORMAT_DOWNLOAD
        if $type =~ /^(?:
            amazonmp3|amazonmp3JP|googledownload|itunes
        )$/ix;

    return RPS::File::Sale::FORMAT_STREAM
        if $type =~ /^(?:
            aba-alibaba|amazonprimeFOR|amazonprimeFORJP|amazonprimedom|amazonprimedomjp|
            amazonunlimitedDOMJP|amazonunlimitedFOR|amazonunlimitedDOM|
            applecloud|applemusic|awa-awa|
            dzr-deezer|ejb-electric-jukebox|googlesubscription|
            kbx-kkbox|scu-soundcloud|slk-slacker|spo-spotify|
            tiktok|tme-tencent|uma-adjustment|uma-uma|
            vvo-vevo|ydx-yandex|youtube|youtubered|
            stb-soundtrack-your-brand|ncm-netease-cloud-music|dst-dubset|boo-boomplay|
            tiktok-adjustment|svn-saavn|svn-adjustment|multitracks|res-resso|trl-triller|
            youtube-adj|youtubeaudio|amazonprime|amazonunlimited|tidal|tiktok-add|snp-snap|
            kbx-kkbox-add|dzr-deezer-adj|svn-saavn-add|uma-uma-vk
        )$/ix;

    return RPS::File::Sale::FORMAT_PERFORMANCE
        if $type =~ /^(?:
            iht-iheart|iht-ihearts|pnd-pandora|soundexchange|siriusxm
        )$/ix;

    $self->fail("Unable to determine format type from '$type'.");
}

sub upc {
    my $self = shift;

    my $upc = $self->_getByFieldName('upc') || 'na';
    return $upc if $upc !~ /^nan?$/i;
}

sub isrc {
    my $self = shift;

    my $isrc = $self->_getByFieldName('isrc') || 'na';
    return $isrc if $isrc !~ /^nan?$/i;
}

sub albumName {
    my $self = shift;

    my $releaseTitle = $self->_getByFieldName('_release_title') || '';
    $releaseTitle = '' if $releaseTitle =~ /^nan?$/;
    return $releaseTitle if $releaseTitle;

    my $albumName = $self->_getByFieldName('trackName') || '';
    $albumName = '' if $albumName =~ /^nan?$/;
    return $albumName if $self->productType eq RPS::File::Sale::TYPE_ALBUM;
}

sub trackName {
    my $self = shift;

    my $trackName = $self->_getByFieldName('trackName') || '';
    $trackName = '' if $trackName =~ /^nan?$/;
    return $trackName if $self->productType eq RPS::File::Sale::TYPE_TRACK;
}

sub price     { sprintf "%.8f", abs( shift->_getByFieldName('price') || 0 ) }
sub unitPrice { abs shift->SUPER::unitPrice }
sub units {
    my $self = shift;

    my $units = $self->_getByFieldName('units') || 0;
    my $price = $self->_getByFieldName('price') || 0;
    $units = floor($units + 0.5);

    if ( $price > 0 ) {
        $units = $units ? abs($units) : 1;
    } elsif ( $price < 0 ) {
       $units = $units ? -1 * abs($units) : -1;
    }

    return $units;
}

sub _isValidSaleRecord {
    my $self = shift;

    return (defined $self->units || defined $self->price) && $self->serviceID;
}


1;