package RPS::Import::Merlin::v77;

use strict;
use warnings;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;
use parent 'RPS::Import::Importer';

sub _fieldMap {
    {
        labelName    => 'F',
        serviceID    => 'A',
        countryCode  => 'N',
        dateBegin    => 'B',
        dateEnd      => 'C',
        productType  => 'L',
        artistName   => 'H',
        upc          => 'J',
        albumName    => 'G',
        isrc         => 'L',
        trackName    => 'I',
        units        => 'O',
        currencyCode => 'Q1',
        price        => 'Q',
    }
}

sub _unverifiedFieldMap { {} }


sub _headerIdentifier { upc => 'release_id' }

sub formatType  { RPS::File::Sale::FORMAT_STREAM }
sub mediaType   { RPS::DB::Item::MediaType::kMediaTypeAudio }

sub saleDates {
    my $self = shift;

    my $dateBegin = $self->_getByFieldName('dateBegin') || '';
    my $dateEnd   = $self->_getByFieldName('dateEnd')   || '';

    # YYYYMMDD
    my @db = $dateBegin =~ /^(\d{4})-?(\d{2})-?(\d{2})$/;
    my @de = $dateEnd   =~ /^(\d{4})-?(\d{2})-?(\d{2})$/;
    if ( @db == 3 && @de == 3 ) {
        return $self->_getDates(
            date_begin => sprintf( "%04d-%02d-%02d", $db[0], $db[1], $db[2] ),
            date_end   => sprintf( "%04d-%02d-%02d", $de[0], $de[1], $de[2] )
        );
    }

    # [M]M/[D]D/[YY]YY or [M]M.[D]D.[YY]YY
    @db = $dateBegin =~ /^(\d{1,2})[\/.-](\d{1,2})[\/.-](\d{2,4})$/;
    @de = $dateBegin =~ /^(\d{1,2})[\/.-](\d{1,2})[\/.-](\d{2,4})$/;
    if ( @db == 3 && @de == 3 ) {
        my $yb = length($db[2]) == 2 ? "20$db[2]" : $db[2];
        my $ye = length($de[2]) == 2 ? "20$de[2]" : $de[2];
        return $self->_getDates(
            date_begin => sprintf( "%04d-%02d-%02d", $yb, $db[0], $db[1] ),
            date_end   => sprintf( "%04d-%02d-%02d", $ye, $de[0], $de[1] )
        );
    }

    $self->fail( "Unable to determine dates from: '$dateBegin' and '$dateEnd'." );
}

sub productType {
    my $self = shift;

    my $isrc = $self->_getByFieldName("isrc") || "";
    return RPS::File::Sale::TYPE_TRACK if $isrc;

    $self->fail("Cannot determine product type");
}

sub serviceID {
    my $self = shift;

    my $service = lc( $self->_getByFieldName('serviceID') || '' );
    my $serviceID = $self->getServiceID($service) || $RPS::Import::ServiceMap::SERVICE_ALIASES{$service};
    return $serviceID if $serviceID;

    $self->fail("Unable to determine service from: '$service'");
}


sub countryCode {
    my $self = shift;

    my $country = $self->_getByFieldName('countryCode') || '';
    return 'TL' if $country =~ /^TP$/;

    my $oCountry = Common::Country->Get($country);
    return $oCountry->alpha2 if $oCountry;

    $self->fail( "Unable to determine country_code from: '$country'." );
}

sub currencyCode {
    my $self = shift;

    my $code = $self->_getByFieldName("currencyCode") || "";

    return $1 if ($code =~ /^Total_Payable_(\w{3})$/i);

    $self->fail("Cannot determine currency code from '$code'");
}

sub price     { abs( shift->_getByFieldName('price') || 0 ) }
sub unitPrice { abs shift->SUPER::unitPrice }
sub units {
    my $self = shift;

    my $units = $self->_getByFieldName('units') || 0;
    my $price = $self->_getByFieldName('price') || 0;

    if ( $price > 0 ) {
        $units = $units ? abs($units) : 1;
    } elsif ( $price < 0 ) {
       $units = $units ? -1 * abs($units) : -1;
    }

    return $units;
}

1;