package RPS::Import::Muzak2;

use strict;

use Date::Calc qw(Days_in_Month);
use Data::Dumper;

use lib '/app/tools/common/lib';
use Common::Util;
use Common::Consts;

use lib '/app/tools/data_classes/lib';

# map version num to the field order
my %fieldMap = (
    '2a' => {
        track  => 0,
        artist => 1,
        album  => 2,
        label  => 3,
        units  => 5,

    },
    '2b' => {
        product_id => 0,
        track      => 1,
        artist     => 2,
        album      => 3,
        label      => 4,
        units      => 6,
    },
    3 => {
        product_id => 0,
        track      => 1,
        artist     => 2,
        album      => 3,
        label      => 4,
        units      => 5,
        titlelink  => 0,
        titleunits => 1,
        titletotal => 2,
    },
    4 => {
        track   => 0,
        artist  => 1,
        album   => 2,
        label   => 3,
        units   => 5,
        revenue => 6,
    },
    5 => {
        track   => 0, # A
        artist  => 1, # B
        album   => 2, # C
        label   => 3, # D
        units   => 4, # E
        revenue => 5, # F
    },
    6 => {
        track   => 0, # A
        artist  => 1, # B
        album   => 2, # C
        label   => 3, # D
        units   => 4, # E
        revenue => 5, # F
    },

);

use lib '/app/tools/rps/lib';
use RPS::File::Sale;
use RPS::Import::Importer;
use base 'RPS::Import::Importer';

#public methods

sub _importLines {
    my $self = shift;
    my %args = @_;

    my $retval   = undef;
    my $lines    = $args{lines};
    my $fileObj  = $args{file};
    my $fileName = $fileObj->OrigFileName;
    my $version  = $fileObj->VersionNum;

    my $sheet_count = 0;
    my $sheet_names = $args{sheet_names};
    my ( $linenum, $dateBegin, $dateEnd, %prices );
    my $offsets = $fieldMap{$version};
    ( $dateBegin, $dateEnd ) = $self->_getDates($fileName);

    # version 4 of this importer has an excel formula for price, so I'm doing one
    # pass over the file to total up the units and revenue and then figure unitPrice
    my $totalUnits   = 0;
    my $totalRevenue = 0;
    my $unitPrice    = 0;
    if ( $fileObj->VersionNum =~ /^4|5|6$/ ) {
        foreach my $sheet ( @{ $args{sheets} } ) {
            foreach my $line (@$sheet) {
                my $artist  = $line->[ $offsets->{artist} ];
                my $track   = $line->[ $offsets->{track} ];
                my ($units) = $line->[ $offsets->{units} ] =~ m/^(-?\d+)$/;

                if ( $units && $track && $artist ) {
                    $totalUnits   += $units;
                    $totalRevenue += $line->[ $offsets->{revenue} ];
                }
            }
        }
        $unitPrice = $totalRevenue / $totalUnits;
    }
    print "unitPrice: " . $unitPrice . "\n";

    foreach my $sheet ( @{ $args{sheets} } ) {
        if ( $sheet_names->[$sheet_count] =~ /(\d)(\w\w)?\s?Q\s?(\d{2,4})/i ) {
            ( $dateBegin, $dateEnd ) = $self->_getDates( $sheet_names->[$sheet_count] );
        }

        unless ( $dateBegin && $dateEnd ) {
            $self->errstr("Couldn't get dates from $fileName");
            return undef;
        }

        $version = "2a" if ( $dateBegin =~ /2006-07-01/ );
        $version = "2b" if ( $dateBegin !~ /2006-07-01/ );

        $linenum = 1;
        if ( $sheet_names->[$sheet_count] =~ /price/i ) {
            foreach my $line (@$sheet) {
                if ( $line->[ $offsets->{titlelink} ] !~ /title/i && $line->[ $offsets->{titlelink} ] ne "" ) {
                    my $tmptitle = $line->[ $offsets->{titlelink} ];
                    $tmptitle =~ s/(\W)//g;
                    $prices{$tmptitle} = ( $line->[ $offsets->{titletotal} ] / $line->[ $offsets->{titleunits} ] );
                }
                $linenum++;
            }
        }
        else {
            foreach my $line (@$sheet) {
                my $prodtype   = RPS::File::Sale::TYPE_TRACK;
                my $format     = RPS::File::Sale::FORMAT_BACKGROUNDMUSIC;
                my $artist     = $line->[ $offsets->{artist} ];
                my $album      = $line->[ $offsets->{album} ];
                my $track      = $line->[ $offsets->{track} ];
                my $cleantrack = $track;
                my $label      = $line->[ $offsets->{label} ];
                my ($units)    = $line->[ $offsets->{units} ] =~ m/^(-?\d+)$/;
                $cleantrack =~ s/(\W)//g;

                if ( $units && $track && $artist ) {
                    my $sale = RPS::Import::SaleRec->new();

                    $sale->productType($prodtype);
                    $sale->formatType($format);
                    $sale->dateBegin($dateBegin);
                    $sale->dateEnd($dateEnd);
                    $sale->artistName($artist);
                    $sale->albumName($album);
                    $sale->trackName($track);
                    $sale->labelName($label);

                    # unitPrice is calculated for the file above and used here...
                    if ( $fileObj->VersionNum =~ /^4|5|6$/ ) {
                        $sale->price($unitPrice);
                    } else {
                        $sale->price( $prices{$cleantrack} ) if ( defined $prices{$cleantrack} );
                    }
                    $sale->units($units);
                    $sale->lineNum($linenum);
                    $sale->countryCode("US");
                    $sale->serviceID( Client::Service::DSP_MUZAK );
                    $self->_insertSale( sale => $sale );

                }

                $linenum++;
            }
        }
        $sheet_count++;
    }
    return $linenum;
}

