package RPS::Import::NaxosDigital::v1;

use strict;
use warnings;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;

use base ('RPS::Import::MapFaceBase', 'RPS::Import::ImporterMixed' );

sub physical { 0 }

sub _fieldMapExtended {
    {
        digital => {
            option1 => {
                labelName    => 'B',
                serviceID    => 'A',
                countryCode  => 'C',
                dateBegin    => 'D',
                dateEnd      => 'D',
                productType  => 'O',
                formatType   => 'P',
                upc          => 'F',
                isrc         => 'H',
                trackName    => 'I',
                units        => 'L',
                price        => 'R',
                artistName   => 'J',
                albumName    => 'G',
            },
        },
    };
}
sub _unverifiedFieldMapExtended {
    {
        digital => {
            option1 => {
                _artist_name  => 'J',
                _album_name   => 'G',
            },
        },
    };
}

sub _headerIdentifierExtended {
    {
        digital => {
            option1 => {
                upc => 'UPC',
            },
        },
    };
}

sub currencyCode { 'USD' }
sub mediaType    { RPS::DB::Item::MediaType::kMediaTypeAudio }

sub serviceID {
    my $self = shift;

    my $service = lc( $self->_getByFieldName('serviceID') || '' );
    my $serviceID = $self->getServiceID($service) || $RPS::Import::ServiceMap::SERVICE_ALIASES{$service};
    return $serviceID if $serviceID;

    $self->handleError( "Unknown service: $service", RPS::DB::Item::SaleImportError::kErrorService );
}

sub countryCode {
    my $self = shift;

    my $country = $self->_getByFieldName('countryCode') || '';
    my $oCountry = Common::Country->Get($country) if $country;
    return $oCountry->alpha2 if $oCountry;

    $self->fail( "Unable to determine country_code from: '$country'." );
}

sub productType {
    my $self = shift;

    my $type  = $self->_getByFieldName('productType')  || '';

    return RPS::File::Sale::TYPE_TRACK if (lc($type) eq 'track');
    return RPS::File::Sale::TYPE_ALBUM if (lc($type) eq 'album');
}

sub formatType {
    my $self = shift;

    my $type  = $self->_getByFieldName('formatType')  || '';

    return RPS::File::Sale::FORMAT_DOWNLOAD if $type =~ /^Download|OTA$/i;
    return RPS::File::Sale::FORMAT_STREAM   if $type =~ /^Streaming|CONTENTID|Match$/i;
    return RPS::File::Sale::FORMAT_PERFORMANCE   if $type =~ /^PPI|Public Performance$/i;

    $self->fail("Unable to determine format type from '$type'.");
}

sub artistName {
    my $self = shift;

    my $artist = $self->_getByFieldName("artistName") || "";
    my $album = $self->_getByFieldName("albumName") || "";
    if (!$artist || $artist eq "/") {
       $artist =  ($album =~ /^(.+?):.*/) ? $1 : $album;
    }

    return $artist;
}

sub albumName {
    my $self = shift;

    my $album = $self->_getByFieldName("albumName") || "";
    $album = $1 if ($album =~ /.*?:(.*)/);

    return $album;
}

sub price     { abs( shift->_getByFieldName('price') || 0 ) }
sub unitPrice { abs shift->SUPER::unitPrice }
sub units {
    my $self = shift;

    my $units = $self->_getByFieldName('units') || 0;
    my $price = $self->_getByFieldName('price') || 0;

    if ( $price > 0 ) {
        $units = $units ? abs($units) : 1;
    } elsif ( $price < 0 ) {
       $units = $units ? -1 * abs($units) : -1;
    }

    return $units;
}

sub free {
    my $self = shift;

    my $price = $self->_getByFieldName('price') || 0;
    return ($price == 0 ? 1 : 0);
}

sub _isValidSaleRecord {
    my $self = shift;

    return ($self->units || $self->price) && $self->serviceID;
}

sub _mapFaceCompatibleVersions {
    return ( 1 );
}

sub _mapFaceServiceID {
    return ('serviceID');
}

sub _mapFaceCountryCode {
    return ( 'serviceID', 'countryCode' );
}

sub _mapFaceProductType {
    return ( 'serviceID', 'mediaType', 'formatType', 'productType' );
}

sub _mapFaceFormatType {
    return ( 'serviceID', 'mediaType', 'formatType', 'productType' );
}

sub _mapFaceMediaType {
    return ( 'serviceID', 'mediaType', 'formatType', 'productType' );
}

1;