package RPS::Import::Merlin::v97;

use strict;
use warnings;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;

use base 'RPS::Import::Importer';

sub _fieldMap {
    {
        labelName    => 'F',
        serviceID    => 'A',
        countryCode  => 'N',
        dateBegin    => 'B',
        dateEnd      => 'C',
        productType  => 'L',
        formatType   => 'P',
        artistName   => 'H',
        upc          => 'J',
        albumName    => 'G',
        isrc         => 'L',
        trackName    => 'I',
        units        => 'O',
        currencyCode => 'S1',
        price        => 'S',
    };
}

sub _headerIdentifier { upc => 'Release_ID' }

sub mediaType  { RPS::DB::Item::MediaType::kMediaTypeAudio }

sub serviceID {
    my $self = shift;

    my $service = $self->_getByFieldName('serviceID') || '';
    my $serviceID = $self->getServiceID( lc($service) ) || $RPS::Import::ServiceMap::SERVICE_ALIASES{ lc($service) };

    return $serviceID if $serviceID;

    $self->fail("Unable to determine service id from '$service'");
}

sub saleDates {
    my $self = shift;

    my $dateBegin = $self->_getByFieldName('dateBegin') || '';
    my $dateEnd   = $self->_getByFieldName('dateEnd')   || '';

    my $startDate = $self->_parseDate($dateBegin);
    my $endDate  = $self->_parseDate($dateEnd);

    return ( $startDate, $endDate ) if $startDate && $endDate;

    $self->fail("Unable to determine sale dates from '$dateBegin' to '$dateEnd'");
}

sub _parseDate {
    my ($self, $date) = @_;

    return unless $date;

    # DD/MM/YYYY
    if ( $date =~ /^(\d{2})\/(\d{2})\/(\d{4})$/ ) {
        return sprintf("%04d-%02d-%02d", $3, $2, $1);
    }
    # DD/MM/YY
    elsif ( $date =~ /^(\d{1,2})\/(\d{1,2})\/(\d{2})$/ ) {
        return sprintf("20%02d-%02d-%02d", $3, $2, $1);
    }
    # YYYYMMDD
    elsif ( $date =~ /^(\d{4})(\d{2})(\d{2})$/ ) {
        return sprintf("%04d-%02d-%02d", $1, $2, $3);
    }
}

sub formatType {
    my $self = shift;

    my $format = $self->_getByFieldName('formatType') || '';
    return RPS::File::Sale::FORMAT_STREAM if $format =~ /^(?:stream|free tier|premium trial)$/i;
    return RPS::File::Sale::FORMAT_TETHERED if $format =~ /^Monthly Premium$/i;

    $self->fail("Unable to determine format type from '$format'.");
}

sub productType {
    my $self = shift;

    my $type = $self->_getByFieldName('productType') || '';

    return  RPS::File::Sale::TYPE_TRACK if $type;

    $self->fail("Unable to determine product type.");
}

sub units {
    my $self = shift;

    my $units = $self->_getByFieldName('units') || 0;
    my $price = $self->_getByFieldName('price') || 0;

    if ( $price > 0 ) {
        $units = $units ? abs($units) : 1;
    } elsif ( $price < 0 ) {
        $units = $units ? -1 * abs($units) : -1;
    }

    return $units;
}

sub currencyCode {
    my $self = shift;

    return $self->{currency_code} if $self->{currency_code};

    my $curr = $self->_getByFieldName('currencyCode') || '';
    ( $self->{currency_code} ) = $curr =~ /_(\w{3})$/;

    return $self->{currency_code} if $self->{currency_code};

    $self->fail("Unable to determine currency code from '$curr'.");
}

1;