#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2013 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------

package RPS::Import::Merlin::v20;

use strict;

use Date::Calc qw(Days_in_Month Decode_Month);

use lib '/app/tools/common/lib';
use Common::Assert;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;

use base 'RPS::Import::Importer';

sub _fieldMap {
    {
        # header
        dateBegin => 'A',

        # detail
        serviceID    => 'A',
        countryCode  => 'C',
        currencyCode => 'N',
        labelName    => 'I',
        formatType   => 'P',
        artistName   => 'F',
        upc          => 'E',
        albumName    => 'H',
        isrc         => 'D',
        trackName    => 'G',
        units        => 'K',
        price        => 'M',
    };
}

sub _headerIdentifier { ( upc => 'EAN UPC' ) }

sub productType { RPS::File::Sale::TYPE_TRACK }

sub mediaType { RPS::DB::Item::MediaType::kMediaTypeAudio }

sub saleDates {
    my $self = shift;
    return ( $self->{_startDate}, $self->{_endDate} ) if ( $self->{_startDate} );    # from header; see _preProcess
}

sub formatType {
    my $self = shift;
    my $fmt  = $self->_getByFieldName('formatType');
    if ( $fmt =~ /^mobile_stream|stream$/i ) {
        return RPS::File::Sale::FORMAT_STREAM;
    }
    $self->fail("Unknown format type '$fmt'");
}

sub serviceID {
    my $self      = shift;
    my $service   = $self->_getByFieldName('serviceID');
    my $serviceID = $self->getServiceID( lc($service) ) || $RPS::Import::ServiceMap::SERVICE_ALIASES{ lc $service };
    return $serviceID if ($serviceID);
    $self->fail("Unknown service '$service'");
}

sub countryCode {
    my $self = shift;
    my $name = $self->_getByFieldName('countryCode');
    my $o    = Common::Country->Get($name);
    if ($o) {
        return $o->alpha2;
    }
    $self->fail("Unrecognized country '$name'");
}

sub _preProcess {
    my $self = shift;
    my %args = @_;

    Log->info("Starting _preProcess");
    $self->SUPER::_preProcess(%args);

    my $getDateFlag;

    my $linenum = 0;
    foreach my $line ( @{ $args{lines} } ) {
        $self->{line} = $line;

        my $dt = $self->_getByFieldName('dateBegin');
        if ( !$getDateFlag ) {
            if ( $dt =~ /^accounted period$/i ) {
                $getDateFlag = 1;
            }
        } else {
            if ( $dt =~ /^(\d{4})(\d{2})$/ ) {
                my $year  = $1;
                my $month = $2;
                $self->{_startDate} = sprintf( "%04d-%02d-%02d", $year, $month, 1 );
                $self->{_endDate} = sprintf( "%04d-%02d-%02d", $year, $month, Days_in_Month( $year, $month ) );
                last;
            }
        }

        $linenum++;
    }

}

###
1;    # Play nicely.
###