package RPS::Import::Rdio::v3;

use strict;

use lib '/app/tools/common/lib';
use Common::Date;

use lib '/app/tools/rps/lib';
use base 'RPS::Import::Importer';

use Data::Dumper;

sub _headerIdentifier { ( upc => 'UPC' ) }

sub _fieldMap {
    {
        dateBegin    => 'B',
        countryCode  => 'R',
        productType  => 'Q',
        formatType   => 'N',
        artistName   => 'G',
        upc          => 'C',
        isrc         => 'D',
        trackName    => 'F',
        units        => 'H',
        currencyCode => 'J',
        price        => 'L',
        mediaType    => 'Q',
    };
}

sub unitPrice {
    my $self = shift;

    # The sales file is already reporting the unit price, so
    # we override unitPrice to prevent it from being recalculated.
    #
    my $unitPrice = $self->_formatPrice( $self->price() );
    return $unitPrice;
}

sub productType {
    my $self = shift;
    my $type = $self->_getByFieldName('productType') || return;

    if ( $type =~ /^trackrelease$/i ) {
        return RPS::File::Sale::TYPE_TRACK;
    }
    $self->fail("Unknown product type '$type'");
}

sub formatType {
    my $self = shift;
    my $format = $self->_getByFieldName('formatType') || return;

    if (   $format =~ /^ondemandstream$/i
        || $format =~ /^noninteractivestream$/i ) {
        return RPS::File::Sale::FORMAT_STREAM;
    } elsif ( $format =~ /^conditionaldownload$/i ) {
        return RPS::File::Sale::FORMAT_TETHERED;
    } elsif ( $format =~ /^permanentdownload$/i ) {
        return RPS::File::Sale::FORMAT_DOWNLOAD;
    }

    $self->fail("Unknown format type '$format'");
}

sub mediaType {
    my $self = shift;
    my $type = $self->_getByFieldName('productType') || return;

    if ( $type =~ /^trackrelease$/i ) {
        return RPS::DB::Item::MediaType::kMediaTypeAudio;
    }
    $self->fail("Unknown media type '$type'");
}

sub _isValidSaleRecord {
    my $self = shift;
    my $type = $self->type();

    if ( !$self->price ) {
        return;    # skip lines with no revenue
    }

    return $self->SUPER::_isValidSaleRecord();
}

###
1;                 # Play nicely.
###