package RPS::Import::Merlin::v70;

use strict;
use warnings;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;

use parent 'RPS::Import::Importer';


sub _headerIdentifier { upc => 'Release_ID' }

sub _fieldMap {
    {
        labelName    => 'F',
        serviceID    => 'A',
        countryCode  => 'N',
        dateBegin    => 'B',
        dateEnd      => 'C',
        productType  => 'L',
        formatType   => 'P',
        artistName   => 'H',
        upc          => 'I',
        isrc         => 'L',
        trackName    => 'J',
        units        => 'Q',
        currencyCode => 'T1',
        price        => 'T',
    };
}

sub formatType { RPS::File::Sale::FORMAT_STREAM }
sub mediaType  { RPS::DB::Item::MediaType::kMediaTypeAudio }

sub serviceID {
    my $self = shift;

    my $service = $self->_getByFieldName('serviceID') || '';
    my $serviceID = $self->getServiceID( lc($service) ) || $RPS::Import::ServiceMap::SERVICE_ALIASES{ lc $service };

    return $serviceID if $serviceID;

    $self->fail("Unable to determine service id from '$service'");
}

sub dateBegin {
    my $self = shift;

    my $date = $self->_getByFieldName('dateBegin') || '';

    # DD/MM/YYYY
    if ( $date =~ /^(\d{2})\/(\d{2})\/(\d{4})$/ ) {
        return sprintf "%04d-%02d-%02d", $3, $2, $1;
    }
    # YYYYMMDD
    elsif ( $date =~ /^(\d{4})(\d{2})(\d{2})$/ ) {
        return sprintf "%04d-%02d-%02d", $1, $2, $3;
    }

    $self->fail("Unable to determine date begin from '$date'");
}

sub dateEnd {
    my $self = shift;

    my $date = $self->_getByFieldName('dateEnd') || '';

    # DD/MM/YYYY
    if ( $date =~ /^(\d{2})\/(\d{2})\/(\d{4})$/ ) {
        return sprintf "%04d-%02d-%02d", $3, $2, $1;
    }
    # YYYYMMDD
    elsif ( $date =~ /^(\d{4})(\d{2})(\d{2})$/ ) {
        return sprintf "%04d-%02d-%02d", $1, $2, $3;
    }

    $self->fail("Unable to determine date end from '$date'");
}

sub productType {
    my $self = shift;

    my $type = $self->_getByFieldName('productType') || '';

    return  RPS::File::Sale::TYPE_TRACK if $type;

    $self->fail("Unable to determine product type.");
}

sub units {
    my $self = shift;

    my $units = $self->_getByFieldName('units') || 0;
    my $price = $self->_getByFieldName('price') || 0;

    if ( $price > 0 ) {
        $units = $units ? abs($units) : 1;
    } elsif ( $price < 0 ) {
        $units = $units ? -1 * abs($units) : -1;
    }

    return $units;
}

sub currencyCode {
    my $self = shift;

    return $self->{__currency_code} if $self->{__currency_code};

    my $codeStr = $self->_getByFieldName('currencyCode') || '';
    ( $self->{__currency_code} ) = $codeStr =~ /^.*_(\w{3})$/;

    return $self->{__currency_code} if $self->{__currency_code};

    $self->fail("Unable to determine currency code.");
}


1;