#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2013 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------

package RPS::Import::MusicQubed::v2;

use strict;

use lib '/app/tools/common/lib';
use Common::Assert;
use Common::UTF8;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;

use base 'RPS::Import::Importer';

sub _fieldMap {
    {
        dateBegin    => 'B',
        dateEnd      => 'C',
        formatType   => 'D',
        productType  => 'G',
        artistName   => 'I',
        isrc         => 'H',
        trackName    => 'J',
        price        => 'O',
        units        => 'K',
        countryCode  => 'Q',
        currencyCode => 'R',
        serviceID    => 'P',
    };
}

sub _noHeader { 1 }

sub _unverifiedFieldMap {
    { altCurrencyCode => 'S', };
}

sub _isValidSaleRecord {
    my $self      = shift;
    my $units     = $self->_getByFieldName('units');
    my $trackName = $self->_getByFieldName('trackName');

    return ( $units && $trackName ) ? 1 : undef;
}

sub currencyCode {
    my $self        = shift;
    my $currency    = $self->_getByFieldName('currencyCode');
    my $altCurrency = $self->_getByFieldName('altCurrencyCode');

    return ( $self->{sheetname} =~ /^subscriptions$/i ) ? $currency : $altCurrency;
}

sub mediaType { RPS::DB::Item::MediaType::kMediaTypeAudio }

sub formatType {
    my $self = shift;
    my $type = $self->_getByFieldName('formatType');

    if ( $type =~ /^stream$/i ) {
        return RPS::File::Sale::FORMAT_STREAM;
    } elsif ( $type =~ /^download$/i ) {
        return RPS::File::Sale::FORMAT_DOWNLOAD;
    }

    $self->fail("Unable to determine formatType from '$type'");
}

sub productType {
    my $self = shift;
    my $type = $self->_getByFieldName('productType');

    if ( $type =~ /^electronic single$/i ) {
        return RPS::File::Sale::TYPE_TRACK;
    }

    $self->fail("Unable to determine productType from '$type'");
}

sub saleDates {
    my $self = shift;

    my $dateBegin = $self->_getByFieldName('dateBegin');
    my $dateEnd   = $self->_getByFieldName('dateEnd');

    my ( $startDate, $endDate ) = $self->_getDates( date_begin => $dateBegin, date_end => $dateEnd );

    return ( $startDate, $endDate );
}

sub serviceID {
    my $self    = shift;
    my $service = $self->_getByFieldName('serviceID');

    $self->fail("Service name not defined") unless ($service);

    my $serviceID = $self->getServiceID( lc($service) ) || $RPS::Import::ServiceMap::SERVICE_ALIASES{ lc $service };

    $self->fail("Unable to determine service id from '$service'") unless ($serviceID);

    return $serviceID;
}

sub _processSheet {
    my $self     = shift;
    my $sheet    = shift;
    my $sheetnum = shift;

    if ( $self->{sheetname} =~ /^(subscriptions|a la carte)$/i ) {
        return $self->SUPER::_processSheet( $sheet, $sheetnum );
    }

    #    else { print STDERR "Skipping sheet '". $self->{sheetname} . "'\n"; }
}

###
1;    # Play nicely.
###