package RPS::Import::Merlin::v64;

use strict;
use warnings;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;

use parent 'RPS::Import::ImporterMixed';

sub physical { 2 }

sub _fieldMapExtended {
    {
        digital => {
            option1 => {
                labelName    => 'F',
                serviceID    => 'A',
                countryCode  => 'N',
                dateBegin    => 'B',
                dateEnd      => 'C',
                productType  => 'L',
                formatType   => 'R',
                artistName   => 'H',
                upc          => 'J',
                albumName    => 'G',
                isrc         => 'L',
                trackName    => 'I',
                units        => 'W',
                currencyCode => 'Y1',
                price        => 'Y',
            },
        },
    };
}

sub _unverifiedFieldMapExtended { {} }

sub _headerIdentifierExtended {
    {
        digital => {
            option1 => {
                isrc => 'ISRC',
            },
        },
    };
}

sub mediaType { RPS::DB::Item::MediaType::kMediaTypeAudio}

sub serviceID {
    my $self = shift;

    my $service = lc( $self->_getByFieldName('serviceID') || '' );
    my $serviceID = $self->getServiceID($service) || $RPS::Import::ServiceMap::SERVICE_ALIASES{$service};
    return $serviceID if $serviceID;

    $self->fail("Unknown service: $service");
}

sub productType {
    my $self = shift;

    my $type = $self->_getByFieldName('productType') || '';
    return $type ? RPS::File::Sale::TYPE_TRACK : RPS::File::Sale::TYPE_ALBUM;
}

sub formatType {
    my $self = shift;

    my $type = $self->_getByFieldName('formatType') || '';
    return RPS::File::Sale::FORMAT_DOWNLOAD if $type =~ /^Download$/i;
    return RPS::File::Sale::FORMAT_STREAM   if $type =~ /^(Stream|Offline play)$/i;
    return RPS::File::Sale::FORMAT_TETHERED if $type =~ /^Tethered download$/i;

    $self->fail("Unable to determine format_type from: '$type'.");
}

sub currencyCode {
    my $self = shift;

    my $header = $self->_getByFieldName('currencyCode') || '';
    my ($cc) = $header =~ /.*_([a-z]+)$/i;

    return $cc;
}

sub units {
    my $self = shift;

    my $units = $self->_getByFieldName('units') || 0;
    my $price = $self->_getByFieldName('price') || 0;

    if ( $price > 0 ) {
        $units = $units ? abs($units) : 1;
    } elsif ( $price < 0 ) {
        $units = $units ? -1 * abs($units) : -1;
    }

    return $units;
}

sub _isValidSaleRecord {
    my $self = shift;

    return ( defined( $self->units ) && ( defined $self->trackName || defined $self->albumName ) );
}


1;