package RPS::Import::SimplyAudioBooks;

use strict;

use Date::Calc qw(Decode_Date_US);

use lib '/app/tools/data_classes/lib';

use lib '/app/tools/rps/lib';
use RPS::File::Sale;
use base 'RPS::Import::Importer';

# summary record
use constant SHEET_SUMMARY => 0;
use constant ROW_DATEEND   => 12;
use constant FIELD_DATEEND => 0;

# detail records
use constant SHEET_DETAIL   => 1;
use constant ROW_DATA_START => 2;
use constant FIELD_ISBN     => 0;
use constant FIELD_ALBUM    => 1;
use constant FIELD_QTY1     => 5;
use constant FIELD_PRICE1   => 7;
use constant FIELD_QTY2     => 8;
use constant FIELD_PRICE2   => 10;

#
# Private methods
#

sub _importLines {
    my $self = shift;
    my %args = @_;
    return undef unless ( $args{sheets}->[SHEET_SUMMARY] && $args{sheets}->[SHEET_DETAIL] );

    my ( $dateBegin, $dateEnd ) = $self->_getDates( $args{sheets}->[SHEET_SUMMARY] );
    unless ( $dateBegin && $dateEnd ) {
        $self->errstr("couldn't get dates");
        return undef;
    }

    my $lines   = $args{sheets}->[SHEET_DETAIL];
    my $lineNum = ROW_DATA_START + 1;
    for ( my $i = ROW_DATA_START ; $i < scalar @$lines ; $i++ ) {
        my $line = $lines->[$i];

        my $album = $line->[FIELD_ALBUM];

        my $units1 = $line->[FIELD_QTY1];
        my $price1 = $units1 > 0 ? $line->[FIELD_PRICE1] / $units1 : 0;

        my $units2 = $line->[FIELD_QTY2];
        my $price2 = $units2 > 0 ? $line->[FIELD_PRICE2] / $units2 : 0;

        if ( $units1 && $price1 && $album ) {
            my $sale = RPS::Import::SaleRec->new();

            $sale->productType(RPS::File::Sale::TYPE_ALBUM);
            $sale->formatType(RPS::File::Sale::FORMAT_DOWNLOAD);
            $sale->serviceProductID( $line->[FIELD_ISBN] );
            $sale->dateBegin($dateBegin);
            $sale->dateEnd($dateEnd);
            $sale->albumName($album);
            $sale->units($units1);
            $sale->price($price1);
            $sale->lineNum($lineNum);
            $sale->countryCode('US');

            $self->_insertSale( sale => $sale );
        }

        if ( $units2 && $price2 && $album ) {
            my $sale = RPS::Import::SaleRec->new();

            $sale->productType(RPS::File::Sale::TYPE_ALBUM);
            $sale->formatType(RPS::File::Sale::FORMAT_DOWNLOAD);
            $sale->serviceProductID( $line->[FIELD_ISBN] );
            $sale->dateBegin($dateBegin);
            $sale->dateEnd($dateEnd);
            $sale->albumName($album);
            $sale->units($units2);
            $sale->price($price2);
            $sale->lineNum($lineNum);
            $sale->countryCode('US');

            $self->_insertSale( sale => $sale );
        }
        $lineNum++;
    }

    return $lineNum;
}

sub _getDates {
    my $self  = shift;
    my $lines = shift;

    my $dateField = $lines->[ROW_DATEEND]->[FIELD_DATEEND];
    $dateField =~ s/^.*to //i;

    my ( $year, $month, $day ) = Decode_Date_US($dateField);

    return undef unless ( $year && $month && $day );

    return ( sprintf( "%04d-%02d-01", $year, $month ), sprintf( "%04d-%02d-%02d", $year, $month, $day ) );
}

###
1;    # Play nicely.
###