package RPS::Import::Merlin::v10;

use strict;

use lib '/app/tools/common/lib';
use Common::Date;

use lib '/app/tools/rps/lib';
use base 'RPS::Import::Importer';

use Data::Dumper;
use Date::Calc qw(Days_in_Month Decode_Month);

sub _headerIdentifier { ( upc => 'UPC' ) }

sub _fieldMap {
    {
        # Header
        formatType => 'C',
        dateBegin  => 'E',
        dateEnd    => 'F',

        # Detail
        labelName   => 'K',
        serviceID   => 'B',
        countryCode => 'B',

        productType => 'D',    # Sale configuration
        mediaType   => 'D',

        artistName => 'H',
        upc        => 'E',
        albumName  => 'J',
        isrc       => 'F',
        trackName  => 'I',

        #units            => '',
        #currencyCode     => '',
        price => 'U',
    };
}

sub _unverifiedFieldMap {
    {
        # Footer
        distFee => 'V',
    };
}

sub units { return 1; }

sub currencyCode { return "USD"; }

sub saleDates {
    my $self = shift;
    return ( $self->{_startDate}, $self->{_endDate} ) if ( $self->{_startDate} );    # from header; see _preProcess
}

sub serviceID {
    my $self = shift;
    return $self->{_serviceID};                                                      # from header; see _preProcess
}

sub formatType {
    my $self = shift;
    return $self->{_formatType};                                                     # from header; see _preProcess
}

sub trackName {
    my $self  = shift;
    my $title = $self->_getByFieldName('trackName');
    return ( $self->productType eq RPS::File::Sale::TYPE_TRACK ) ? $title : "";
}

sub productType {
    my $self = shift;
    my $type = $self->_getByFieldName('productType');
    if ( $type =~ /^(track|stream)$/i ) {
        return RPS::File::Sale::TYPE_TRACK;
    } elsif ( $type =~ /^(bundle)$/i ) {
        return RPS::File::Sale::TYPE_ALBUM;
    }
    $self->fail("Unable to determine product type from '$type'") if ($type);
}

sub mediaType {
    my $self = shift;

    my $type = $self->_getByFieldName('mediaType');
    if ( $type =~ /^(track|bundle|stream)$/i ) {
        return RPS::DB::Item::MediaType::kMediaTypeAudio;
    }

    $self->fail("Unknown media type '$type'");
}

sub price {
    my $self = shift;

    my $price = $self->_getByFieldName('price');

    $self->fail("Unable to determine distribution fee") unless ( $self->{_distFee} );

    my $distFee = $self->{_distFee};
    $distFee = ( 100 - $distFee ) * .01;
    $price *= $distFee;

    return $price;
}

sub _preProcess {
    my $self = shift;
    my %args = @_;

    Log->info("Starting _preProcess");
    $self->SUPER::_preProcess(%args);

    my $distFee;

    my $getDateFlag;          # set if we find a date header
    my $getFormatTypeFlag;    # set if we find a report type header
    my $getServiceFlag;       # set if we find a service header

    foreach my $line ( @{ $args{lines} } ) {

        $self->{line} = $line;

        # Get the date from the header
        #
        if ( !$getDateFlag && $self->_getByFieldName('dateBegin') =~ /report start date/i ) {
            $getDateFlag = 1;
        } elsif ( !$self->{_startDate} && $getDateFlag ) {
            my $dt = $self->_getByFieldName('dateBegin');

            if ( $dt =~ /^(\d{4})-(\d{2})-(\d{2})$/ )    # YYYY-MM-DD
            {
                $self->{_startDate} = sprintf( "%04d-%02d-%02d", $1, $2, 1 );

                #$self->{_endDate}   = sprintf( "%04d-%02d-%02d", $1, $2, Days_in_Month($1, $2) );

                my $endDate = $self->_getByFieldName('dateEnd');
                my ( $y, $m, $d ) = split( "-", $endDate );
                $self->{_endDate} = sprintf( "%04d-%02d-%02d", $y, $m, $d );
            } else {
                print STDERR "_preProcess: WARNING: Unable decode date '$dt'\n";
            }
        }

        # Get the report type from the header
        #
        if ( !$getFormatTypeFlag && $self->_getByFieldName('formatType') =~ /report type/i ) {
            $getFormatTypeFlag = 1;
        } elsif ( !$self->{_formatType} && $getFormatTypeFlag ) {
            my $format = $self->_getByFieldName('formatType');

            if ( $format =~ /^(streaming)$/i ) {
                $self->{_formatType} = RPS::File::Sale::FORMAT_STREAM;
            } elsif ( $format =~ /^(download)$/i ) {
                $self->{_formatType} = RPS::File::Sale::FORMAT_DOWNLOAD;
            } else {
                $self->fail("Unknown format type '$format'");
            }

        }

        # Get the service information from the header
        #
        if ( !$getServiceFlag && $self->_getByFieldName('serviceID') =~ /dsp \(url\)/i ) {
            $getServiceFlag = 1;
        } elsif ( !$self->{_serviceID} && $getServiceFlag ) {
            my $serviceData = $self->_getByFieldName('serviceID');
            my $serviceID;
            my $serviceName;

            if ( $serviceData =~ /(.+) (\(.+\))$/ ) {
                $serviceName = $1;
                $serviceID   = $self->getServiceID($serviceName);
            }

            $self->fail("Unable to determine service id from '$serviceData'") unless ($serviceID);

            $self->{_serviceID} = $serviceID;
        }

        # Get the distribution fee from the footer
        #
        $distFee = $self->_getByFieldName('distFee');

        if ( $distFee =~ /LESS Merlin ADMIN FEE \((.+?)%\)/ ) {
            $self->{_distFee} = $1;
            last;
        }
    }
}

###
1;    # Play nicely.
###