#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2014 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------

package RPS::Import::Merlin::v28;

use strict;

use Date::Calc qw(Days_in_Month Decode_Month);

use lib '/app/tools/common/lib';
use Common::Assert;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;

use base 'RPS::Import::Importer';

sub _fieldMap {
    {
        labelName    => 'I',
        countryCode  => 'C',
        formatType   => 'O',
        artistName   => 'F',
        upc          => 'E',
        albumName    => 'H',
        isrc         => 'D',
        trackName    => 'G',
        units        => 'K',
        currencyCode => 'N',
        free         => 'P',
        price        => 'M',
    };
}

sub _unverifiedFieldMap {
    { serviceName => 'B', };
}

sub _headerIdentifier { ( upc => 'UPC' ) }

sub mediaType { RPS::DB::Item::MediaType::kMediaTypeAudio }

sub serviceID {
    my $self      = shift;
    my $name      = $self->_getByFieldName('serviceName');
    my $serviceID = $self->getServiceID( lc($name) ) || $RPS::Import::ServiceMap::SERVICE_ALIASES{ lc $name };
    return $serviceID;
}

sub free {
    my $self    = shift;
    my $isFree  = $self->_getByFieldName('free');
    my $units   = $self->_getByFieldName('units');
    my $revenue = $self->_getByFieldName('price');

    if ( $isFree =~ /Free Trial/i || ( $units && !$revenue ) ) {
        return '1';
    } else {
        return '0';
    }
}

sub productType {
    my $self  = shift;
    my $track = $self->_getByFieldName('trackName');

    if ( $track && length($track) > 0 ) {
        return RPS::File::Sale::TYPE_TRACK;
    } else {
        return RPS::File::Sale::TYPE_ALBUM;
    }
}

sub formatType {
    my $self = shift;
    my $type = $self->_getByFieldName('formatType');

    if ( $type =~ /On Demand/i ) {
        return RPS::File::Sale::FORMAT_TETHERED;
    } else {
        $self->fail("Unable to determine format from format($type)");
    }
}

sub saleDates {
    my $self = shift;

    return ( $self->{_startDate}, $self->{_endDate} ) if ( $self->{_startDate} );

    $self->fail("Unknown filename") unless ( $self->filename );

    unless ( $self->filename =~ /(\d{4})(\d{2})/ ) {
        $self->fail( "Could not determine period from filename '" . $self->filename . "'" );
    }

    my $startDate = sprintf( "%04d-%02d-%02d", $1, $2, 1 );

    ( $self->{_startDate}, $self->{_endDate} ) = $self->_getDates( date_begin => $startDate );

    return ( $self->{_startDate}, $self->{_endDate} );

}

###
1;    # Play nicely.
###