#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2010 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------

package RPS::Import::Redeye::v2;

use strict;

use lib '/app/tools/common/lib';
use Common::Assert;
use Common::UTF8;

use lib '/app/tools/rps/lib';
use base 'RPS::Import::Importer';

sub _fieldMap {
    {
        dateBegin   => 'B',
        dateEnd     => 'C',
        countryCode => 'D',

        labelName   => 'G',
        productType => 'K',
        formatType  => 'J',
        artistName  => 'H',
        upc         => 'E',
        isrc        => 'E',
        trackName   => 'I',
        albumName   => 'I',
        units       => 'L',
        price       => 'O',
        mediaType   => 'K',
    };
}

sub _unverifiedFieldMap {
    { serviceName => 'A', };
}

sub productType {
    my $self = shift;
    my $type = $self->_getByFieldName('productType') || return;

    if ( $type =~ /^(track|ringtone|video)$/ ) {
        return RPS::File::Sale::TYPE_TRACK;
    } elsif ( lc $type eq 'album' ) {
        return RPS::File::Sale::TYPE_ALBUM;
    }
    $self->fail("Unknown product type $type");
}

sub price {
    my $price = abs( shift->SUPER::price() );
    return $price;
}

sub units {
    my $self  = shift;
    my $units = $self->SUPER::units() || return;
    my $price = $self->SUPER::price();

    if ( defined($price) ) {
        return $price < 0 ? abs($units) * -1 : $units;
    } else {
        return $units;
    }

}

sub unitPrice { abs( shift->SUPER::unitPrice ) }

sub upc {
    my $self = shift;
    my $upc  = $self->_getByFieldName('upc');

    if ( $self->productType eq RPS::File::Sale::TYPE_ALBUM ) {
        return $upc;
    } else {
        return undef;
    }
}

sub albumName {
    my $self = shift;
    my $name = $self->_getByFieldName('albumName') || "";

    if ( $self->productType eq RPS::File::Sale::TYPE_ALBUM ) {
        return $name;
    } else {
        return undef;
    }
}

sub isrc {
    my $self = shift;
    my $isrc = $self->_getByFieldName('isrc');

    if ( $self->productType eq RPS::File::Sale::TYPE_TRACK ) {
        return $isrc;
    } else {
        return undef;
    }
}

sub trackName {
    my $self = shift;
    my $name = $self->_getByFieldName('trackName') || "";

    if ( $self->productType eq RPS::File::Sale::TYPE_TRACK ) {
        return $name;
    } else {
        return undef;
    }
}

sub formatType {
    my $self       = shift;
    my $unit_price = $self->unitPrice;
    my $fmt        = $self->_getByFieldName('formatType');     # col J
    my $type       = $self->_getByFieldName('productType');    # col K
    my $service    = $self->_getByFieldName('serviceName');    # col A

    my $format;

    # From the template:
    #
    # if J = Download but L < .1 = DTETH
    # Video = DS
    # if J = Download and K = Ringtone = RING
    # Download = D
    # Stream = DS
    # if column A = emusic = VPD
    # if column A = Amie street = VPD

    if ( $service =~ m/^emusic$/i || $service =~ /^amie street$/i ) {
        $format = RPS::File::Sale::FORMAT_VPD;
    } elsif ( $fmt =~ /^download$/i ) {
        if ( $unit_price != 0 && $unit_price < .1 ) {
            $format = RPS::File::Sale::FORMAT_TETHERED;
        } elsif ( $type =~ /^ringtone$/i ) {
            $format = RPS::File::Sale::FORMAT_RINGTONE;
        } else {
            $format = RPS::File::Sale::FORMAT_DOWNLOAD;
        }
    } elsif ( $fmt =~ /^(stream|video)$/i ) {
        $format = RPS::File::Sale::FORMAT_STREAM;
    }
    return $format;
}

sub mediaType {
    my $self = shift;
    my $mtype = $self->_getByFieldName('mediaType') || return;

    if ( $mtype =~ /^(album|track|ringtone)$/ ) {
        return RPS::DB::Item::MediaType::kMediaTypeAudio;
    } elsif ( $mtype =~ /^video$/ ) {
        return RPS::DB::Item::MediaType::kMediaTypeVideo;
    }

    $self->fail("Could not determine media type from from '$mtype'");
}

sub currencyCode { 'USD' }

sub _headerIdentifier { ( dateEnd => 'End Date' ) }

sub saleDates {
    my $self = shift;

    my $date = $self->_getByFieldName('dateEnd') || return;

    my ( $year, $month, $day );

    if ( $date =~ m/(\d{4})\D(\d+)\D(\d+)/ ) {
        $year  = $1;
        $month = $2;
        $day   = $3;
    } else {
        $self->fail("Could not parse date from '$date'");
    }

    return undef unless ( $year ne "" && $month ne "" );

    return ( sprintf( "%04d-%02d-01", $year, $month ), sprintf( "%04d-%02d-%02d", $year, $month, $day ) );

}

sub _formatPrice {
    my $self = shift;
    my $price = shift || return;

    #$price =~ s/,/./;
    return $price;
}

sub _isValidSaleRecord {
    my $self = shift;

    return ( defined( $self->units ) && ( $self->trackName || $self->albumName || $self->isrc ) );
}

###
1;    # Play nicely.
###