#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2014 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------

package RPS::Import::OrchardPhysical2;

use strict;

use Date::Calc qw(Days_in_Month);

use lib '/app/tools/common/lib';
use Common::Assert;
use Common::UTF8;
use Common::Country;

use lib '/app/tools/rps/lib';

use base 'RPS::Import::Importer';

sub _fieldMap {
    {
        # header
        #
        labelName => 'J',

        # detail section of each sheet
        #
        dateBegin        => 'B',
        countryCode      => 'L',
        artistName       => 'D',
        albumName        => 'E',
        sales            => 'F',    # Qty.
        salesRevenue     => 'K',    # Net Amount
        totalRevenue     => 'K',
        serviceProductID => 'C',

    };
}

sub _headerIdentifier { ( dateBegin => 'Document date' ) }

sub physical { 1; }

sub channel { RPS::File::Sale::CHANNEL_RETAIL; }

sub priceLevel { RPS::File::Sale::PLEVEL_FULL; }

sub productType { RPS::File::Sale::TYPE_CD; }

sub configuration { 'CD'; }

sub currencyCode {
    return shift->{_currencyCode};    # See _preProcess
}

sub labelName {
    return shift->{_labelName};       # See _processSheet
}

sub countryCode {
    my $self = shift;

    my $name    = $self->_getByFieldName('countryCode');
    my $country = Common::Country->Get($name);
    if ($country) {
        return $country->alpha2();
    } else {
        return $name;
    }
}

sub saleDates {
    my $self = shift;
    my $sdate;
    my $edate;
    my $dt = $self->_getByFieldName('dateBegin');

    if ( $dt =~ /^(\d{4})-(\d{1,2})-(\d{1,2})$/ ) {
        my $month = $2;
        my $year  = $1;

        $sdate = sprintf( "%04d-%02d-01", $year, $month );
        $edate = sprintf( "%04d-%02d-%02d", $year, $month, Days_in_Month( $year, $month ) );

        return ( $sdate, $edate );
    } elsif ( $dt =~ /^\d{5}$/ ) {
        $sdate = Spreadsheet::ParseExcel::Utility::ExcelFmt( "yyyy-mm-dd", $dt );
        return $self->_getDates( date_begin => $sdate );
    }
}

sub sales {
    my $self  = shift;
    my $sales = $self->_getByFieldName('sales');

    return ( $sales > 0 ) ? $sales : 0;
}

sub salesRevenue {
    my $self         = shift;
    my $salesRevenue = $self->_getByFieldName('salesRevenue');

    return ( $salesRevenue > 0 ) ? $salesRevenue : 0;
}

sub returns {
    my $self         = shift;
    my $sales        = $self->_getByFieldName('sales');
    my $salesRevenue = $self->_getByFieldName('salesRevenue');
    return ( $sales < 0 && $salesRevenue < 0 ) ? abs($sales) : 0;
}

sub returnsRevenue {
    my $self         = shift;
    my $sales        = $self->_getByFieldName('sales');
    my $salesRevenue = $self->_getByFieldName('salesRevenue');

    return ( $sales < 0 && $salesRevenue < 0 ) ? abs($salesRevenue) : 0;
}

sub totalRevenue {
    my $self         = shift;
    my $salesRevenue = $self->_getByFieldName('totalRevenue');

    return $salesRevenue;
}

sub _isValidSaleRecord {
    my $self = shift;

    # The line is valid if it has sales or returns, and has an album title and artist name
    #
    return ( ( $self->sales != 0 || $self->returns != 0 ) && $self->albumName && $self->artistName );
}

sub _preProcess {
    my $self = shift;
    my %args = @_;

    # Get the currency code information from the 'Label DS' tab
    #
    my $sheetNames = $args{sheet_names};

    my $sheetCount = 0;
  SHEET: foreach my $sheet ( @{ $args{sheets} } ) {
        my $sheetName = $sheetNames->[$sheetCount];

        next if ( $sheetName !~ /^label ds$/i );

        foreach my $line (@$sheet) {
            $self->{line} = $line;

            my $ccode = $self->_getByFieldName('currencyCode');

            if ( $ccode =~ /^US Dollars \$/i ) {
                $self->{_currencyCode} = 'USD';
                last;
            }
        }

        $sheetCount++;
    }

}

sub _processSheet {
    my $self     = shift;
    my $sheet    = shift;
    my $sheetnum = shift;

    # Skip the summary sheet
    #
    if ( $self->sheetname !~ /^label ds$/i ) {
        $self->{_labelName} = '';
        foreach my $line (@$sheet) {
            $self->{line} = $line;

            my $label = $self->_getByFieldName('labelName');
            if ($label) {
                $self->{_labelName} = $label;
                last;
            }
        }
        return $self->SUPER::_processSheet( $sheet, $sheetnum );
    }
}

###
1;    # Play nicely.
###