package RPS::Import::SPV::v2;

use strict;
use warnings;

use lib '/app/tools/rps/lib';

use RPS::Import::ServiceMap;
use Date::Calc qw(Days_in_Month);

use parent qw/RPS::Import::MapFaceBase RPS::Import::SPV::v1/;

sub physical { 0 }

sub _fieldMapExtended {
    {
        digital => {
            option1 => {
                serviceID       => 'F',
                countryCode     => 'E',
                dateBegin       => 'D',
                productType     => 'A',
                clientProductID => 'A',
                artistName      => 'B',
                albumName       => 'C',
                isrc            => 'A',
                trackName       => 'C',
                units           => 'G',
                price           => 'J',
            }
        }
    }
}

sub _unverifiedFieldMapExtended { {} }

sub _headerIdentifierExtended {
    {
        digital => {
            option1 => { isrc => 'ISRC' }
        }
    }
}

sub currencyCode { 'EUR' }
sub mediaType    { RPS::DB::Item::MediaType::kMediaTypeAudio }

sub saleDates {
    my $self = shift;

    my $date = $self->_getByFieldName('dateBegin') || '';

    if ( my($m, $y) = $date =~ /^(\d{2})\/(\d{4})$/i ) {
        return $self->_getDates(
            date_begin => sprintf( "%04d-%02d-%02d", $y, $m, 1),
            date_end   => sprintf( "%04d-%02d-%02d", $y, $m, Days_in_Month($y, $m))
        )
    }

    $self->fail( "Unable to determine date from $date" );
}

sub serviceID {
    my $self = shift;

    my $service = lc( $self->_getByFieldName('serviceID') || '' );
    my $serviceID = $self->getServiceID($service) || $RPS::Import::ServiceMap::SERVICE_ALIASES{$service};
    return $serviceID if $serviceID;

    return $self->handleError( "Unknown service: $service", RPS::DB::Item::SaleImportError::kErrorService );
}

sub productType {
    my $self = shift;

    my $type = $self->_getByFieldName('productType') || '';

    return RPS::File::Sale::TYPE_ALBUM if length($type) < 12;
    return RPS::File::Sale::TYPE_TRACK;
}

sub formatType {
    my $self = shift;

    my $type = $self->filename || "";
    my $service = $self->_getByFieldName('serviceID') || "";

    return RPS::File::Sale::FORMAT_EPHEMERAL if $service =~ /soundexchange/i;
    return RPS::File::Sale::FORMAT_STREAM if $type =~ /-streams\./i;

    $self->handleError( "Unknown format type: $type", RPS::DB::Item::SaleImportError::kErrorFormatType );
}


sub clientProductID {
    my $self = shift;

    my $clientProductID = $self->_getByFieldName('clientProductID') || '';

    if ( $self->productType eq RPS::File::Sale::TYPE_ALBUM ) {
        return $clientProductID;
    }

    return;
}

sub albumName {
    my $self = shift;

    my $albumName = $self->_getByFieldName('albumName')   || '';

    if ( $self->productType eq RPS::File::Sale::TYPE_ALBUM ) {
        return $albumName;
    }

    return;
}

sub trackName {
    my $self = shift;

    my $trackName = $self->_getByFieldName('trackName')   || '';

    if ( $self->productType eq RPS::File::Sale::TYPE_TRACK ) {
        return $trackName;
    }

    return;
}

sub isrc {
    my $self = shift;

    my $isrc = $self->_getByFieldName('isrc')   || '';

    if ( $self->productType eq RPS::File::Sale::TYPE_TRACK ) {
        return $isrc;
    }

    return;
}

sub price {
    my $self = shift;

    my $price = $self->_getByFieldName('price') || 0;
    $price =~ s/\.//g;
    $price =~ s/,/\./g;

    return $price;
}

sub unitPrice { abs shift->SUPER::unitPrice }

sub units {
    my $self = shift;

    my $units = $self->_getByFieldName('units') || 0;
    my $price = $self->price;

    if ( $price > 0 ) {
        $units = $units ? abs($units) : 1;
    } elsif ( $price < 0 ) {
       $units = $units ? -1 * abs($units) : -1;
    }

    return $units;
}

sub _mapFaceServiceID   { 'serviceID' }
sub _mapFaceCountryCode { 'countryCode' }
sub _mapFaceFormatType  { 'formatType' }
sub _mapFaceProductType { }
sub _mapFaceMediaType   { }

1;