package RPS::Import::PocketGroup;

use strict;

use Date::Calc qw(Days_in_Month Add_Delta_Days Decode_Month);

use lib '/app/tools/common/lib';
use Common::Util;
use Common::Consts;

use lib '/app/tools/data_classes/lib';

# map version num to the field order
my %fieldMap = (
    1 => {
        'isrc'     => 1,
        'artist'   => 2,
        'title'    => 3,
        'price'    => 10,
        'currency' => 11,
        'format'   => 13,
        'country'  => 14,
        'date'     => 16,
        'units'    => 17,
    },
);

use lib '/app/tools/rps/lib';
use RPS::File::Sale;
use RPS::Import::Importer;
use base 'RPS::Import::Importer';

#public methods

sub _importLines {
    my $self = shift;
    my %args = @_;

    my $lines   = $args{sheets}->[1];     ## 2nd sheet, after summary
    my $fileObj = $args{file};
    my $version = $fileObj->VersionNum;
    ##my $version = $args{version}; # for cmd-line testing

    return undef unless ( defined $lines && defined $version );

    my $offsets = $fieldMap{$version};

    my $header_found = 0;
    my $linenum      = 1;
    foreach my $line (@$lines) {
        if ( $header_found == 0 ) {
            $header_found = 1 if ( $line->[ $offsets->{isrc} ] eq "ISRC" );
            $linenum++;
            next;
        }

        my $artist   = $line->[ $offsets->{artist} ];
        my $isrc     = $line->[ $offsets->{isrc} ];
        my $title    = $line->[ $offsets->{title} ];
        my $currency = $line->[ $offsets->{currency} ];
        my $country  = $Common::Consts::COUNTRY_CODE{ lc $line->[ $offsets->{country} ] };

        unless ( $artist || $isrc || $title ) {
            $linenum++;
            next;
        }

        unless ($country) {
            $self->errstr( "unknown country: " . $line->[ $offsets->{country} ] );
            return undef;
        }

        if ( $currency =~ m/^(stirling|gbp|)$/i ) {
            $currency = "GBP";
        } elsif ( $currency =~ m/^(eur)$/i ) {
            $currency = "EUR";
        } else {
            $self->errstr("unknown currency: $currency");
            return undef;
        }

        my ( $dateBegin, $dateEnd ) = $self->_getDates( $line->[ $offsets->{date} ] );
        unless ( defined $dateBegin && defined $dateEnd ) {
            $self->errstr( "couldn't get dates from " . $line->[ $offsets->{date} ] );
            return undef;
        }

        my $format = $line->[ $offsets->{format} ];
        if ( $format =~ m/^tt|rbt|ppc|mpc$/i ) {
            $format = RPS::File::Sale::FORMAT_RINGTONE;
        } elsif ( $format =~ m/^pdl|ft$/i ) {
            $format = RPS::File::Sale::FORMAT_DOWNLOAD;
        } elsif ( $format =~ m/^tdl$/i ) {
            $format = RPS::File::Sale::FORMAT_TETHERED;
        } elsif ( $format =~ m/^str$/i ) {
            $format = RPS::File::Sale::FORMAT_STREAM;
        } elsif ( $format =~ m/^img|vidl|vidc$/i ) {
            ## unsupported
            $linenum++;
            next;
        } else {
            $self->errstr("unknown format: $format");
            return undef;
        }

        my $prodtype = RPS::File::Sale::TYPE_TRACK;

        my ($units) = $line->[ $offsets->{units} ] =~ m/^(-?\d+)$/;
        my ($price) = $line->[ $offsets->{price} ] =~ m/^(\d*\.?\d*)$/;

        $price = ( $units != 0 ) ? ( $price / $units ) : 0;

        if ( $units && $price && $title && $artist && $format ) {
            my $sale = RPS::Import::SaleRec->new();

            $sale->productType($prodtype);
            $sale->dateBegin($dateBegin);
            $sale->dateEnd($dateEnd);
            $sale->isrc($isrc);
            $sale->artistName($artist);
            $sale->albumName($title) if ( $prodtype eq RPS::File::Sale::TYPE_ALBUM );
            $sale->trackName($title) if ( $prodtype eq RPS::File::Sale::TYPE_TRACK );
            $sale->formatType($format);
            $sale->units($units);
            $sale->price($price);
            $sale->countryCode($country);
            $sale->currencyCode($currency);
            $sale->lineNum($linenum);

            ##$args{dumper}($sale); ## for cmd-line testing
            $self->_insertSale( sale => $sale );
        }
        $linenum++;
    }

    return $linenum;
}

#
# Private methods
#

sub _getDates {
    my $self = shift;
    my $date = shift;    # end date of period

    my ( $dateBegin, $dateEnd );
    if ( $date =~ m/^(\d{4})-(\d\d)-\d\d$/ ) {
        my $year  = $1;
        my $month = $2;
        $dateBegin = sprintf( "%04d-%02d-%02d", $year, $month, 1 );
        $dateEnd = sprintf( "%04d-%02d-%02d", $year, $month, Days_in_Month( $year, $month ) );
        return ( $dateBegin, $dateEnd );
    } elsif ( $date =~ m/^(\w{3})-(\w{3})(\d\d)$/ ) {
        my $m1 = $1;
        my $m2 = $2;
        my $yr = $3 + 2000;
        $dateBegin = sprintf( "%04d-%02d-%02d", $yr, Decode_Month($m1), 1 );
        $dateEnd = sprintf( "%04d-%02d-%02d", $yr, Decode_Month($m2), Days_in_Month( $yr, Decode_Month($m2) ) );
        return ( $dateBegin, $dateEnd );
    }

    return undef;
}

###
1;    # Play nicely.
###