package RPS::Import::Redeye::v9;

use strict;

use lib '/app/tools/rps/lib';
use RPS::File::Sale;
use RPS::Import::ServiceMap;
use RPS::Import::Importer;

use base 'RPS::Import::Importer';

sub _fieldMap {
    {
        countryCode  => 'N',
        dateBegin    => 'H',
        productType  => 'A',
        artistName   => 'C',
        upc          => 'B',
        albumName    => 'D',
        sales        => 'E',
        totalRevenue => 'L',
    };
}

sub _headerIdentifier { ( upc => 'UPC' ) }

sub physical { 1 }

sub channel      { RPS::File::Sale::CHANNEL_RETAIL; }
sub priceLevel   { RPS::File::Sale::PLEVEL_UNKNOWN; }
sub currencyCode { 'USD' }

sub saleDates {
    my $self      = shift;
    my $startDate = $self->_getByFieldName('dateBegin');

    return $self->_getDates( date_begin => $startDate );
}

sub productType {
    my $self = shift;
    my $type = $self->_getByFieldName('productType') || return;

    if ( $type =~ /^CD-/i ) {
        return RPS::File::Sale::TYPE_CD;
    } elsif ( $type =~ /^LP-/i || $type =~ /^BOX-/i ) {
        return RPS::File::Sale::TYPE_LP;
    } elsif ( $type =~ /^SI-/i ) {
        return RPS::File::Sale::TYPE_LP5;
    } elsif ( $type =~ /^DVD-/i ) {
        return RPS::File::Sale::TYPE_DVD;
    } else {
        $self->fail("Could not get product type from '$type'");
    }
}

sub sales {
    my $self  = shift;
    my $sales = $self->_getByFieldName('sales');

    return ( $sales > 0 ) ? $sales : 0;
}

sub salesRevenue {
    my $self         = shift;
    my $salesRevenue = $self->_getByFieldName('totalRevenue');

    return ( $salesRevenue > 0 ) ? $salesRevenue : 0;
}

sub returns {
    my $self         = shift;
    my $sales        = $self->_getByFieldName('sales');
    my $salesRevenue = $self->_getByFieldName('totalRevenue');
    return ( $sales < 0 && $salesRevenue < 0 ) ? abs($sales) : 0;
}

sub returnsRevenue {
    my $self         = shift;
    my $sales        = $self->_getByFieldName('sales');
    my $salesRevenue = $self->_getByFieldName('totalRevenue');

    return ( $sales < 0 && $salesRevenue < 0 ) ? abs($salesRevenue) : 0;
}

sub _isValidSaleRecord {
    my $self = shift;

    # The line is valid if it has sales or returns, or has revenue without units,
    # and has an album title
    #
    return ( ( ( $self->sales != 0 ) || ( $self->sales == 0 && $self->totalRevenue != 0 ) ) && $self->albumName );
}

###
1;    # Play nicely.
###