package RPS::Import::Merlin::v67;

use strict;
use warnings;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;
use Date::Calc qw(Days_in_Month);

use parent 'RPS::Import::ImporterMixed';

sub physical { 2 }

sub _fieldMapExtended {
    {
        digital => {
            option1 => {
                labelName    => 'F',
                serviceID    => 'A',
                countryCode  => 'L',
                dateBegin    => 'B',
                dateEnd      => 'C',
                productType  => 'K',
                formatType   => 'N',
                artistName   => 'H',
                upc          => 'J',
                albumName    => 'G',
                isrc         => 'K',
                trackName    => 'I',
                units        => 'O',
                currencyCode => 'T1',
                price        => 'T',
                mediaType    => 'M',
            },
        },
    };
}

sub _unverifiedFieldMapExtended { {} }

sub _headerIdentifierExtended {
    {
        digital => {
            option1 => {
                isrc => 'ISRC',
            },
        },
    };
}

sub saleDates {
    my $self = shift;
    my $date = $self->_getByFieldName("dateBegin");

	if ( $date =~ /^(\d{2})\/(\d{2})\/(\d{4})$/ ) {        # DD/MM/YYYY
		my ($year, $month, $day)  = ($3, $2, $1);
		my $startDate = sprintf( "%04d-%02d-%02d", $year, $month, 1 );
		my $endDate = sprintf( "%04d-%02d-%02d", $year, $month, Days_in_Month( $year, $month ) );
		return ( $startDate, $endDate );
	} elsif ( $date =~ /^(\d{4})[\/-](\d{2})[\/-](\d{2})$/ ) {    # YYYY-MM-DD
		my ($year, $month, $day)  = ($1, $2, $3);
		my $startDate = sprintf( "%04d-%02d-%02d", $year, $month, 1 );
		my $endDate = sprintf( "%04d-%02d-%02d", $year, $month, Days_in_Month( $year, $month ) );
		return ( $startDate, $endDate );
    }

    $self->fail( "Unable to determine date from: '$date'." );
}

sub mediaType {
    my $self = shift;

    my $type = $self->_getByFieldName("mediaType");
    return RPS::DB::Item::MediaType::kMediaTypeAudio if ($type =~ /^(?:Ad-Supported|.*Subscription|AliGenie)$/i);

    $self->fail("Unknown media type: '$type'");
}

sub serviceID {
    my $self = shift;

    my $service = lc( $self->_getByFieldName('serviceID') || '' );
    my $serviceID = $self->getServiceID($service) || $RPS::Import::ServiceMap::SERVICE_ALIASES{$service};
    return $serviceID if $serviceID;

    $self->fail("Unknown service: $service");
}

sub productType {
    my $self = shift;

    my $isrc = $self->_getByFieldName('isrc') || '';
    return  RPS::File::Sale::TYPE_TRACK if $isrc;

    $self->fail("Cannot determine product type.");
}

sub formatType {
    my $self = shift;

    my $type = $self->_getByFieldName('formatType') || '';
    return RPS::File::Sale::FORMAT_STREAM if $type =~ /^(?:Stream)$/i;
    return RPS::File::Sale::FORMAT_TETHERED if $type =~ /^(?:Tethered download)$/i;

    $self->fail("Unable to determine format_type from: '$type'.");
}

sub currencyCode {
    my $self = shift;

    my $code = $self->_getByFieldName('currencyCode') || '';
    return ($code =~ /.+?_(\w{3})$/i);
}

sub units {
    my $self = shift;

    my $units = $self->_getByFieldName('units') || 0;
    my $price = $self->_getByFieldName('price') || 0;

    if ( $price > 0 ) {
        $units = $units ? abs($units) : 1;
    } elsif ( $price < 0 ) {
        $units = $units ? -1 * abs($units) : -1;
    }

    return $units;
}

sub _isValidSaleRecord {
    my $self = shift;

    return ( defined( $self->units ) && ( defined $self->trackName || defined $self->albumName ) );
}

1;