package RPS::Import::Merlin::v2;

use strict;

use lib '/app/tools/data_classes/lib';
use Client::Service;

use lib '/app/tools/common/lib';
use Common::Date;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;
use base 'RPS::Import::Importer';

use Data::Dumper;

sub _headerIdentifier { ( upc => 'UPC' ) }

sub _fieldMap {
    {
        # Data
        labelName    => 'I',
        serviceID    => 'A',
        countryCode  => 'D',
        currencyCode => 'E',
        dateBegin    => 'B',
        dateEnd      => 'C',
        artistName   => 'K',
        upc          => 'G',
        isrc         => 'H',
        trackName    => 'L',
        units        => 'M',
        price        => 'Q',
        mediaType    => 'N',
    };
}

sub _unverifiedFieldMap {
    {
        # Footer
        distFee => 'R',
    };
}

sub productType { return RPS::File::Sale::TYPE_TRACK; }
sub formatType  { return RPS::File::Sale::FORMAT_STREAM; }

sub price {
    my $self = shift;

    my $price = $self->_getByFieldName('price');

    # Apply the distribution only if it was found in the footer;
    # Otherwise the user will have to enter it on the UI.
    #
    if ( $self->{_distFee} ) {
        my $distFee = $self->{_distFee};
        $distFee = ( 100 - $distFee ) * .01;
        $price *= $distFee;
    }

    return $price;
}

sub currencyCode {
    my $self         = shift;
    my $currencyCode = $self->_getByFieldName('currencyCode');

    $self->fail("Currency Code is not USD") unless ( $currencyCode eq 'USD' );

    return $currencyCode;
}

sub serviceID {
    my $self    = shift;
    my $service = $self->_getByFieldName('serviceID');

    $self->fail("Service name not defined") unless ($service);

    # case 15364
    if ( $service eq 'MOBILE' ) {
        $service = 'vevo';
    }

    my $serviceID = $self->getServiceID( lc($service) ) || $RPS::Import::ServiceMap::SERVICE_ALIASES{ lc $service };

    $self->fail("Unable to determine service id from '$service'") unless ($serviceID);

    return $serviceID;
}

sub mediaType {
    my $self = shift;
    if ( $self->serviceID() == Client::Service::DSP_VEVO ) {
        return RPS::DB::Item::MediaType::kMediaTypeVideo;
    } else {
        return RPS::DB::Item::MediaType::kMediaTypeAudio;
    }
}

sub _preProcess {
    my $self = shift;
    my %args = @_;

    Log->info("Starting _preProcess");
    $self->SUPER::_preProcess(%args);

    my $distFee;

    foreach my $line ( @{ $args{lines} } ) {
        $self->{line} = $line;
        $distFee = $self->_getByFieldName('distFee');

        if ( $distFee =~ /LESS Merlin ADMIN FEE \((.+?)%\)/ ) {
            $self->{_distFee} = $1;
            last;
        }
    }
}

###
1;    # Play nicely.
###