package RPS::Import::Merlin::v50;

use strict;
use warnings;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;

use parent 'RPS::Import::ImporterMixed';

use constant RE_DD_MM_YYYY => qr/^(\d{1,2})[\.\/-](\d{1,2})[\.\/-](\d{4})$/;

sub physical { 2 }

sub _fieldMapExtended {
    {
        digital => {
            option1 => {
                labelName    => 'F',
                serviceID    => 'A',
                countryCode  => 'L',
                dateBegin    => 'B',
                dateEnd      => 'C',
                productType  => 'K',
                formatType   => 'M',
                artistName   => 'H',
                upc          => 'J',
                albumName    => 'G',
                isrc         => 'K',
                trackName    => 'I',
                units        => 'N',
                price        => 'R',
                mediaType    => 'M'
            }
         }
    };
}

sub _unverifiedFieldMapExtended { {} };

sub _headerIdentifierExtended {
    {
        digital => {
            option1 => {
                productType => 'ISRC',
            },
        },
    };
}

sub currencyCode { 'USD' }

sub saleDates {
    my $self = shift;

    my $startDate = $self->_getByFieldName('dateBegin') || '';
    my $endDate   = $self->_getByFieldName('dateEnd')   || '';

    # YYYY/MM/DD
    if ( $startDate =~ /^(\d{4})[\.\/-]?(\d{1,2})[\.\/-]?(\d{1,2})$/ ) {
        $startDate = sprintf "%04d-%02d-01", $1, $2;
    }
    if ( $endDate =~ /^(\d{4})[\.\/-]?(\d{1,2})[\.\/-]?(\d{1,2})$/ ) {
        $endDate = sprintf "%04d-%02d-%02d", $1, $2, $3;
    }

    # MM/DD/YY
    if ( $startDate =~ /^(\d{1,2})[\.\/-](\d{1,2})[\.\/-](\d{2})$/ ) {
        $startDate = sprintf "20%02d-%02d-%02d", $3, $1, $2;
    }
    if ( $endDate =~ /^(\d{1,2})[\.\/-](\d{1,2})[\.\/-](\d{2})$/ ) {
        $endDate = sprintf "20%02d-%02d-%02d", $3, $1, $2;
    }

    # We need to determine which format do we have: DD/MM or MM/DD.
    # So, let's check out days count in the endDate
    $endDate =~ RE_DD_MM_YYYY;
    if ($2 && ($2 > 12)) {
        # MM/DD/YYYY
        if ( $startDate =~ RE_DD_MM_YYYY ) {
            $startDate = sprintf "%04d-%02d-%02d", $3, $1, $2;
        }
        if ( $endDate =~ RE_DD_MM_YYYY ) {
            $endDate = sprintf "%04d-%02d-%02d", $3, $1, $2;
        }
    }
    else {
        # DD/MM/YYYY
        if ( $startDate =~ RE_DD_MM_YYYY ) {
            $startDate = sprintf "%04d-%02d-01", $3, $2;
        }
        if ( $endDate =~ RE_DD_MM_YYYY ) {
            $endDate = sprintf "%04d-%02d-%02d", $3, $2, $1;
        }
    }

    $self->_getDates( date_begin => $startDate, date_end => $endDate );
}

sub mediaType {
    my $self = shift;

    my $type = $self->_getByFieldName('mediaType');

    return RPS::DB::Item::MediaType::kMediaTypeAudio if $type =~ /^(Ad-Supported|Basic Subscription|Premium(?: Subscription)?|Karaoke|S?VIP.*|Lossless|Download)$/i;

    $self->fail("Unable to determine media type from '$type'");
}

sub serviceID {
    my $self = shift;

    my $service = lc( $self->_getByFieldName('serviceID') || '' );
    my $serviceID = $self->getServiceID($service) || $RPS::Import::ServiceMap::SERVICE_ALIASES{$service};

    $self->fail("Unable to determine service id from '$service'") unless $serviceID;

    return $serviceID;
}

sub countryCode {
    my $self = shift;

    my $country  = $self->_getByFieldName('countryCode') || '';
    my $oCountry = Common::Country->Get($country);

    return $oCountry->alpha2 if $oCountry;
}

sub productType {
    my $self = shift;

    my $type      = $self->_getByFieldName('productType') || '';
    my $trackName = $self->_getByFieldName('trackName')   || '';
    return RPS::File::Sale::TYPE_TRACK if $type || $trackName;

    $self->fail("Unable to determine product type from '$type'");
}

sub formatType {
    my $self = shift;

    my $type = $self->_getByFieldName('formatType') || '';

    return RPS::File::Sale::FORMAT_DOWNLOAD if $type =~ /^Download$/i;
    return RPS::File::Sale::FORMAT_STREAM if $type =~ /^(Ad-Supported|Basic Subscription|Premium(?: Subscription)?|Karaoke|S?VIP.*|Lossless)$/i;

    $self->fail("Unable to determine format type from '$type'");
}
sub units {
    my $self = shift;

    my $price = $self->_getByFieldName('price') || 0;
    my $units = $self->_getByFieldName('units') || 0;
    $units =~ s/[^0-9]+//g;

    if ( $price > 0 ) {
         $units = $units ? abs($units) : 1;
    } elsif ( $price < 0 ) {
        $units = $units ? -1 * abs($units) : -1;
    }

    return $units;
}

sub price {
    my $self = shift;

    my $price = $self->_getByFieldName('price') || 0;
    return sprintf "%.8f", $price;
}

sub upc {
    my $self = shift;

    my $upc = $self->_getByFieldName('upc') || 0;
    $upc =~ s/[^\d]//g;
    return $upc;
}

sub _isValidSaleRecord {
    my $self = shift;

    return defined $self->units && defined $self->_getByFieldName('price')
        && ( $self->_getByFieldName('albumName') || $self->_getByFieldName('trackName') );
}


1;