#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (c) 2013-2014 RoyaltyShare, Inc. All Rights Reserved
#---------------------------------------------------------------

package RPS::Import::Sony::v21;

use strict;

use Date::Calc qw(Days_in_Month);

use lib '/app/tools/common/lib';
use Common::Assert;
use Data::Dumper;

use lib '/app/tools/rps/lib';
use base 'RPS::Import::Importer';

sub _fieldMap {
    {
        dateBegin      => 'L',
        dateEnd        => 'L',
        artistName     => 'D',
        upc            => 'C',
        albumName      => 'E',
        wholesalePrice => 'G',
        totalRevenue   => 'U',
    };
}

sub _unverifiedFieldMap {
    { netQuantity => 'P', };
}

sub physical { 1 }

sub _headerIdentifier { ( 'upc' => 'Catalog' ) }

sub channel { RPS::File::Sale::CHANNEL_RETAIL }

sub priceLevel { RPS::File::Sale::PLEVEL_UNKNOWN }

sub productType { RPS::File::Sale::TYPE_CD }

sub _preProcess {
    my $self     = shift;
    my %args     = @_;
    my $fileName = $args{file}->OrigFileName();

    my $currencyCode;
    my $countryCode;

    if ( $fileName =~ /AUS/i ) {
        $countryCode  = "AU";
        $currencyCode = "AUD";
    } else {
        $self->fail("Unable to determine country/currency code from filename");
    }

    $self->{_currencyCode} = $currencyCode;
    $self->{_countryCode}  = $countryCode;
}

sub sales {
    my $self    = shift;
    my $units   = $self->_getByFieldName('netQuantity');
    my $revenue = $self->_getByFieldName('totalRevenue');

    if ( $revenue > 0 ) {
        return abs($units);
    } elsif ( $revenue <= 0 ) {
        return 0;
    }
}

sub salesRevenue {
    my $self    = shift;
    my $units   = $self->_getByFieldName('netQuantity');
    my $revenue = $self->_getByFieldName('totalRevenue');

    if ( $revenue > 0 ) {
        $units = abs($units);
    }
    return ( $units > 0 && $revenue > 0 ) ? $revenue : 0;
}

sub returns {
    my $self    = shift;
    my $units   = $self->_getByFieldName('netQuantity');
    my $revenue = $self->_getByFieldName('totalRevenue');

    if ( $revenue < 0 ) {
        return abs($units);
    }
    return 0;
}

sub returnsRevenue {
    my $self    = shift;
    my $revenue = $self->_getByFieldName('totalRevenue');

    return ( $revenue < 0 ) ? abs($revenue) : 0;
}

sub countryCode {
    my $self = shift;
    return $self->{_countryCode};
}

sub currencyCode {
    my $self = shift;
    return $self->{_currencyCode};
}

sub saleDates {
    my $self      = shift;
    my $startDate = $self->_getByFieldName('dateBegin');

    my $dateBegin;
    my $dateEnd;
    if ( $startDate =~ /(\d{4})(\d{2})/ ) {
        $dateBegin = sprintf( "%04d-%02d-%02d", $1, $2, 1 );
        $dateEnd = sprintf( "%04d-%02d-%02d", $1, $2, Days_in_Month( $1, $2 ) );
    }
    return ( $dateBegin, $dateEnd );
}

sub _isValidSaleRecord {
    my $self = shift;

    # The line is valid if it has sales or returns, and has a album/track title
    #
    return ( ( $self->sales() || $self->returns() ) && $self->albumName() );
}

###
1;    # Play nicely.
###