package RPS::Import::Merlin::v11;

use strict;

use lib '/app/tools/common/lib';
use Common::Date;

use lib '/app/tools/rps/lib';
use base 'RPS::Import::Importer';

use Data::Dumper;
use Date::Calc qw(Days_in_Month Decode_Month);

sub _headerIdentifier { ( upc => 'upc' ) }

sub _fieldMap {
    {
        labelName    => 'H',
        serviceID    => 'A',
        countryCode  => 'B',
        formatType   => 'N',
        mediaType    => 'M',
        artistName   => 'E',
        upc          => 'D',
        albumName    => 'G',
        isrc         => 'C',
        trackName    => 'F',
        units        => 'I',
        currencyCode => 'L',
        price        => 'K',
    };
}

sub _unverifiedFieldMap {
    {
        # Footer
        distFee => 'L',
    };
}

sub serviceID {
    my $self    = shift;
    my $service = $self->_getByFieldName('serviceID');

    my $serviceID;
    $serviceID = $self->getServiceID($service) if ($service);

    $self->fail("Unknown service '$service'") unless ($serviceID);

    return $serviceID;
}

sub saleDates {
    my $self = shift;

    return ( $self->{_startDate}, $self->{_endDate} ) if ( $self->{_startDate} );

    $self->fail("Unknown filename") unless ( $self->filename );

    unless ( $self->filename =~ /(\d{4})(\d{2})/ ) {
        $self->fail( "Could not determine period from filename '" . $self->filename . "'" );
    }

    my $startDate = sprintf( "%04d-%02d-%02d", $1, $2, 1 );

    ( $self->{_startDate}, $self->{_endDate} ) = $self->_getDates( date_begin => $startDate );

    return ( $self->{_startDate}, $self->{_endDate} );
}

sub formatType {
    my $self = shift;
    my $type = $self->_getByFieldName('formatType');
    if ( $type =~ /^(on-demand)$/i ) {
        return RPS::File::Sale::FORMAT_STREAM;
    }
    $self->fail("Unknown format type '$type'");
}

sub productType { return RPS::File::Sale::TYPE_TRACK; }

sub mediaType {
    my $self = shift;

    my $type = $self->_getByFieldName('mediaType');
    if ( $type =~ /^(audio)$/i ) {
        return RPS::DB::Item::MediaType::kMediaTypeAudio;
    }

    $self->fail("Unknown media type '$type'");
}

sub price {
    my $self = shift;

    my $price = $self->_getByFieldName('price');

    $self->fail("Unable to determine distribution fee") unless ( $self->{_distFee} );

    my $distFee = $self->{_distFee};
    $distFee = ( 100 - $distFee ) * .01;
    $price *= $distFee;

    return $price;
}

sub _preProcess {
    my $self = shift;
    my %args = @_;

    Log->info("Starting _preProcess");
    $self->SUPER::_preProcess(%args);

    my $distFee;

    foreach my $line ( @{ $args{lines} } ) {

        $self->{line} = $line;

        # Get the distribution fee from the footer
        #
        $distFee = $self->_getByFieldName('distFee');

        if ( $distFee =~ /LESS Merlin ADMIN FEE \((.+?)%\)/ ) {
            $self->{_distFee} = $1;
            last;
        }
    }
}

###
1;    # Play nicely.
###