#
# Private methods
#

sub _getDates {
    my $self  = shift;
    my $fname = shift;
    my ( $beginDate, $endDate, $year, $qtr );
    print STDERR "XX " . $fname . " XX\n";
    if ( $fname =~ /(\d)(\w\w)?\s?Q\s?(\d{2,4})/i ) {
        $year = length($3) == 2 ? "20$3" : $3;
        $qtr  = $1;
        return $self->_makeDate( $qtr, $year );
    }

    # for version 4, the date is in the tab in this odd format "YYYY XQtr Label Detail"
    # where X is the quarter number
    if ( $fname =~ m/(\d{4}) (\d)Qtr/ ) {
        $year = $1;
        $qtr  = $2;
        return $self->_makeDate( $qtr, $year );
    }

    # for version 5, file name is like XQYYYY-Muzak
    # where X is the quarter number
    if (  $fname =~ m/(\d)[\sQtr]*(\d{4})/ ) {
        $year = $2;
        $qtr  = $1;
        return $self->_makeDate( $qtr, $year );
    }

    print STDERR "X->" . $year . "<->" . $qtr . "<-X\n";

    return undef;
}

sub _makeDate {
    my $self = shift;
    my $qtr  = shift;
    my $year = shift;
    my ( $beginDate, $endDate );

    if ( $qtr == 1 ) {
        $beginDate = $year . "-01-01";
        $endDate = $year . "-03-" . Days_in_Month( $year, 3 );
    } elsif ( $qtr == 2 ) {
        $beginDate = $year . "-04-01";
        $endDate = $year . "-06-" . Days_in_Month( $year, 6 );
    } elsif ( $qtr == 3 ) {
        $beginDate = $year . "-07-01";
        $endDate = $year . "-09-" . Days_in_Month( $year, 9 );
    } elsif ( $qtr == 4 ) {
        $beginDate = $year . "-10-01";
        $endDate = $year . "-12-" . Days_in_Month( $year, 12 );
    }

    return ( $beginDate, $endDate );
}

###
1;    # Play nicely.
###