package RPS::Import::Merlin::v82;

use strict;
use warnings;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;

use base 'RPS::Import::Importer';

sub _fieldMap {
    my $self = shift;

    my %map = (
        82 => {
            labelName    => 'F',
            serviceID    => 'A',
            countryCode  => 'N',
            dateBegin    => 'B',
            dateEnd      => 'C',
            productType  => 'L',
            formatType   => 'Q',
            artistName   => 'H',
            upc          => 'J',
            albumName    => 'G',
            isrc         => 'L',
            trackName    => 'I',
            units        => 'S',
            currencyCode => 'V1',
            price        => 'V',
        },
        91 => {
            labelName    => 'F',
            serviceID    => 'A',
            countryCode  => 'O',
            dateBegin    => 'B',
            dateEnd      => 'C',
            productType  => 'L',
            formatType   => 'Q',
            artistName   => 'H',
            upc          => 'M',
            albumName    => 'G',
            isrc         => 'L',
            trackName    => 'I',
            units        => 'P',
            currencyCode => 'R',
            price        => 'S',
        },
    );

    return $map{ $self->_version };
}

sub _headerIdentifier {
    my $self = shift;

    my %map = (
        82 => {
            upc => 'Release_ID',
        },
        91 => {
            upc => 'UPC',
        },
    );

    return $map{ $self->_version };
}

sub mediaType  { RPS::DB::Item::MediaType::kMediaTypeAudio }

sub formatType {
    my $self = shift;

    my $type = $self->_getByFieldName('formatType');

    return RPS::File::Sale::FORMAT_STREAM if $type =~ /^stream$/i;
    return RPS::File::Sale::FORMAT_DOWNLOAD if $type =~ /^download$/i;

    if ( $self->_version == 91 ) {
        return RPS::File::Sale::FORMAT_STREAM if $type =~ /^(?:Free|Subscription)$/i;
    }

    $self->fail("Could not determine format from '$type'");
}

sub serviceID {
    my $self = shift;

    my $service = $self->_getByFieldName('serviceID') || '';
    my $serviceID = $self->getServiceID( lc($service) ) || $RPS::Import::ServiceMap::SERVICE_ALIASES{ lc($service) };

    return $serviceID if $serviceID;

    $self->fail("Unable to determine service id from '$service'");
}

sub dateBegin {
    my $self = shift;

    my $date = $self->_getByFieldName('dateBegin') || '';

    # DD/MM/YYYY
    if ( $date =~ /^(\d{2})\/(\d{2})\/(\d{4})$/ ) {
        return sprintf("%04d-%02d-%02d", $3, $2, $1);
    }
    # YYYYMMDD
    elsif ( $date =~ /^(\d{4})(\d{2})(\d{2})$/ ) {
        return sprintf("%04d-%02d-%02d", $1, $2, $3);
    }

    $self->fail("Unable to determine date begin from '$date'");
}

sub dateEnd {
    my $self = shift;

    my $date = $self->_getByFieldName('dateEnd') || '';

    # DD/MM/YYYY
    if ( $date =~ /^(\d{2})\/(\d{2})\/(\d{4})$/ ) {
        return sprintf("%04d-%02d-%02d", $3, $2, $1);
    }
    # YYYYMMDD
    elsif ( $date =~ /^(\d{4})(\d{2})(\d{2})$/ ) {
        return sprintf("%04d-%02d-%02d", $1, $2, $3);
    }

    $self->fail("Unable to determine date end from '$date'");
}

sub saleDates {
    my $self = shift;

    return $self->dateBegin, $self->dateEnd;
}

sub productType {
    my $self = shift;

    my $type = $self->_getByFieldName('productType') || '';

    return ($type ? RPS::File::Sale::TYPE_TRACK : RPS::File::Sale::TYPE_ALBUM);
}

sub units {
    my $self = shift;

    my $units = $self->_getByFieldName('units') || 0;
    my $price = $self->_getByFieldName('price') || 0;

    if ( $price > 0 ) {
        $units = $units ? abs($units) : 1;
    } elsif ( $price < 0 ) {
        $units = $units ? -1 * abs($units) : -1;
    }

    return $units;
}

sub currencyCode {
    my $self = shift;

    my $curr = $self->_getByFieldName('currencyCode') || '';

    if ( $self->_version == 91 ) {
        return $curr if $curr =~ /^\w{3}$/i;
    }

    return $self->{currency_code} if $self->{currency_code};

    ( $self->{currency_code} ) = $curr =~ /_(\w{3})$/;

    return $self->{currency_code} if $self->{currency_code};

    $self->fail("Unable to determine currency code from '$curr'.");
}


1;