#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2009 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------

package RPS::Import::Masterbeat;

use strict;

use Date::Calc qw(Days_in_Month Add_Delta_Days Decode_Month);

use lib '/app/tools/rps/lib';
use RPS::Import::SaleRec;
use RPS::DB::Item::Client;

use lib '/app/tools/common/lib';
use Common::Consts;
use Common::Assert;
use Common::Log;

use lib '/app/tools/data_classes/lib';

use lib '/app/tools/rps/lib';
use RPS::DB::Item::MediaType;
use RPS::File::Sale;

use Data::Dumper;

use lib '/app/tools/rps/lib';
use RPS::Import::Importer;
use base 'RPS::Import::Importer';

my %fieldMap = (
    1 => {
        artist       => 6,
        catalog_id   => 5,
        upc          => 3,
        album_name   => 0,
        isrc         => 4,
        track_name   => 2,
        units        => 8,
        product_type => 1,
        net_price    => 9,
    },
);

my %gProductTypeMap = (
    't' => {
        productType => RPS::File::Sale::TYPE_TRACK,
        formatType  => RPS::File::Sale::FORMAT_DOWNLOAD,
        mediaType   => RPS::DB::Item::MediaType::kMediaTypeAudio,
    },
    'r' => {
        productType => RPS::File::Sale::TYPE_ALBUM,
        formatType  => RPS::File::Sale::FORMAT_DOWNLOAD,
        mediaType   => RPS::DB::Item::MediaType::kMediaTypeAudio,
    },
);

#public methods

sub _importLines {
    my $self        = shift;
    my %args        = @_;
    my $fileObj     = $args{file};
    my $version     = $args{file}->VersionNum();
    my $fileName    = $args{file}->OrigFileName();
    my $serviceID   = $args{file}->ServiceID;
    my $sheet_count = 0;

    assert( defined $args{sheets} );
    assert( defined $version );

    my $offsets     = $fieldMap{$version};
    my $sheet_names = $args{sheet_names};
    my $sheets      = $args{sheets};
    my $linenum     = 1;

    for ( my $sheetIndex = 0 ; $sheetIndex < scalar @{ $args{sheets} } ; $sheetIndex++ ) {
        my $sheet = $sheets->[$sheetIndex];

        my ( $startDate, $endDate ) = $self->_getReportDates($sheet);

        my $foundHeader = 0;
        for ( my $lineIndex = 0 ; $lineIndex < scalar @$sheet ; $lineIndex++ ) {
            $linenum = $lineIndex + 1;
            my $line = $sheet->[$lineIndex];

            if ( !$foundHeader ) {
                if ( 'Release or Track' eq $line->[ $offsets->{product_type} ] ) {
                    $foundHeader = 1;
                }
                next;
            }

            my $country      = 'US';
            my $currencyCode = 'USD';

            my $productType;
            my $format;
            my $mediaType;

            my $mapping = $gProductTypeMap{ lc( $line->[ $offsets->{product_type} ] ) };
            if ($mapping) {
                $productType = $mapping->{productType};
                $format      = $mapping->{formatType};
                $mediaType   = $mapping->{mediaType};
            }

            my $trackTitle = $line->[ $offsets->{track_name} ];
            my $albumTitle = $line->[ $offsets->{album_name} ];

            my $upc      = $line->[ $offsets->{upc} ];
            my $isrc     = $line->[ $offsets->{isrc} ];
            my $artist   = $line->[ $offsets->{artist} ];
            my $units    = $line->[ $offsets->{units} ];
            my $netPrice = $line->[ $offsets->{net_price} ];

            # Probably wise to allow for blank lines...
            #
            if ( $units && $artist && ( $albumTitle || $trackTitle ) ) {
                my ( $dateBegin, $dateEnd ) = $self->_getDates( date_begin => $startDate, date_end => $endDate, type => 'us' );

                my $unitPrice = $netPrice / $units;

                my $sale = RPS::Import::SaleRec->new();

                $sale->mediaType($mediaType);
                $sale->productType($productType);
                $sale->formatType($format);
                $sale->dateBegin($dateBegin);
                $sale->dateEnd($dateEnd);
                $sale->trackName($trackTitle);
                $sale->albumName($albumTitle);
                $sale->artistName($artist);
                $sale->upc($upc);
                $sale->isrc($isrc);
                $sale->units($units);
                $sale->price($unitPrice);
                $sale->countryCode($country);
                $sale->currencyCode($currencyCode);
                $sale->lineNum($linenum);

                $self->_insertSale( sale => $sale );
            }
        }
    }

    return $linenum;
}

sub _getReportDates {
    my $self  = shift;
    my $sheet = shift;

    my $cell = $sheet->[0]->[1] || return;

    $cell =~ /Report Timeframe: (\d{1,2}\/\d{1,2}\/\d{4})\s*-\s*(\d{1,2}\/\d{1,2}\/\d{4})/i;

    my $startDate = $1;
    my $endDate   = $2;

    return ( $startDate, $endDate );
}

###
1;    # Play nicely.
###