#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2009 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------

package RPS::Import::Slacker;

use strict;

use Date::Calc qw(Days_in_Month Add_Delta_Days Decode_Month);

use lib '/app/tools/rps/lib';
use RPS::DB::Item::Client;

use lib '/app/tools/common/lib';
use Common::Consts;
use Common::Assert;
use Common::Log;

use lib '/app/tools/data_classes/lib';

use lib '/app/tools/rps/lib';
use RPS::File::Sale;
use RPS::DB::Item::MediaType;

use lib '/app/tools/rps/lib';
use RPS::Import::Importer;
use base 'RPS::Import::Importer';

my %fieldMap = (
    1 => {
        artist      => 0,    # A
        album_title => 1,    # B
        track_title => 2,    # C
        label       => 3,    # D
        upc         => 4,    # E
        isrc        => 5,    # F
        format      => 6,    # G
        units       => 7,    # H
        net_price   => 9,    # J
    },
);

#public methods

sub _importLines {
    my $self        = shift;
    my %args        = @_;
    my $fileObj     = $args{file};
    my $version     = $args{file}->VersionNum();
    my $fileName    = $args{file}->OrigFileName();
    my $serviceID   = $args{file}->ServiceID;
    my $sheet_count = 0;

    assert( defined $args{sheets} );
    assert( defined $version );

    my $offsets     = $fieldMap{$version};
    my $sheet_names = $args{sheet_names};
    my $sheets      = $args{sheets};
    my $linenum     = 1;

    my $country      = 'US';
    my $currencyCode = 'USD';
    my $productType  = RPS::File::Sale::TYPE_TRACK;
    my $mediaType    = RPS::DB::Item::MediaType::kMediaTypeAudio;

    for ( my $sheetIndex = 0 ; $sheetIndex < scalar @{ $args{sheets} } ; $sheetIndex++ ) {
        my $sheet = $sheets->[$sheetIndex];

        my $foundHeader = 0;
        for ( my $lineIndex = 0 ; $lineIndex < scalar @$sheet ; $lineIndex++ ) {
            $linenum = $lineIndex + 1;
            my $line = $sheet->[$lineIndex];

            if ( !$foundHeader ) {
                if ( 'artistName' eq $line->[ $offsets->{artist} ] ) {
                    $foundHeader = 1;
                }
                next;
            }

            my $format;

            my $trackTitle = $line->[ $offsets->{track_title} ];
            my $albumTitle = $line->[ $offsets->{album_title} ];
            my $upc        = $line->[ $offsets->{upc} ];
            my $isrc       = $line->[ $offsets->{isrc} ];
            my $artist     = $line->[ $offsets->{artist} ];
            my $units      = $line->[ $offsets->{units} ];
            my $netPrice   = $line->[ $offsets->{net_price} ];
            my $label      = $line->[ $offsets->{label} ];

            # Probably wise to allow for blank lines...
            #
            if ( $units && $artist && ( $albumTitle || $trackTitle ) ) {
                my $_format = $line->[ $offsets->{format} ];

                if ( $_format =~ /^radio$/i ) {
                    $format = RPS::File::Sale::FORMAT_STREAM;
                } elsif ( $_format =~ /^(savedtrack|ondemand|artistFranchise)$/i ) {
                    $format = RPS::File::Sale::FORMAT_TETHERED;
                } else {
                    $self->errstr("Unrecognized format (line: $linenum): $_format");
                    return undef;
                }

                my ( $dateBegin, $dateEnd ) = $self->_getDates( date_begin => $fileName );

                my $unitPrice = $netPrice / $units;

                my $sale = RPS::Import::SaleRec->new();

                $sale->mediaType($mediaType);
                $sale->productType($productType);
                $sale->formatType($format);
                $sale->dateBegin($dateBegin);
                $sale->dateEnd($dateEnd);
                $sale->labelName($label);
                $sale->trackName($trackTitle);
                $sale->albumName($albumTitle);
                $sale->artistName($artist);
                $sale->upc($upc);
                $sale->isrc($isrc);
                $sale->units($units);
                $sale->price($unitPrice);
                $sale->countryCode($country);
                $sale->currencyCode($currencyCode);
                $sale->lineNum($linenum);

                $self->_insertSale( sale => $sale );
            }
        }
    }

    return $linenum;
}

###
1;    # Play nicely.
###