package RPS::Import::Mtheory::v1;

use strict;
use warnings;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;

use parent 'RPS::Import::ImporterMixed';

sub physical { 2 }

sub _fieldMapExtended {
    {
        digital => {
            option1 => {
                labelName   => 'B',
                serviceID   => 'A',
                countryCode => 'C',
                dateBegin   => 'Y',
                dateEnd     => 'Y',
                productType => 'F',
                formatType  => 'G',
                artistName  => 'K',
                upc         => 'M',
                albumName   => 'N',
                isrc        => 'O',
                trackName   => 'Q',
                units       => 'S',
                price       => 'V',
                mediaType   => 'H',
            },
         },
    };
}

sub _unverifiedFieldMapExtended { {} }

sub _headerIdentifierExtended {
    {
        digital => {
            option1 => {
                upc => 'upc_ean',
            },
        },
    };
}

sub currencyCode { 'USD' }

sub countryCode {
    my $self = shift;

    my $name = $self->_getByFieldName('countryCode') || '';
    return 'US' if $name =~ /^USA$/i;

    my $oCountry = Common::Country->Get($name);
    return $oCountry ? $oCountry->alpha2 : undef ;
}

sub saleDates {
    my $self = shift;

    my $dateBegin = $self->_getByFieldName('dateBegin') || '';
    if ( my ($m, $d, $y) = $dateBegin =~ /^(\d{1,2})[-_\/](\d{1,2})[-_\/](\d{2}$)/ ) {
        return $self->_getDates(
            date_begin => sprintf( "20%02d-%02d-%02d", $y, $m, $d)
        );
    } elsif ( my ($y, $d, $m) = $dateBegin =~ /^(\d{4})[-_\/](\d{1,2})[-_\/](\d{1,2}$)/ ) {
        return $self->_getDates(
            date_begin => sprintf( "%04d-%02d-%02d", $y, $m, $d)
        );
    } elsif ( my ($m, $d, $y) = $dateBegin =~ /^(\d{1,2})[-_\/](\d{1,2})[-_\/](\d{4}$)/ ) {
        return $self->_getDates(
            date_begin => sprintf( "%04d-%02d-%02d", $y, $m, $d)
        );
    }

    $self->fail("Can't determine sales date from '$dateBegin'.");
}

sub productType {
    my $self = shift;

    my $type = $self->_getByFieldName('productType') || '';
    if ( $type =~ /^(?:album|A)$/i ) {
        return RPS::File::Sale::TYPE_ALBUM;
    } elsif ( $type =~ /^(?:track|T)$/i ) {
        return RPS::File::Sale::TYPE_TRACK;
    }

    $self->fail( "Unable to determine product_type from: '$type'." );
}

sub formatType {
    my $self = shift;

    my $type = $self->_getByFieldName('formatType') || '';
    return RPS::File::Sale::FORMAT_STREAM   if $type =~ /^DS$/i;
    return RPS::File::Sale::FORMAT_DOWNLOAD if $type =~ /^D$/i;

    $self->fail( "Unable to determine format_type from: '$type'." );
}

sub mediaType {
    my $self = shift;

    my $type = $self->_getByFieldName('mediaType') || '';
    return RPS::DB::Item::MediaType::kMediaTypeAudio if $type =~ /^A$/i;
    return RPS::DB::Item::MediaType::kMediaTypeVideo if $type =~ /^V$/i;

    $self->fail( "Unable to determine media_type from '$type'." );
}

sub upc {
    my $self = shift;

    my $upc = $self->_getByFieldName('upc') || '';
    return sprintf "%d", $upc;
}

sub units {
    my $self = shift;

    my $units = $self->_getByFieldName('units');
    my $price = $self->_getByFieldName('price') || 0;

    # check if the value of units is undefined or blank
    $self->fail("The value of units is not defined.") if !defined $units || $units eq '';

    if ( $price > 0 ) {
        $units = $units ? abs($units) : 1;
    } elsif ( $price < 0 ) {
        $units = $units ? -1 * abs($units) : -1;
    }

    return $units;
}

sub _isValidSaleRecord {
    return ( $_[0]->_getByFieldName('units') || $_[0]->_getByFieldName('price') )
}


1;