package RPS::Import::Merlin::v33;

use strict;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;
use base 'RPS::Import::Importer';

sub _headerIdentifier { ( upc => 'EAN_UPC2' ) }

sub _fieldMap {
    {
        # Data
        labelName    => 'O',
        serviceID    => 'H',
        countryCode  => 'I',
        dateBegin    => 'A2',
        formatType   => 'T',
        artistName   => 'L',
        upc          => 'K',
        albumName    => 'N',
        isrc         => 'J',
        trackName    => 'M',
        units        => 'P',
        currencyCode => 'S',
        totalRevenue => 'R',
    };
}

sub _unverifiedFieldMap {
    { unitPrice => 'Q', };
}

sub productType { return RPS::File::Sale::TYPE_TRACK; }
sub _dateFormat { 'numerical_year_first' }
sub mediaType   { return RPS::DB::Item::MediaType::kMediaTypeAudio }

sub sales {
    my $self  = shift;
    my $sales = $self->_getByFieldName('units');

    return ( $sales > 0 ) ? $sales : 0;
}

sub salesRevenue {
    my $self         = shift;
    my $salesRevenue = $self->_getByFieldName('totalRevenue');

    return ( $salesRevenue > 0 ) ? $salesRevenue : 0;
}

sub returns {
    my $self         = shift;
    my $sales        = $self->_getByFieldName('units');
    my $salesRevenue = $self->_getByFieldName('totalRevenue');

    return ( $sales < 0 && $salesRevenue < 0 ) ? abs($sales) : 0;
}

sub returnsRevenue {
    my $self         = shift;
    my $sales        = $self->_getByFieldName('units');
    my $salesRevenue = $self->_getByFieldName('totalRevenue');

    return ( $sales < 0 && $salesRevenue < 0 ) ? abs($salesRevenue) : 0;
}

sub formatType {
    my $self = shift;
    my $type = $self->_getByFieldName('formatType');
    if ( $type =~ /^on-demand$/i || $type =~ /^pre-configured$/i ) {
        return RPS::File::Sale::FORMAT_STREAM;
    }
    $self->fail("Unable to get format from '$type'");
}

sub _isValidSaleRecord {
    my $self  = shift;
    my $units = $self->units;
    my $price = $self->price;

    #skipping the nearly blank second line of the sales file
    return undef if ( !$units && !$price );

    return $self->SUPER::_isValidSaleRecord();
}

sub serviceID {
    my $self    = shift;
    my $service = $self->_getByFieldName('serviceID');

    $self->fail("Service name not defined") unless ($service);

    my $serviceID = $self->getServiceID( lc($service) ) || $RPS::Import::ServiceMap::SERVICE_ALIASES{ lc $service };

    $self->fail("Unable to determine service id from '$service'") unless ($serviceID);

    return $serviceID;
}

sub countryCode {
    my $self  = shift;
    my $cname = $self->_getByFieldName('countryCode');
    my $o     = Common::Country->Get($cname);
    return ( defined $o ) ? $o->alpha2() : $cname;
}

sub unitPrice {
    my $self = shift;

    # The sales file is reporting the unit price, so
    # we provide unitPrice to prevent it from being derived
    #
    my $unitPrice = $self->_getByFieldName('unitPrice');

    return $unitPrice;
}

###
1;    # Play nicely.
###