package RPS::Import::Nokia::v8;

use strict;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;

use base 'RPS::Import::Importer';

sub _headerIdentifier { ( upc => 'UPC Code' ) }

sub _fieldMap {
    {
        dateBegin       => 'E',
        serviceID       => 'B',
        formatType      => 'C',
        artistName      => 'F',
        trackName       => 'G',
        isrc            => 'H',
        upc             => 'I',
        labelName       => 'K',
        countryCode     => 'M',
        currencyCode    => 'R',
        clientProductID => 'L',
        units           => 'S',
        price           => 'Q',
    };
}

sub saleDates {
    my $self = shift;

    my $dt = $self->_getByFieldName('dateBegin');

    my $startDate;
    my $endDate;

    if ( $dt =~ /^(\d{2})\/(\d{4})$/ )    # MM/YYYY
    {
        my $_start = sprintf( "%04d-%02d-%02d", $2, $1, 1 );

        ( $startDate, $endDate ) = $self->_getDates( date_begin => $_start );
    } else {
        ( $startDate, $endDate ) = $self->_getDates( date_begin => $dt );
    }

    $self->fail( "Line " . $self->{linenum} . ": unable to get dates from '$dt'" ) if ( !$startDate );
    return ( $startDate, $endDate );
}

sub productType {
    my $self = shift;
    return RPS::File::Sale::TYPE_TRACK;
}

sub formatType {
    my $self = shift;
    my $format = $self->_getByFieldName('formatType') || return;

    if ( $format =~ /^R$/i ) {
        return RPS::File::Sale::FORMAT_STREAM;
    }

    $self->fail("Unknown format type '$format'");
}

sub mediaType { RPS::DB::Item::MediaType::kMediaTypeAudio }

sub serviceID {
    my $self    = shift;
    my $service = $self->_getByFieldName('serviceID');

    $self->fail("Service name not defined") unless ($service);

    if ( $service =~ /^ovi music/i ) {
        return Client::Service::DSP_OVI_MUSIC;
    }

    my $serviceID = $self->getServiceID( lc($service) ) || $RPS::Import::ServiceMap::SERVICE_ALIASES{ lc $service };

    $self->fail("Unable to determine service id from '$service'") unless ($serviceID);

    return $serviceID;
}

###
1;    # Play nicely.
###