package RPS::Import::MriMegaforce::v1;

use strict;
use warnings;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;

use parent 'RPS::Import::ImporterMixed';

use Date::Calc qw(Add_Delta_Days Days_in_Month);

sub physical { 0 }

sub _fieldMapExtended {
    {
        digital => {
            option1 => {
                labelName    => 'D',
                serviceID    => 'C',
                countryCode  => 'K',
                dateBegin    => 'B',
                dateEnd      => 'B',
                upc          => 'J',
                albumName    => 'F',
                isrc         => 'I',
                trackName    => 'H',
                units        => 'N',
                currencyCode => 'P',
                price        => 'P',
            },
        },
    };
}
sub _unverifiedFieldMapExtended {
    {
        digital => {
            option1 => {
                _sale_type    => 'M',
                _store_name   => 'C',
                _track_artist => 'G',
                _artist_name  => 'E',
            },
        },
    };
}

sub _headerIdentifierExtended {
    {
        digital => {
            option1 => {
                upc => 'Display Upc',
            },
        },
    };
}

sub currencyCode { 'USD' }
sub mediaType    { RPS::DB::Item::MediaType::kMediaTypeAudio }

sub serviceID {
    my $self = shift;

    my $service = lc( $self->_getByFieldName('serviceID') || '' );
    my $serviceID = $self->getServiceID($service) || $RPS::Import::ServiceMap::SERVICE_ALIASES{$service};
    return $serviceID if $serviceID;

    $self->fail("Unable to determine service from: '$service'");
}

sub countryCode {
    my $self = shift;

    my $country = $self->_getByFieldName('countryCode') || '';
    my $oCountry = Common::Country->Get($country) if $country;
    return $oCountry->alpha2 if $oCountry;

    $self->fail( "Unable to determine country_code from: '$country'." );
}

sub productType {
    my $self = shift;

    return $self->isrc
        ? RPS::File::Sale::TYPE_TRACK
        : RPS::File::Sale::TYPE_ALBUM;
}

sub formatType {
    my $self = shift;

    my $saleType  = $self->_getByFieldName('_sale_type')  || '';
    my $storeName = $self->_getByFieldName('_store_name') || '';

    return RPS::File::Sale::FORMAT_DOWNLOAD if $saleType =~ /^Download$/i;
    return RPS::File::Sale::FORMAT_TETHERED if $saleType =~ /^Locker$/i;
    return RPS::File::Sale::FORMAT_STREAM   if $saleType =~ /^Stream (?:Ad-Supported|Premium)$/i;

    if ( $saleType =~ /^Other$/i && $storeName =~ /^Spotify$/ ) {
        return RPS::File::Sale::FORMAT_STREAM;
    }

    $self->fail("Unable to determine format type from '$saleType'.");
}

sub artistName {
    my $self = shift;

    if ( $self->productType eq RPS::File::Sale::TYPE_TRACK ) {
        return $self->_getByFieldName('_track_artist');
    }

    return $self->_getByFieldName('_artist_name');
}

sub price     { abs( shift->_getByFieldName('price') || 0 ) }
sub unitPrice { abs shift->SUPER::unitPrice }
sub units {
    my $self = shift;

    my $units = $self->_getByFieldName('units') || 0;
    my $price = $self->_getByFieldName('price') || 0;

    if ( $price > 0 ) {
        $units = $units ? abs($units) : 1;
    } elsif ( $price < 0 ) {
       $units = $units ? -1 * abs($units) : -1;
    }

    return $units;
}

sub _isValidSaleRecord {
    my $self = shift;

    return (defined $self->units || defined $self->price) && $self->serviceID;
}


1;