#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2010 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------

package RPS::Import::SelectDigitalIdol::v1;

use strict;
use warnings;

use Encode;

use Date::Calc qw(Days_in_Month);

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;

use base 'RPS::Import::Importer';

sub _fieldMap {
    my $self = shift;

    my %field_map = (
        1 => {
            labelName   => 'A',
            serviceID   => 'E',
            dateBegin   => 'B',
            dateEnd     => 'B',
            productType => 'M',
            formatType  => 'L',
            artistName  => 'G',
            upc         => 'I',
            albumName   => 'H',
            isrc        => 'K',
            trackName   => 'J',
            units       => 'P',
            price       => 'T',
            countryCode => 'C',
        },
        2 => {
            labelName   => 'A',
            dateBegin   => 'B',
            serviceID   => 'E',
            countryCode => 'C',
            productType => 'M',
            formatType  => 'L',
            artistName  => 'G',
            upc         => 'I',
            albumName   => 'H',
            isrc        => 'K',
            trackName   => 'J',
            units       => 'P',
            price       => 'S'
        },
        3 => {
            labelName   => 'A',
            dateBegin   => 'B',
            serviceID   => 'E',
            countryCode => 'C',
            productType => 'N',
            formatType  => 'M',
            artistName  => 'G',
            upc         => 'I',
            albumName   => 'H',
            isrc        => 'K',
            trackName   => 'J',
            units       => 'Q',
            price       => 'T'
        },
        4 => {
            labelName   => 'A',
            serviceID   => 'E',
            countryCode => 'C',
            dateBegin   => 'B',
            dateEnd     => 'B',
            productType => 'N',
            formatType  => 'M',
            artistName  => 'G',
            upc         => 'I',
            albumName   => 'H',
            isrc        => 'K',
            trackName   => 'J',
            units       => 'Q',
            price       => 'U',
            mediaType   => 'N',
        },
        5 => {
            labelName   => 'B',
            serviceID   => 'F',
            countryCode => 'D',
            dateBegin   => 'C',
            dateEnd     => 'C',
            productType => 'N',
            formatType  => 'M',
            artistName  => 'H',
            upc         => 'J',
            albumName   => 'I',
            isrc        => 'L',
            trackName   => 'K',
            units       => 'Q',
            price       => 'U',
            mediaType   => 'N',
        },
        6 => {
            labelName   => 'A',
            serviceID   => 'E',
            countryCode => 'C',
            dateBegin   => 'B',
            dateEnd     => 'B',
            productType => 'N',
            formatType  => 'M',
            artistName  => 'G',
            upc         => 'I',
            albumName   => 'H',
            isrc        => 'K',
            trackName   => 'J',
            units       => 'Q',
            price       => 'T',
            mediaType   => 'N',
        }
    );

    return $field_map{ $self->_version };
}

sub _unverifiedFieldMap {
    my $self = shift;

    my %field_map = (
        6 => {
            _video => 'L',
        },
    );

    return $field_map{ $self->_version };
}

sub _headerIdentifier {
    my $self = shift;

    my $colName = $self->_version == 6 ? 'Transaction Date' : 'Period';
    return dateBegin => $colName;
}

sub _preProcess {
    my $self = shift;
    my %args = @_;

    $self->SUPER::_preProcess(%args);

    my $fileName = $args{file}->OrigFileName();
    if ( $fileName =~ /_(\w{3}).*?\.\w+$/i ) {
        my $cc = uc $1;
        $cc =~ s/CAN/CAD/;
        $self->{_currencyCode} = $cc;
    } else {
        $self->fail("Couldn't get currency code from filename");
    }
}

sub upc {
    my  $self = shift;

    my $upc = $self->_getByFieldName("upc") || "";
    $upc =~ s/'//g;

    return $upc;
}

sub currencyCode { shift->{_currencyCode} }

sub saleDates {
    my $self = shift;

    my $dt = $self->_getDateBegin();

    my $dateBegin;
    my $dateEnd;

    if ( $dt =~ /^(\d{4})-(\d{2})$/ )    # YYYY-MM
    {
        my $year  = $1;
        my $month = $2;
        $dateBegin = sprintf( "%04d-%02d-%02d", $year, $month, 1 );
        $dateEnd = sprintf( "%04d-%02d-%02d", $year, $month, Days_in_Month( $year, $month ) );
    }

    return ( $dateBegin, $dateEnd );
}

sub serviceID {
    my $self      = shift;
    my $service   = $self->_getByFieldName('serviceID');

    return Client::Service::DSP_7DIGITAL if $service =~ /^snowite.+mobile$/i;

    my $serviceID = $self->getServiceID( lc($service) ) || $RPS::Import::ServiceMap::SERVICE_ALIASES{ lc $service };
    return $serviceID if ($serviceID);

    $self->fail("Unknown service '$service'");
}


my $hCountriesInFrench = Common::Country->GetListOfCountriesByCountryCode('fr');

