#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (c) 2013-2014 RoyaltyShare, Inc. All Rights Reserved
#---------------------------------------------------------------

package RPS::Import::Sony::v26;

use strict;

use Date::Calc qw(Days_in_Month);

use lib '/app/tools/common/lib';
use Common::Assert;
use Data::Dumper;

use lib '/app/tools/rps/lib';
use base 'RPS::Import::Importer';

sub _fieldMap {
    {
        labelName      => 'B',
        dateBegin      => 'N',
        configuration  => 'E',
        artistName     => 'F',
        upc            => 'C',
        albumName      => 'G',
        wholesalePrice => 'I',
        sales          => 'P',
        salesRevenue   => 'S',
        returns        => 'Q',
        returnsRevenue => 'T',
        units          => 'R',
        totalRevenue   => 'W',
    };
}

sub _unverifiedFieldMap {
    { distFee => 'V', };
}

sub physical { 1 }

sub _headerIdentifier { ( 'upc' => 'Catalog' ) }

sub countryCode { 'AUS' }
sub channel     { RPS::File::Sale::CHANNEL_RETAIL }
sub priceLevel  { RPS::File::Sale::PLEVEL_UNKNOWN }

sub _preProcess {
    my $self     = shift;
    my %args     = @_;
    my $fileName = $args{file}->OrigFileName();

    my $currencyCode;

    if ( $fileName =~ /AUS/i ) {
        $currencyCode = "AUD";
    } else {
        $self->fail("Unable to determine country/currency code from filename");
    }

    $self->{_currencyCode} = $currencyCode;
}

sub productType {
    my $self   = shift;
    my $config = $self->_getByFieldName('configuration');

    if ( $config =~ /^cd album$/i ) {
        return RPS::File::Sale::TYPE_CD;
    } elsif ( $config =~ /^cd\/dvd combo$/i ) {
        return RPS::File::Sale::TYPE_DVD_CD_SET;
    }

    $self->fail("Unable to determine productType from configuration($config)");
}

sub sales {
    my $self    = shift;
    my $units   = $self->_getByFieldName('units');
    my $revenue = $self->_getByFieldName('totalRevenue');

    if ( $revenue > 0 ) {
        return abs($units);
    } elsif ( $revenue <= 0 ) {
        return 0;
    }
}

sub salesRevenue {
    my $self    = shift;
    my $units   = $self->_getByFieldName('units');
    my $revenue = $self->_getByFieldName('totalRevenue');

    if ( $revenue > 0 ) {
        $units = abs($units);
    }
    return ( $units > 0 && $revenue > 0 ) ? $revenue : 0;
}

sub returns {
    my $self    = shift;
    my $units   = $self->_getByFieldName('units');
    my $revenue = $self->_getByFieldName('totalRevenue');

    if ( $revenue < 0 ) {
        return abs($units);
    }
    return 0;
}

sub returnsRevenue {
    my $self    = shift;
    my $revenue = $self->_getByFieldName('totalRevenue');

    return ( $revenue < 0 ) ? abs($revenue) : 0;
}

sub currencyCode {
    my $self = shift;
    return $self->{_currencyCode};
}

sub saleDates {
    my $self      = shift;
    my $startDate = $self->_getByFieldName('dateBegin');

    my $dateBegin;
    my $dateEnd;
    if ( $startDate =~ /(\d{4})(\d{2})/ ) {
        $dateBegin = sprintf( "%04d-%02d-%02d", $1, $2, 1 );
        $dateEnd = sprintf( "%04d-%02d-%02d", $1, $2, Days_in_Month( $1, $2 ) );
    }
    return ( $dateBegin, $dateEnd );
}

sub configuration {
    my $self   = shift;
    my $config = $self->_getByFieldName('configuration');

    if ( $config =~ /^cd album$/i ) {
        return "CD";
    } elsif ( $config =~ /^cd\/dvd combo$/i ) {
        return "DVDCD";
    }

    $self->fail("Unable to determine configuration from format($config)");
}

sub _isValidSaleRecord {
    my $self           = shift;
    my $sales          = $self->sales();
    my $returns        = $self->returns();
    my $salesRevenue   = $self->salesRevenue();
    my $returnsRevenue = $self->returnsRevenue();

    if (   ( $sales == 0 )
        && ( $returns == 0 )
        && ( $salesRevenue != 0 || $returnsRevenue != 0 ) ) {
        $self->fail("Zero units with non-zero revenue");
    }

    return ( ( $self->sales() || $self->returns() ) && $self->albumName() );
}

###
1;    # Play nicely.
###