#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (c) 2013-2014 RoyaltyShare, Inc. All Rights Reserved
#---------------------------------------------------------------

package RPS::Import::Sony::v29;

use strict;

use Date::Calc qw(Days_in_Month);

use lib '/app/tools/common/lib';
use Common::Assert;
use Data::Dumper;

use lib '/app/tools/rps/lib';
use base 'RPS::Import::Importer';


## Note that the columns in the field map are actually one letter lower than the actual columns in the spreadsheet.
sub _fieldMap {
    my $self = shift;
    my $version = $self->_version;    
    my %field_map = (
        29 =>{
            labelName      => 'B',
            dateBegin      => 'M',
            configuration  => 'E',
            artistName     => 'F',
            upc            => 'C',
            albumName      => 'G',
            wholesalePrice => 'H',
            sales          => 'P',
            salesRevenue   => 'T',
            returns        => 'Q',
            returnsRevenue => 'R',
            units          => 'S',
            totalRevenue   => 'X',
        },
        32 =>{
            labelName      => 'B',
            dateBegin      => 'D',
            configuration  => 'G',
            artistName     => 'E',
            upc            => 'C',
            albumName      => 'F',
            wholesalePrice => 'H',
            sales          => 'O',
            returns        => 'P',
            units          => 'Q',
            totalRevenue   => 'T',
        },     
    );
    return $field_map{$version};
}

sub _unverifiedFieldMap {
    my $self = shift;
    my $version = $self->_version;
    my %field_map = (
        29 => {
            distFee        => 'W',
        },     
        32 => {
            distFee        => 'T',
        },             
    );
    return $field_map{$version};
}

sub physical { 1 }

sub _headerIdentifier { ( 'upc' => 'Catalog' ) }

sub countryCode  { 'AU' }
sub currencyCode { 'AUD' }
sub channel      { RPS::File::Sale::CHANNEL_RETAIL }
sub priceLevel   { RPS::File::Sale::PLEVEL_UNKNOWN }

sub productType {
    my $self = shift;
    my $config = $self->_getByFieldName( 'configuration' );

    if( $config =~ /^cd album$/i || $config =~ /^album$/i ) {
        return RPS::File::Sale::TYPE_CD;
    }
    elsif( $config =~ /^cd\/dvd combo$/i ) {
        return RPS::File::Sale::TYPE_DVD_CD_SET;
    }
    elsif( $config =~ /^vinyl album$/i ) {
        return RPS::File::Sale::TYPE_LP;
    }    

    $self->fail("Unable to determine productType from configuration($config)");
}

sub sales {
    my $self = shift;
    my $units = $self->_getByFieldName( 'units' );
    my $revenue = $self->_getByFieldName( 'totalRevenue' );

    if( $revenue > 0 ) {
        return abs($units);
    } elsif( $revenue <= 0 ) {
        return 0;
    }
}

sub salesRevenue {
    my $self = shift;
    my $units = $self->_getByFieldName( 'units' );
    my $revenue = $self->_getByFieldName( 'totalRevenue' );

    if( $revenue > 0 ) {
        $units = abs($units);
    }
    return ( $units > 0 && $revenue > 0 ) ? $revenue : 0;
}

sub returns {
    my $self = shift;
    my $units = $self->_getByFieldName( 'units' );
    my $revenue = $self->_getByFieldName( 'totalRevenue' );

    if( $revenue < 0 ) {
        return abs($units);
    }
    return 0;
}

sub returnsRevenue {
    my $self = shift;
    my $revenue = $self->_getByFieldName( 'totalRevenue' );

    return ( $revenue < 0 ) ? abs($revenue) : 0;
}

sub currencyCode  {
    my $self = shift;
    return $self->{_currencyCode};
}

sub saleDates {
    my $self = shift;
    my $startDate = $self->_getByFieldName('dateBegin');

    my $dateBegin;
    my $dateEnd;
    if( $startDate =~ /(\d{4})(\d{2})/ ) {
        $dateBegin = sprintf("%04d-%02d-%02d", $1, $2, 1 );
        $dateEnd   = sprintf("%04d-%02d-%02d", $1, $2, Days_in_Month($1, $2) );
    }
    return ( $dateBegin, $dateEnd );
}

sub configuration {
    my $self = shift;
    my $config = $self->_getByFieldName( 'configuration' );

    if( $config =~ /^cd album$/i || $config =~ /^album$/i )
    {
        return "CD";
    }
    elsif( $config =~ /^cd\/dvd combo$/i )
    {
        return "DVDCD";
    }
    elsif( $config =~ /^vinyl album$/i )
    {
        return "LP";
    }

    $self->fail("Unable to determine configuration from format($config)");
}

sub _isValidSaleRecord {
    my $self = shift;
    my $sales = $self->sales();
    my $returns = $self->returns();
    my $salesRevenue = $self->salesRevenue();
    my $returnsRevenue = $self->returnsRevenue();

    if(( $sales == 0 ) && ( $returns == 0 ) &&
       ( $salesRevenue != 0 || $returnsRevenue != 0 )) {
            $self->fail("Zero units with non-zero revenue");
    }

    return (( $self->sales() || $self->returns() ) && $self->albumName() );
}

###
1;# Play nicely.
###