package RPS::Import::PlayNetwork::v7;

use strict;
use warnings;

use lib '/app/tools/rps/lib';
use Date::Calc qw(Days_in_Month);

use parent 'RPS::Import::ImporterMixed';

use constant RE_MM_YYYY => qr/^(\d{1,2})[ ](\d{4})$/;


sub physical { 2 }

sub _fieldMapExtended {
    {
        digital => {
            option1 => {
                labelName  => 'E',
                dateBegin  => 'A',
                dateEnd    => 'A',
                artistName => 'H',
                upc        => 'J',
                isrc       => 'I',
                trackName  => 'G',
                units      => 'L',
                price      => 'N',
            },
         },
    };
}

sub _unverifiedFieldMapExtended { {} }

sub _headerIdentifierExtended {
    {
        digital => {
            option1 => {
                upc => 'UPC',
            },
        },
    };
}

sub countryCode  { 'US' }
sub currencyCode { 'USD' }
sub productType  { RPS::File::Sale::TYPE_TRACK }
sub formatType   { RPS::File::Sale::FORMAT_BACKGROUNDMUSIC }
sub mediaType    { RPS::DB::Item::MediaType::kMediaTypeAudio }

sub _isValidSaleRecord { defined $_[0]->units && defined $_[0]->price }

sub saleDates {
    my $self = shift;

    my $dateBegin = $self->_getByFieldName('dateBegin') || '';
    if ( my ($month, $year) = $dateBegin =~ RE_MM_YYYY ) {
        return $self->_getDates(
            date_begin => sprintf ("%04d-%02d-%02d", $year, $month, 1),
            date_end   => sprintf ("%04d-%02d-%02d", $year, $month, Days_in_Month($year, $month))
        );
    }

    return $dateBegin;
}

sub units {
    my $self = shift;

    my $units = $self->_getByFieldName('units') || 0;
    my $price = $self->_getByFieldName('price') || 0;

    if ( $price > 0 ) {
        $units = $units ? abs($units) : 1;
    } elsif ( $price < 0 ) {
        $units = $units ? -1 * abs($units) : -1;
    }
    return $units;
}


1;