package RPS::Import::MerchNow::v2;

use strict;
use warnings;

use lib '/app/tools/rps/lib';
use parent 'RPS::Import::ImporterMixed';

sub physical { 2 }

sub _fieldMapExtended {
    {
        mixed => {
            option1 => {
                countryCode  => 'E',
                dateBegin    => 'J1',
                dateEnd      => 'L1',
                productType  => 'A',
                formatType   => 'A',
                artistName   => 'C',
                upc          => 'F',
                albumName    => 'C',
                units        => 'G',
                price        => 'M',
                mediaType    => 'A',
            },
         },
    };
}

sub _unverifiedFieldMapExtended {{}}

sub _headerIdentifierExtended {
    {
        mixed => {
            option1 => {
                upc => 'UPC',
            },
        },
    };
}


sub currencyCode { 'USD' }
sub serviceID    { Client::Service::DSP_MERCHNOW }

sub _preProcess {
    my $self = shift;
    my %args = @_;
    $self->SUPER::_preProcess(%args);
    foreach my $line(@{ $args{lines} }) {
        # J1 / L1
        if( !$self->{_startDate} && $line->[9] =~ /Start Date: (\d{2})\/(\d{2})\/(\d{4})/i ){
            $self->{_startDate} = sprintf( "%04d-%02d-%02d", $3, $1, $2);
        }
        if( !$self->{_endDate} && $line->[11] =~ /End Date: (\d{2})\/(\d{2})\/(\d{4})/i ){
            $self->{_endDate} = sprintf( "%04d-%02d-%02d", $3, $1, $2);
        }
    }
}

sub productType {
    my $self = shift;

    my $type = $self->_getByFieldName('productType') || "";

    return RPS::File::Sale::TYPE_ALBUM if ($type =~ /-DD/);

    $self->fail("Can't determine product type from: '$type'.");
}

sub formatType {
    my $self = shift;

    my $type = $self->_getByFieldName('formatType') || "";

    return RPS::File::Sale::FORMAT_DOWNLOAD if ($type =~ /-DD/);

    $self->fail("Can't determine format type from: '$type'.");
}

sub mediaType {
    my $self = shift;

    my $type = $self->_getByFieldName('mediaType') || "";

    return RPS::DB::Item::MediaType::kMediaTypeAudio, if ($type =~ /-DD/);

    $self->fail("Can't determine media type from: '$type'.");
}

sub countryCode {
    my $self  = shift;
    my $cname = $self->_getByFieldName('countryCode');
    my $code  = Common::Country->Get($cname);
    return ( defined $code ) ? $code->alpha2() : $cname;
}

sub artistName {
    my $self = shift;

    my ($name) = $self->_getByFieldName('artistName') =~ /^(.+?) -/;

    return $name if $name;
}

sub albumName {
    my $self = shift;

    my ($name) = $self->_getByFieldName('albumName') =~ /- (.+?)(?: -.*)?$/;

    return $name if $name;
}

sub price     { sprintf( "%.8f", abs( shift->_getByFieldName('price') || 0 )) }
sub unitPrice { abs shift->SUPER::unitPrice }
sub units {
    my $self = shift;

    my $units = $self->_getByFieldName('units') || 0;
    my $price = $self->_getByFieldName('price') || 0;

    if ( $price > 0 ) {
        $units = $units ? abs($units) : 1;
    } elsif ( $price < 0 ) {
       $units = $units ? -1 * abs($units) : -1;
    }

    return $units;
}

sub _isValidSaleRecord {
    return ($_[0]->_getByFieldName('albumName') || $_[0]->_getByFieldName('artistName')) &&
           ($_[0]->_getByFieldName('units') || $_[0]->_getByFieldName('price'));
}

1;