sub countryCode {
    my $self = shift;
    my $name = $self->_getByFieldName('countryCode') || '';

    if ( $self->_version == 6 ) {
        # a trick to lowercase utf8 text
        my $frenchName = encode_utf8( lc decode_utf8( encode_utf8($name) ) );
        if ( exists $hCountriesInFrench->{$frenchName} ) {
             # translate name from french to english
             $name = $hCountriesInFrench->{$frenchName};
        }
    }

    $name =~ s/&/ and /g;
    $name =~ s/St\./Saint /gi;
    $name =~ s/\s+/ /g;

    return 'FR' if $name =~ /^\?$/i;        # see comments in RSD-7258
    return 'CI' if $name =~ /C.+voire/i;    # Côte d’Ivoire
    return 'RE' if $name =~ /R.+union/i;    # Réunion
    return 'VG' if $name =~ /^British Virgin Islands/i;
    return 'CG' if $name =~ /Congo ?\- ?Brazzaville/i;
    return 'CD' if $name =~ /Congo ?\- ?Kinshasa/i;
    return 'MO' if $name =~ /Macao/i;
    return 'HK' if $name =~ /Hong Kong/i;
    return 'MK' if $name =~ /macedonia/i;
    return 'LA' if $name =~ /^Laos/i;
    return 'MO' if $name =~ /^Macau/i;
    return 'FM' if $name =~ /^Micronesia/i;
    return 'MM' if $name =~ /^Myanmar/i;
    return 'VI' if $name =~ /^U\.S\. Virgin Islands.*/i;
    return 'SV' if $name =~ /salvador/i;
    return 'VC' if $name =~ /^Saint Vincent and Grenadines$/i;
    return 'PS' if $name =~ /^Palestinian Territories$/i;
    return 'GF' if $name =~ /^Guyane.*/i;
    return 'AS' if $name =~ /^Samoa amricaines$/i;
    return 'PS' if $name =~ /^Territoires palestiniens$/i;
    return 'WF' if $name =~ /^Wallis-et-Futuna$/i;
    return 'NC' if $name =~ /^Nouvelle\-Cal.*/i;
    return 'PW' if $name =~ /^Palaos.*$/i;
    return 'AS' if $name =~ /Samoa .*ricaines/i;
    return 'VI' if $name =~ /.*les Vierges des .*tats-Unis/i;

    my $o = Common::Country->Get($name);
    return $o->alpha2 if $o;

    $self->fail("Unrecognized country '$name'");
}

sub productType {
    my $self = shift;
    my $type = $self->_getByFieldName('productType') || return;

    if ( $type =~ /^(?:album|product)$/i ) {
        return RPS::File::Sale::TYPE_ALBUM;
    } elsif ( $type =~ /^(?:free|motion audio|motion video|premium|radio|track|trial|upgrade|video|bundle|freemium|no)$/i ) {
        return RPS::File::Sale::TYPE_TRACK;
    } else {
        $self->fail("Could not parse product type from '$type'");
    }
}

sub mediaType {
    my $self = shift;
    my $type = $self->_getByFieldName('productType') || return;

    if ( $type =~ /video/i ) {
        return RPS::DB::Item::MediaType::kMediaTypeVideo;
    } else {
        return RPS::DB::Item::MediaType::kMediaTypeAudio;
    }
}

sub trackName {
    my $self = shift;

    my $name    = $self->_getByFieldName('trackName') || '';
    my $service = $self->_getByFieldName('serviceID') || '';

    if ( $self->_version == 6 ) {
        return $service =~ /^YouTube$/i
            ? $self->_getByFieldName('_video')
            : $self->_getByFieldName('trackName');
    }

    return $name if ( $self->productType eq RPS::File::Sale::TYPE_TRACK );
}

sub formatType {
    my $self = shift;
    my $fmt  = $self->_getByFieldName('formatType') || '';

    if ( $fmt =~ /^download$/i ) {
        return RPS::File::Sale::FORMAT_DOWNLOAD;
    } elsif ( $fmt =~ /^(?:stream|other|content_production|copy_scan|non_interactive_stream|on_demand_stream)$/i ) {
        return RPS::File::Sale::FORMAT_STREAM;
    }

    $self->fail("Could not parse format type from '$fmt'");
}

sub units {
    my $self = shift;

    my $units = $self->_getByFieldName('units') || 0;
    my $price = $self->price();

    if ( $price > 0 ) {
        $units = $units ? abs( $units ) : 1;
    } elsif ( $price < 0 ) {
        $units = $units ? -1 * abs( $units ) : -1;
    }

    return $units;
}

sub unitPrice {
    return abs( shift->SUPER::unitPrice() );
}

sub free {
    my $self = shift;

    my $type  = $self->_getByFieldName('productType') || '';
    my $price = $self->price();

    return 1 if $type =~ /^(free|trial|freemium)$/i && $price == 0;
}

sub price {
    my $self = shift;

    my $price = $self->_getByFieldName('price') || 0;
    $price =~ s/,/./g;

    return sprintf("%.8f", $price);
}

sub _isValidSaleRecord {
    my $self = shift;

    return $self->_getByFieldName('price') || $self->_getByFieldName('units') ? 1 : 0;
}


1;