#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2013 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------

package RPS::Import::PIASDigital::v6;

use strict;

use lib '/app/tools/common/lib';
use Common::Country;
use Common::Assert;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;
use base 'RPS::Import::Importer';

sub _fieldMap {
    {
        # header
        dateBegin    => 'C',
        dateEnd      => 'C',
        currencyCode => 'C',

        # detail
        countryCode => 'F',
        serviceID   => 'G',
        upc         => 'E',
        isrc        => 'D',
        artistName  => 'B',
        albumName   => 'C',
        trackName   => 'C',
        units       => 'Q',
        price       => 'R',
    };
}

sub _unverifiedFieldMap {
    {
        fmtType  => 'H',
        priceCat => 'I',
    };
}

sub _headerIdentifier { ( albumName => 'PRODUCT' ) }

sub _processSheet {
    my $self     = shift;
    my $sheet    = shift;
    my $sheetnum = shift;

    if ( $self->{sheetname} =~ /^royalties(?:\s\d+)?$/i ) {

        # Grab data from area above the header
        #
        foreach my $line (@$sheet) {
            $self->{line} = $line;

            # We'll grab the date begin and currency code from above the header area
            #
            my $label = $self->_getByFieldName('artistName');    # get the row label

            if ( !defined $self->{_startDate} ) {
                if ( $label =~ /^Reporting Period\:$/i ) {
                    my $dt = $self->_getByFieldName('dateBegin');

                    # Ex. 01/07/2014 To 31/12/2014
                    #
                    if ( $dt =~ /^(\d{1,2})\/(\d{1,2})\/(\d{4}) To (\d{1,2})\/(\d{1,2})\/(\d{4})$/i ) {
                        my ( $sDay, $sMonth, $sYear, $eDay, $eMonth, $eYear ) = ( $1, $2, $3, $4, $5, $6 );
                        my $sdate = sprintf( "%04d-%02d-%02d", $sYear, $sMonth, $sDay );
                        my $edate = sprintf( "%04d-%02d-%02d", $eYear, $eMonth, $eDay );
                        $self->{_startDate} = $sdate;
                        $self->{_endDate}   = $edate;
                    }
                }
            }

            if ( !defined $self->{_currencyCode} ) {
                if ( $label =~ /^Currency\:$/i ) {
                    $self->{_currencyCode} = $self->_getByFieldName('currencyCode');
                }
            }

            last if ( $self->{_startDate} && $self->{_currencyCode} );    # all done

        }

        # Now process the rest of the sheet
        #
        $self->SUPER::_processSheet( $sheet, $sheetnum );
    } else {
        print STDERR "_processSheet: skipping '" . $self->{sheetname} . "'\n";
    }
}

sub artistName {
    my $self = shift;
    my $name = $self->_getByFieldName('artistName');
    $name =~ s/^-   //;    # Remove any cruft if necessary
    return $name;
}

sub currencyCode {
    my $self = shift;
    return $self->{_currencyCode} if ( $self->{_currencyCode} );
}

sub saleDates {
    my $self = shift;

    return ( $self->{_startDate}, $self->{_endDate} ) if ( $self->{_startDate} );    # from header of current sheet; see _processSheet
}

sub serviceID {
    my $self      = shift;
    my $name      = $self->_getByFieldName('serviceID');
    my $serviceID = $self->getServiceID($name) || $RPS::Import::ServiceMap::SERVICE_ALIASES{ lc $name };
    $self->fail("Unknown service '$name'") if ( !$serviceID );
    return $serviceID;
}

sub countryCode {
    my $self  = shift;
    my $cname = $self->_getByFieldName('countryCode');

    my $countryObj = Common::Country->Get($cname);
    my $countryCode;
    if ($countryObj) {
        $countryCode = $countryObj->alpha2();
    } else {
        $self->fail("Unknown country '$cname'");
    }
    return $countryCode;
}

sub productType {
    my $self    = shift;
    my $fmtType = $self->_getByFieldName('fmtType');
    if ( $fmtType =~ /^digital (album|ep)$/i ) {
        return RPS::File::Sale::TYPE_ALBUM;
    } 
    elsif ( $fmtType =~ /^digital (track|single)$/i || $fmtType =~ /^digital video short form$/i ) {
        return RPS::File::Sale::TYPE_TRACK;
    }

    $self->fail("Unknown product type '$fmtType'");
}

sub formatType {
    my $self = shift;
    my $type = $self->_getByFieldName('priceCat');
    if (   $type =~ /^Breakage$/i
        || $type =~ /^Cloud Streaming$/i
        || $type =~ /^Official Ad-funded Streaming Product$/i
        || $type =~ /^Streaming$/i
        || $type =~ /^Subscr' Streaming product$/i
        || $type =~ /^Subsc' Stream Prod \(A\)$/i 
        || $type =~ /^Discount subsc' streaming product$/i 
        || $type =~ /^Radio streaming product$/i 
        || $type =~ /^Subsc' UGC product$/i )

    {
        return RPS::File::Sale::FORMAT_STREAM;
    } elsif ( $type =~ /^A la carte download Product$/i ) {
        return RPS::File::Sale::FORMAT_DOWNLOAD;
    } elsif ( $type =~ /^Subscr' Stream prod\(teth\)$/i
        || $type =~ /^Subscription DL Product$/i ) {
        return RPS::File::Sale::FORMAT_TETHERED;
    }
    $self->fail("Unknown format '$type'");
}

sub mediaType {
    my $self    = shift;
    my $fmtType = $self->_getByFieldName('fmtType');
    if ( $fmtType =~ /^digital (album|track|single|ep)$/i ) {
        return RPS::DB::Item::MediaType::kMediaTypeAudio;
    } elsif ( $fmtType =~ /^digital video short form$/i ) {
        return RPS::DB::Item::MediaType::kMediaTypeVideo;
    }
    $self->fail("Unknown media type '$fmtType'");
}

sub albumName {
    my $self = shift;
    return ( $self->productType eq RPS::File::Sale::TYPE_ALBUM ) ? $self->_getByFieldName('albumName') : '';
}

sub trackName {
    my $self = shift;
    return ( $self->productType eq RPS::File::Sale::TYPE_TRACK ) ? $self->_getByFieldName('trackName') : '';
}

sub isrc {
    Common::Util::normalize_isrc( shift->SUPER::isrc );
}

sub units {
    my $self  = shift;
    my $units = $self->SUPER::units() || return;
    my $price = $self->SUPER::price();

    # The 'sign' of the units is driven by the price.
    # If the price is negative, we'll store negative units,
    # regardless of whether the units were positive or negative
    # in the sale file.  Accordingly, the price is always
    # positive.  This ensures that returns are recorded correctly.
    #
    if ( defined($price) ) {
        return $price < 0 ? abs($units) * -1 : $units;
    } else {
        return $units;
    }
}

sub unitPrice {
    return abs( shift->SUPER::unitPrice() );
}

###
1;    # Play nicely.
###