#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2013 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------

package RPS::Import::PIAS::v6;

use strict;

use lib '/app/tools/common/lib';
use Common::Country;
use Common::Assert;
use Date::Calc qw(Days_in_Month Decode_Month);

use lib '/app/tools/rps/lib';
use base 'RPS::Import::Importer';

sub _fieldMap {
    {
        # Header
        dateBegin    => 'C',
        currencyCode => 'C',

        # Detail
        countryCode  => 'F',
        productType  => 'H',
        artistName   => 'B',
        upc          => 'E',
        albumName    => 'C',
        priceLevel   => 'I',
        retailPrice  => 'L',
        totalRevenue => 'R',
    };
}

sub _unverifiedFieldMap {
    { netUnits => 'Q', };
}

sub physical { 1; }

sub _headerIdentifier { ( albumName => 'PRODUCT' ) }

sub channel { RPS::File::Sale::CHANNEL_RETAIL }

sub artistName {
    my $self = shift;
    my $name = $self->_getByFieldName('artistName');
    $name =~ s/^-   //;    # Remove any cruft if necessary
    return $name;
}

sub priceLevel {
    my $self          = shift;
    my $priceCategory = $self->_getByFieldName('priceLevel');

    if ( $priceCategory =~ /^(INVOICE|CREDIT NOTE)$/i ) {
        return RPS::File::Sale::PLEVEL_UNKNOWN;
    } elsif ( $priceCategory =~ /^FULL PRICE$/i ) {
        return RPS::File::Sale::PLEVEL_FULL;
    } elsif ( $priceCategory =~ /^MID PRICE$/i ) {
        return RPS::File::Sale::PLEVEL_MID;
    }
    $self->fail("Unable to get price level from $priceCategory");
}

sub currencyCode {
    my $self = shift;
    return $self->{_currencyCode} if ( $self->{_currencyCode} );
}

sub saleDates {
    my $self = shift;

    return ( $self->{_startDate}, $self->{_endDate} ) if ( $self->{_startDate} );    # from header of current sheet; see _processSheet
}

sub countryCode {
    my $self  = shift;
    my $cname = $self->_getByFieldName('countryCode');

    my %countryMap = ( 'East Timor' => 'Timor-Leste' );

    $cname = $countryMap{$cname} if ( exists $countryMap{$cname} );
    my $countryObj = Common::Country->Get($cname);
    my $countryCode = $countryObj->alpha2() if ($countryObj);
    return $countryCode;
}

sub productType {
    my $self = shift;
    my $type = $self->_getByFieldName('productType');

    if (   $type =~ /^(lp|2lp|2nd LP Format|12\" EP)$/i
        || $type =~ /^(12ltd|12|2x12)$/i ) {
        return RPS::File::Sale::TYPE_LP;
    } elsif ( $type =~ /^7$/i ) {
        return RPS::File::Sale::TYPE_LP5;
    } elsif ( $type =~ /^cd$/i
        || $type =~ /^cd digipack$/i ) {
        return RPS::File::Sale::TYPE_CD;
    } elsif ( $type =~ /^(2cd|4cd)$/i ) {
        return RPS::File::Sale::TYPE_DBL_CD;
    }
    $self->fail("Unknown configuration '$type'");
}

sub sales {
    my $self     = shift;
    my $netUnits = $self->_getByFieldName('netUnits');

    return ( $netUnits > 0 ) ? $netUnits : 0;
}

sub salesRevenue {
    my $self    = shift;
    my $revenue = $self->_getByFieldName('totalRevenue');

    return ( $revenue > 0 ) ? $revenue : 0;
}

sub returns {
    my $self     = shift;
    my $netUnits = $self->_getByFieldName('netUnits');

    return ( $netUnits < 0 ) ? abs($netUnits) : 0;
}

sub returnsRevenue {
    my $self    = shift;
    my $revenue = $self->_getByFieldName('totalRevenue');

    return ( $revenue < 0 ) ? abs($revenue) : 0;
}

sub _processSheet {
    my $self     = shift;
    my $sheet    = shift;
    my $sheetnum = shift;

    if ( $self->{sheetname} =~ /royalties/i ) {

        # Grab data from area above the header
        #
        foreach my $line (@$sheet) {
            $self->{line} = $line;

            # We'll grab the date begin and currency code from above the header area
            #
            my $label = $self->_getByFieldName('artistName');    # get the row label

            if ( !defined $self->{_startDate} ) {
                if ( $label =~ /^Reporting Period\:$/i ) {
                    my $dt = $self->_getByFieldName('dateBegin');

                    # Ex. 01/07/2014 To 31/12/2014
                    #
                    if ( $dt =~ /^(\d{1,2})\/(\d{1,2})\/(\d{4}) To (\d{1,2})\/(\d{1,2})\/(\d{4})$/i ) {
                        my ( $sDay, $sMonth, $sYear, $eDay, $eMonth, $eYear ) = ( $1, $2, $3, $4, $5, $6 );
                        my $sdate = sprintf( "%04d-%02d-%02d", $sYear, $sMonth, $sDay );
                        my $edate = sprintf( "%04d-%02d-%02d", $eYear, $eMonth, $eDay );
                        $self->{_startDate} = $sdate;
                        $self->{_endDate}   = $edate;
                    }
                }
            }

            if ( !defined $self->{_currencyCode} ) {
                if ( $label =~ /^Currency\:$/i ) {
                    $self->{_currencyCode} = $self->_getByFieldName('currencyCode');
                }
            }

            last if ( $self->{_startDate} && $self->{_currencyCode} );    # all done

        }

        # Now process the rest of the sheet
        #
        $self->SUPER::_processSheet( $sheet, $sheetnum );
    }
}

sub _isValidSaleRecord {
    my $self = shift;

    # The line is valid if it has sales or returns, and has an album title
    #
    return ( ( $self->sales != 0 || $self->returns != 0 ) && $self->albumName );
}

###
1;    # Play nicely.
###