package RPS::Import::Merlin::v3;

use strict;

use lib '/app/tools/common/lib';
use Common::Date;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;
use base 'RPS::Import::Importer';

use Data::Dumper;

sub _headerIdentifier { ( upc => 'UPC' ) }

sub _fieldMap {
    {
        # Header

        # Data
        labelName    => 'I',
        serviceID    => 'A',
        countryCode  => 'D',
        currencyCode => 'E',
        dateBegin    => 'B',
        dateEnd      => 'C',
        artistName   => 'K',
        upc          => 'G',
        isrc         => 'H',
        trackName    => 'L',
        units        => 'M',
        price        => 'R',
        mediaType    => 'N',
    };
}

sub _unverifiedFieldMap {
    {
        # Footer
        distFee  => 'S',
        revShare => 'Q',
    };
}

sub productType { return RPS::File::Sale::TYPE_TRACK; }
sub formatType  { return RPS::File::Sale::FORMAT_STREAM; }
sub mediaType   { return RPS::DB::Item::MediaType::kMediaTypeAudio; }

sub _processHeader {
    my $self = shift;

    unless ( $self->{_currencyCode} ) {
        my $headerStr = $self->_getByFieldName('currencyCode') || return;
        my $currencyCode;

        if ( $headerStr =~ /^(\w{3}) PAYABLE$/ ) {
            $currencyCode = $1;
        }

        $self->{_currencyCode} = $currencyCode if ($currencyCode);
    }
}

sub price {
    my $self = shift;

    my $price = $self->_getByFieldName('revShare');

    $self->fail("Unable to determine distribution fee") unless ( $self->{_distFee} );

    my $distFee = $self->{_distFee};
    $distFee = ( 100 - $distFee ) * .01;
    $price *= $distFee;

    return $price;
}

sub serviceID {
    my $self    = shift;
    my $service = $self->_getByFieldName('serviceID');

    $self->fail("Service name not defined") unless ($service);

    my $serviceID = $self->getServiceID( lc($service) ) || $RPS::Import::ServiceMap::SERVICE_ALIASES{ lc $service };

    $self->fail("Unable to determine service id from '$service'") unless ($serviceID);

    return $serviceID;
}

my %currencyConversions;

sub conversionRate {
    my $self         = shift;
    my $revShare     = $self->_getByFieldName('revShare');
    my $convertedRev = $self->_getByFieldName('price');
    my $currencyCode = $self->_getByFieldName('currencyCode');

    my $conversionRate;

    if ( $currencyCode eq 'USD' ) {
        $conversionRate = 1;
    } else {
        $conversionRate = sprintf( "%.8f", $convertedRev / $revShare );
    }

    if ( $currencyConversions{$currencyCode} ) {
        if ( $currencyConversions{$currencyCode} != $conversionRate ) {
            $self->fail(
                "Found different conversion rates for same currency $currencyCode: $conversionRate and $currencyConversions{$currencyCode}"
            );
        }
    } else {
        $currencyConversions{$currencyCode} = $conversionRate;
    }

    return $conversionRate;
}

sub _preProcess {
    my $self = shift;
    my %args = @_;

    Log->info("Starting _preProcess");
    $self->SUPER::_preProcess(%args);

    my $distFee;

    foreach my $line ( @{ $args{lines} } ) {
        $self->{line} = $line;
        $distFee = $self->_getByFieldName('distFee');

        if ( $distFee =~ /LESS Merlin ADMIN FEE \((.+?)%\)/ ) {
            $self->{_distFee} = $1;
            last;
        }
    }
}

sub _postProcess {
    my $self = shift;
    my %args = @_;

    Log->info("Starting _postProcess");
    $self->SUPER::_postProcess(%args);

    my $file = $args{file};

    foreach my $currencyCode ( keys %currencyConversions ) {
        my $conversionRate = $currencyConversions{$currencyCode};

        $file->SetMultipleConversionRate( $currencyCode, $conversionRate );
    }
}

###
1;    # Play nicely.
###