package RPS::Import::Merlin::v65;

use strict;
use warnings;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;

use parent 'RPS::Import::ImporterMixed';

sub physical { 2 }

sub _fieldMapExtended {
    {
        digital => {
            option1 => {
                labelName    => 'F',
                serviceID    => 'A',
                countryCode  => 'M',
                dateBegin    => 'B',
                dateEnd      => 'B',
                productType  => 'K',
                formatType   => 'O',
                artistName   => 'H',
                upc          => 'J',
                albumName    => 'G',
                isrc         => 'K',
                trackName    => 'I',
                units        => 'Q',
                currencyCode => 'T1',
                price        => 'T',
            },
        },
    };
}

sub _unverifiedFieldMapExtended { {} }

sub _headerIdentifierExtended {
    {
        digital => {
            option1 => {
                isrc => 'ISRC',
            },
        },
    };
}

sub mediaType { RPS::DB::Item::MediaType::kMediaTypeAudio}

sub serviceID {
    my $self = shift;

    my $service = lc( $self->_getByFieldName('serviceID') || '' );
    my $serviceID = $self->getServiceID($service) || $RPS::Import::ServiceMap::SERVICE_ALIASES{$service};
    return $serviceID if $serviceID;

    $self->fail("Unknown service: $service");
}

sub saleDates {
    my $self = shift;
    my $date = $self->_getByFieldName("dateBegin");

    if ( $date =~ /^(\d{1,2})\/(\d{1,2})\/(\d{2,4})$/ ) {
        $date = sprintf( "20%02d-%02d-%02d", substr($3, -2), $2, $1 );
    }
    my ( $dateBegin, $dateEnd ) = $self->SUPER::_getDates( date_begin => $date, type => 'iso' );
    return ($dateBegin, $dateEnd) if ($dateBegin);

    $self->fail( "Unable to determine date from: '$date'." );
}

sub productType {
    my $self = shift;

    my $isrc = $self->_getByFieldName('isrc') || '';
    return  RPS::File::Sale::TYPE_TRACK if $isrc;

    $self->fail("Cannot determine product type.");
}

sub formatType {
    my $self = shift;

    my $type = $self->_getByFieldName('formatType') || '';
    return RPS::File::Sale::FORMAT_STREAM if $type =~ /^(?:Stream|Cached Play)$/i;

    $self->fail("Unable to determine format_type from: '$type'.");
}

sub currencyCode {
    my $self = shift;

    my $code = $self->_getByFieldName('currencyCode') || '';
    return ($code =~ /.+?_(\w{3})$/i);
}

sub units {
    my $self = shift;

    my $units = $self->_getByFieldName('units') || 0;
    my $price = $self->_getByFieldName('price') || 0;

    if ( $price > 0 ) {
        $units = $units ? abs($units) : 1;
    } elsif ( $price < 0 ) {
        $units = $units ? -1 * abs($units) : -1;
    }

    return $units;
}

sub _isValidSaleRecord {
    my $self = shift;

    return ( defined( $self->units ) && ( defined $self->trackName || defined $self->albumName ) );
}

1;