package RPS::Import::Merlin::v76;

use strict;
use warnings;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;
use parent 'RPS::Import::Importer';

sub _fieldMap {
    my $self = shift;

    my %fieldMap = (
        76 => {
            labelName    => 'J',
            serviceID    => 'C',
            countryCode  => 'M',
            dateBegin    => 'A',
            dateEnd      => 'B',
            artistName   => 'H',
            upc          => 'L',
            albumName    => 'I',
            isrc         => 'K',
            trackName    => 'G',
            units        => 'O',
            currencyCode => 'Q',
            price        => 'P',
        },
        87 => {
            labelName    => 'J',
            serviceID    => 'C',
            countryCode  => 'M',
            dateBegin    => 'A',
            dateEnd      => 'B',
            artistName   => 'H',
            upc          => 'L',
            albumName    => 'I',
            isrc         => 'K',
            trackName    => 'G',
            units        => 'N',
            currencyCode => 'Q',
            price        => 'P',
        },
        92 => {
            labelName    => 'J',
            serviceID    => 'C',
            countryCode  => 'M',
            dateBegin    => 'A',
            dateEnd      => 'B',
            artistName   => 'H',
            upc          => 'L',
            albumName    => 'I',
            isrc         => 'K',
            trackName    => 'G',
            units        => 'N',
            currencyCode => 'S',
            price        => 'R',
        },
    );

    return $fieldMap{ $self->_version };
}

sub _unverifiedFieldMap { {} }


sub _headerIdentifier { upc => 'product_code' }

sub productType { RPS::File::Sale::TYPE_TRACK }
sub formatType  { RPS::File::Sale::FORMAT_STREAM }
sub mediaType   { RPS::DB::Item::MediaType::kMediaTypeAudio }

sub saleDates {
    my $self = shift;

    my $dateBegin = $self->_getByFieldName('dateBegin') || '';
    my $dateEnd   = $self->_getByFieldName('dateEnd')   || '';

    # YYYY-MM-DD / M/DD/YY / M/DD/YYYY
    my @db = $dateBegin =~ /^(\d{1,4})[-\/]?(\d{1,2})[-\/]?(\d{2,4})$/;
    my @de = $dateEnd   =~ /^(\d{1,4})[-\/]?(\d{1,2})[-\/]?(\d{2,4})$/;
    if ( @db == 3 && @de == 3 ) {
        $dateBegin = sprintf( "%04d-%02d-%02d", $db[0], $db[1], $db[2] ); # YYYY-MM-DD
        $dateEnd   = sprintf( "%04d-%02d-%02d", $de[0], $de[1], $de[2] ); # YYYY-MM-DD
        if(length($db[0]) < 4) { # M/DD/YY
            $db[2] += 2000 if (length($db[2]) == 2); # M/DD/YYYY
            $dateBegin = sprintf( "%04d-%02d-%02d", $db[2], $db[0], $db[1] );
        }
        if(length($de[0]) < 4) {
            $de[2] += 2000 if (length($de[2]) == 2);
            $dateEnd = sprintf( "%04d-%02d-%02d", $de[2], $de[0], $de[1] );
        }
        return $self->_getDates(
            date_begin => $dateBegin,
            date_end   => $dateEnd
        );
    }

    $self->fail( "Unable to determine dates from: '$dateBegin' and '$dateEnd'." );
}

sub serviceID {
    my $self = shift;

    my $service = lc( $self->_getByFieldName('serviceID') || '' );
    my $serviceID = $self->getServiceID($service) || $RPS::Import::ServiceMap::SERVICE_ALIASES{$service};
    return $serviceID if $serviceID;

    $self->fail("Unable to determine service from: '$service'");
}


sub countryCode {
    my $self = shift;

    my $country = $self->_getByFieldName('countryCode') || '';
    return 'TL' if $country =~ /^TP$/;

    my $oCountry = Common::Country->Get($country);
    return $oCountry->alpha2 if $oCountry;

    $self->fail( "Unable to determine country_code from: '$country'." );
}

sub price     { abs( shift->_getByFieldName('price') || 0 ) }
sub unitPrice { abs shift->SUPER::unitPrice }
sub units {
    my $self = shift;

    my $units = $self->_getByFieldName('units') || 0;
    my $price = $self->_getByFieldName('price') || 0;

    if ( $price > 0 ) {
        $units = $units ? abs($units) : 1;
    } elsif ( $price < 0 ) {
       $units = $units ? -1 * abs($units) : -1;
    }

    return $units;
}


1;